; CDCat installation script  $VER: CDCat v2.0 (15.12.97)
;
;
;->fs english
(set default_lang 0)
(set default_doc 0)

(set #info "\nThis script will install CDCat and the supported files onto your hard disk.\n\nCDCat © 1997 by Frank Weber.")
(set #demouser "\nPlease remember that CDCat is Shareware. If you like it und use it, please register by paying the registration fee of 20 US$.\n\nThe development of CDCat can only be promoted by your registration.")
(set #keyfileuser "\nThank you for registering. Please do not copy the keyfile which contains your name TO anyone.\n\nThe development of CDCat can only be promoted by your help.")
(set #installkey "Install keyfile ")
(set #selectinstallmode "Please choose installation mode")
(set #im_new "New installation")
(set #im_update "Update installation (removing old version)")
(set #im_deinstall "Deinstall")
(set #selectdest "Please choose destination drawer\n(A drawer 'CDCat' will be created)")
(set #selectdest_help "You have to select the directory where the 'CDCat' drawer will be created.\n\nCDCat and all related files will then be copied into this drawer.")
(set #installedtwice "\nCDCat has already been installed into this directory.\n\nDo you want me to switch to installation mode 'update' or to rename the existing drawer?.")
(set #it_update "Install as update")
(set #it_renameolddir "Rename old dir")
(set #installcats "\nDo you want to install the example catalog(s)?")
(set #doinstall "Install")
(set #donotinstall "Don't install")
(set #askprefs "\nWhere do you want the main configuration file to be located?")
(set #pd_cdcatdir "CDCat directory")
(set #pd_sdir "S:")
(set #askbuttons "\nWhere do you want the button configuration file to be located?")
(set #askmemolist "\nWhere do you want the memolist file to be located?")
(set #askcdcatprog "Please select the main CDCat program")
(set #askdeinstall "Really proceed with deinstallation?")
(set #dodeinstall "Deinstall")
(set #donotdeinstall "Cancel")
(set #di_aborted "\nDeinstallation aborted!")
(set #di_complete "\nDeinstallation complete!")
(set #askdelete "Really delete the following file(s)?\n\n")
(set #dodelete "Delete")
(set #donotdelete "Skip")
(set #chooselang "\nWhich languages do you want to be installed ???")
(set #chooselang-help "\nIf you want to use CDCat in different languages, the catalog files must be installed. Please select the catalogs you want to be installed.")
(set #askkeydest "Where do you want the keyfile to be installed?")
(set #askdoc "Which documentation do you want to be installed?")

;->fe
;->fs deutsch
(if (= "deutsch" @language )
(
    (set default_lang 1)
    (set default_doc 1)

    (set #info "\nDieses Skript installiert CDCat und alle dazugehörigen Dateien auf Ihrer Festplatte.\n\nCDCat © 1997 by Frank Weber.")
    (set #demouser "\nBitte denken Sie daran, daß CDCat Shareware ist. Wenn Sie es kennengelernt haben und regelmäßig benutzen, sollten Sie sich bei mir für 30 DM registrieren lassen. Nur durch Ihre Unterstützung wird die Weiterentwicklung von CDCat sichergestellt.")
    (set #keyfileuser "\nNochmals vielen Dank für Ihre Registration. Bitte geben Sie das Keyfile, das Ihren Namen und Ihre Adresse enthält, nicht weiter. Nur durch Ihre Unterstützung wird die Weiterentwicklung von CDCat sichergestellt.")
    (set #installkey "Keyfile installieren")
    (set #selectinstallmode "Bitte wählen Sie den Installations-Modus")
    (set #im_new "Neuinstallation")
    (set #im_update "Updateinstallation (über alte Version)")
    (set #im_deinstall "Deinstallation")
    (set #selectdest "Bitte Zielverzeichnis wählen.\n(Ein Verzeichnis 'CDCat' wird dort erstellt)")
    (set #selectdest_help "Sie müssen hier das Verzeichnis wählen, in dem die 'CDCat'-Schublade erstellt werden soll.\n\nIn diese Schublade werden CDCat und die dazugehörigen Dateien kopiert.")
    (set #installedtwice "\nCDCat wurde bereits in dieses Verzeichnis installiert.\n\nSoll in den Installationsmodus 'Update' gewechselt oder die alte Schublade umbenannt werden?")
    (set #it_update "Als Update installieren")
    (set #it_renameolddir "Altes Dir umbenennen")
    (set #installcats "\nMöchten Sie den/die mitgelieferten Beispielkatalog(e) installieren?")
    (set #doinstall "Installieren")
    (set #donotinstall "Nicht installieren")
    (set #askprefs "\nWo soll sich die Hauptkonfigurationsdatei befinden?")
    (set #pd_cdcatdir "CDCat-Verzeichnis")
    (set #pd_sdir "S:-Verzeichnis")
    (set #askbuttons "\nWo soll sich die Knopf-Konfigurationsdatei befinden?")
    (set #askmemolist "\nWo soll sich die Merkbrettdatei befinden?")
    (set #askcdcatprog "Bitte wählen Sie das CDCat-Hauptprogramm aus")
    (set #askdeinstall "Deinstallation wirklich durchführen?")
    (set #dodeinstall "Deinstallieren")
    (set #donotdeinstall "Abbruch")
    (set #di_aborted "\nDeinstallation abgebrochen!")
    (set #di_complete "\nDeinstallion abgeschlossen!")
    (set #askdelete "Folgende Datei(en) wirklich löschen?\n\n")
    (set #dodelete "Löschen")
    (set #donotdelete "Nicht Löschen")
    (set #chooselang "\nWelche Cataloge sollen installiert werden ???")
    (set #chooselang-help "\nWenn Sie CDCat in verschiedenen Sprachen benutzen möchten, müssen Sie die Catalog-Dateien installieren. Wählen Sie aus, welche Cataloge Sie installieren wollen.")
    (set #askkeydest "Wohin soll das Keyfile kopiert werden?")
    (set #askdoc "Welche Dokumentation soll installiert werden?")
))
;->fe
;->fs français
(if (= "français" @language )
(
    (set default_lang 2)
    (set default_doc 2)

    (set #info "\nCe script va installer CDCat et les fichiers requis sur votre disque dur.\n\nCDCat © 1997 de Frank Weber.")
    (set #demouser "Rappelez-vous que CDCat est Shareware. Si vous l'aimez et l'utilisez, veuillez vous enregistrer en vous acquittant des frais d'enregistrements de 130FF.\n\nLe développement de CDCat dépend du nombre de vos enregistrements.")
    (set #keyfileuser "Merci de votre enregistrement. Ne copier pas votre clé contenant votre nom à n'importe qui, S.V.P.\n\nLe développement de CDCat peut être soutenu qu'avec votre aide.")
    (set #installkey "Installation de la clé ")
    (set #selectinstallmode "Choisissez, S.V.P., le mode d'installation")
    (set #im_new "Nouvelle installation")
    (set #im_update "Mise à jour (effaçant l'ancienne version)")
    (set #im_deinstall "Désinstaller")
    (set #selectdest "Choisissez, S.V.P., le répertoire de destination\n(Un répertoire 'CDCat' sera créé)")
    (set #selectdest_help "Vous devez sélectionner le répertoire oÙ sera créé le tiroir pour 'CDCat'.\n\nCDCat et tous les fichiers requis seront copié dans ce tiroir.")
    (set #installedtwice "\nCDCat a déjà été installé dans ce répertoire.\n\nVoulez-vous commuter l'installation en mode 'Mise à jour' ou renommer le tiroir existant?.")
    (set #it_update "Installation en mode mise à jour")
    (set #it_renameolddir "Renommer ancien rép.")
    (set #installcats "\nVoulez-vous installer le(s) catalogue(s) fourni(s)?")
    (set #doinstall "Installer")
    (set #donotinstall "Ne pas installer")
    (set #askprefs "\nOÙ voulez-vous que le fichier de configuration principal soit stocké?")
    (set #pd_cdcatdir "Répertoire de CDCat")
    (set #pd_sdir "S:")
    (set #askbuttons "\nOÙ voulez-vous que le fichier de configuration des boutons soit stocké?")
    (set #askmemolist "\nOÙ voulez-vous que le fichier Mémolist soit stocké?")
    (set #askcdcatprog "Sélectionnez, S.V.P., le programme CDCat")
    (set #askdeinstall "Voulez-vous vraiment procéder à la désinstallation?")
    (set #dodeinstall "Désinstaller")
    (set #donotdeinstall "Annuler")
    (set #di_aborted "\nDésinstallation arrêtée!")
    (set #di_complete "\nDésinstallation complète!")
    (set #askdelete "Voulez-vous vraiment effacer le(s) fichier(s) suivant(s)?\n\n")
    (set #dodelete "Effacer")
    (set #donotdelete "Passer")
    (set #chooselang "\nQuel(les) langue(s) voulez-vous installée(s) ???")
    (set #chooselang-help "\nSi vous désirez utiliser CDCat dans une autre langue, le fichier catalogue doit être installé. Sélectionnez, S.V.P., le(s) catalogue(s) à installé(s).")
    (set #askkeydest "OÙ voulez-vous que la clé soit installée?")
    (set #askdoc "Quelle documentation voulez-vous installée?")
))
;->fe
;->fs italiano
(if (= "italiano" @language )
(
    (set default_lang 4)
    (set default_doc 0)

    (set #info "\nQuesto programma installerà CDCat ed i file di supporto nel tuo hard disk.\n\nCDCat © 1997 da Frank Weber.")
    (set #demouser "Ricorda che CDCat è Shareware. Se lo usi e ti piace, per cortesia registrati pagando 20 US$.\n\nIl futuro sviluppo di CDCat dipende solo dalla tua registrazione.")
    (set #keyfileuser "Grazie per esserti registrato. Per favore non dare la tua chiave di registrazione a nessuno.\n\nIl futuro sviluppo di CDCat dipende solo dal tuo aiuto.")
    (set #installkey "Installa la chiave di registrazione ")
    (set #selectinstallmode "Scegli la modalità di installazione ")
    (set #im_new "Nuova installazione ")
    (set #im_update "Aggiorna installazione (rimuovi vecchie versioni) ")
    (set #im_deinstall "Deinstalla")
    (set #selectdest "Scegli il cassetto di installazione\n(Un nuovo cassetto 'CDCat' verrà creato)")
    (set #selectdest_help "Devi scegliere dove il cassetto 'CDCat' verrà creato.\n\nCDCat ed i file di supporto vi saranno copiati dentro.")
    (set #installedtwice "\nCDCat è già installato in questo cassetto.\n\nvuoi cambiare la modalità di installazione in 'aggiornamento' o rinominare il cassetto ?.")
    (set #it_update "Installa in aggiornamento")
    (set #it_renameolddir "Rinomina il vecchio cassetto")
    (set #installcats "\nVuoi installare i cataloghi di esempio ?")
    (set #doinstall "Installa")
    (set #donotinstall "Non installare")
    (set #askprefs "\nDove vuoi collocare il file principale di configurazione ?")
    (set #pd_cdcatdir "Cassetto di CDCat")
    (set #pd_sdir "S:")
    (set #askbuttons "\nDove vuoi collocare il file di configurazione dei pulsanti ?")
    (set #askmemolist "\nDove vuoi collocare il file del promemoria ?")
    (set #askcdcatprog "Seleziona il file principale del programma CDCat")
    (set #askdeinstall "Vuoi realmente deinstallare CDCat ?")
    (set #dodeinstall "Deinstalla")
    (set #donotdeinstall "Cancella")
    (set #di_aborted "\nDeinstallazione interrotta!")
    (set #di_complete "\nDeinstallazione completata")
    (set #askdelete "Vuoi realmente cancellare i seguenti file ?\n\n")
    (set #dodelete "Cancella")
    (set #donotdelete "Salta")
    (set #chooselang "\nQuale lingua vuoi installare ???")
    (set #chooselang-help "\nSe vuoi usare CDCat in un'altra lingua, devi installare il catalogo. Scegli il catalogo che vuoi installare.")
    (set #askkeydest "Dove vuoi installare la chiave di registrazione ?")
    (set #askdoc "Quale documentazione vuoi installare ?")

))
;->fe
;->fs nederlands
(if (= "nederlands" @language )
(
    (set default_lang 8)
    (set default_doc 0)

    (set #info "\nDit script zal CDCat en de ondersteunende bestanden op je harde schijf installeren.\n\nCDCat © 1997 by Frank Weber.")
    (set #demouser "Onthou dat CDCat Shareware is. Als je het gebruikt, ondersteun dan verdere ontwikkeling door het programma te registreren. Registratie kost 20US$")
    (set #keyfileuser "Bedankt voor uw registratie. Gelieve jou persoonlijke keyfile (waarin jou gegevens gecodeerd zitten) niet verder te copiëren.\n\nVerdere ontwikkeling van CDCat is enkel mogelijk met jou hulp!")
    (set #installkey "Keyfile Installeren")
    (set #selectinstallmode "Kies de installatie modus")
    (set #im_new "Nieuwe installatie")
    (set #im_update "Update installatie (oude versie verwijderen)")
    (set #im_deinstall "De-installeren")
    (set #selectdest "Kies een bestemming (Een schuifje 'CDCat' zal automatisch worden gecreëerd)")
    (set #selectdest_help "Je moet een directory kiezen waar een 'CDCat' schuifje zal worden aangemaakt.\n\nCDCat en alle nodige bestanden zullen in deze schuif worden geplaatst.")
    (set #installedtwice "\nCDCat was reeds geïnstalleerd in deze directory.\n\nWil je omschakelen naar 'update' modus of de bestaande dir hernoemen?")
    (set #it_update "Installeer als update")
    (set #it_renameolddir "Oude dir hernoemen")
    (set #installcats "\nWilt u de voorbeeld catalogi installeren?")
    (set #doinstall "Installeren")
    (set #donotinstall "Niet installeren")
    (set #askprefs "\nKies een plaats voor het hoofd-configuratie bestand")
    (set #pd_cdcatdir "CDCat directory")
    (set #pd_sdir "S:")
    (set #askbuttons "\nKies een plaats voor het knoppen-configuratie bestand")
    (set #askmemolist "\nKies een plaats voor het memo-list bestand")
    (set #askcdcatprog "Selecteer het CDCat hoofdprogramma")
    (set #askdeinstall "Werkelijk doorgaan met de installatie?")
    (set #dodeinstall "De-installeren")
    (set #donotdeinstall "Afbreken")
    (set #di_aborted "\nDe-installatie afgebroken!")
    (set #di_complete "\nDe-installation voltooid!")
    (set #askdelete "Volgend(e) bestand(en) werkelijk verwijderen?\n\n")
    (set #dodelete "Verwijderen")
    (set #donotdelete "Overslaan")
    (set #chooselang "\nWelke talen wil je installeren???")
    (set #chooselang-help "\nAls je CDCat in verschillende talen wil gebruiken moeten catalog-bestanden worden geïnstalleerd. Kies de catalogi die je wil gebruiken")
    (set #askkeydest "Waar moet je keyfile worden geïnstalleerd?")
    (set #askdoc "Welke documentatie moet worden geïnstalleerd?")
))
;->fe
;->fs norsk
(if (= "norsk" @language )
(
    (set default_lang 16)
    (set default_doc 0)

    (set #info "\nDette skriptet vil installere CDCat og noen ekstrafiler til din harddisk.\n\nCDCat © 1997 av Frank Weber.")
    (set #demouser "Vennligst husk på at CDCat er Shareware. Hvis du liker det og bruker det bør du registrere det ved å betale registreringsavgiften på 20 US$.\n\nUtviklingen av CDCat kan bare fremmes med hjelp fra din registrering.")
    (set #keyfileuser "Tusen takk for at du registrerte CDCat. Ikke kopier nøkkelfilen, som inneholder ditt navn, til noen.\n\nUtviklingen av CDCat kan bare fremmes med din hjelp.")
    (set #installkey "Installer nøkkelfil ")
    (set #selectinstallmode "Vennligst velg installeringsmodus")
    (set #im_new "Ny installering")
    (set #im_update "Oppdater installering (fjerner eldre versjon)")
    (set #im_deinstall "Deinstaller")
    (set #selectdest "Vennligst velg installasjonskatalogen\n(En katalog 'CDCat' vil bli opprettet)")
    (set #selectdest_help "Du må velge en katalog hvor 'CDCat' katalogen vil bli opprettet.\n\nCDCat og alle relaterte filer vil så bli kopiert inn i denne katalogen.")
    (set #installedtwice "\nCDCat er allerede installert i denne katalogen.\n\nVil du skifte installeringsmodus til 'oppdatering' eller vil du skifte navn på den eksisterende katalogen?.")
    (set #it_update "Installer eller oppdater")
    (set #it_renameolddir "Endre navnet på den gamle katalogen")
    (set #installcats "\nVil du installere eksempelkatalog(er)?")
    (set #doinstall "Installer")
    (set #donotinstall "Ikke installer")
    (set #askprefs "\nHvos vil du plassere de viktigste konfigurasjonsfilene?")
    (set #pd_cdcatdir "CDCat katalog")
    (set #pd_sdir "S:")
    (set #askbuttons "\nHvor vil du installere konfigurasjonen av knapper?")
    (set #askmemolist "\nHvor vil du installere momolist-filen?")
    (set #askcdcatprog "Vennligst velg selve CDCat programmet")
    (set #askdeinstall "Vil du fortsette med deinstalleringen?")
    (set #dodeinstall "Deinstaller")
    (set #donotdeinstall "Avbryt")
    (set #di_aborted "\nDeinstallering avbrutt!")
    (set #di_complete "\nDeinstallering ferdig!")
    (set #askdelete "Vil du virkelig slette de følgende filene?\n\n")
    (set #dodelete "Slett")
    (set #donotdelete "Hopp over")
    (set #chooselang "\nHvilke språk vil installere?")
    (set #chooselang-help "\nHvis du vil bruke CDCat i forskjellige språk må språkfilene installeres. Vennligst velg de språkfilene du vil installere.")
    (set #askkeydest "Hvor vil du plassere nøkkelfilen?")
    (set #askdoc "Hvilken dokumentasjon vil du installere?")
))
;->fe

;->fs P_installnormal
(procedure P_installnormal
(
  (complete 20)

  (makedir #cdcatdrawer (infos))
  (set #cdcatprog (tackon #cdcatdrawer "CDCat"))

  (copyfiles  (source "/CDCat")
              (dest #cdcatdrawer)
              (infos)
  )

  (complete 35)


  (set doclanguage (askchoice (prompt #askdoc)
                              (choices "English" "Deutsch" "Français")
                              (help @askchoice-help)
                              (default default_doc)
                   )
  )

  (set language (select doclanguage
                          "english"
                          "deutsch"
                          "français"
                          "italiano"
                          "nederlands"
                          "norsk"
                          ""
                 )
  )

  (copyfiles (source (cat "/docs/" language ".guide"))
             (dest #cdcatdrawer)
             (infos)
  )

  (rename (tackon #cdcatdrawer (cat language ".guide")) (tackon #cdcatdrawer "CDCat.guide"))
  (rename (tackon #cdcatdrawer (cat language ".guide.info")) (tackon #cdcatdrawer "CDCat.guide.info"))

  (tooltype (dest (tackon #cdcatdrawer "CDCat.guide"))
            (setposition 180 21)
  )

  (complete 45)

  (set lang (askoptions (prompt #chooselang)
                        (help #chooselang-help)
                        (choices "Deutsch" "Français" "Italiano" "Nederlands" "Norsk")
                        (default default_lang)
            )
  )

  (set n 0)
  (while (set language (select n
                                 "deutsch"
                                 "français"
                                 "italiano"
                                 "nederlands"
                                 "norsk"
                                 ""
                        )
          )
  (
    (if (IN lang n)
    (
        (makedir (tackon (tackon #cdcatdrawer "Catalogs/") language))
        (copyfiles
           (source (tackon (tackon "/Catalogs/" language) "CDCat.catalog"))
           (dest (tackon (tackon #cdcatdrawer "Catalogs/") language))
        )
    ))
    (set n (+ n 1))
  ))

  (copyfiles (source "/catalogs/CDCat.cd")
             (dest (tackon #cdcatdrawer "catalogs"))
  )

  (copyfiles  (source "/RegiTool")
              (dest #cdcatdrawer)
              (infos)
  )

  (copyfiles  (source (cat @language ".info"))
              (dest #cdcatdrawer)
  )

  (rename (tackon #cdcatdrawer (cat @language ".info")) (tackon #cdcatdrawer "Deinstall.info"))

  (copyfiles  (source "Installer_script")
              (dest #cdcatdrawer)
  )

  (complete 55)

  (makedir (tackon #cdcatdrawer "pics"))

  (copyfiles (source "/docs/pics/")
             (dest (tackon #cdcatdrawer "pics"))
             (pattern "#?")
  )


  (complete 60)

  (copyfiles  (source "/DArc_converter")
              (dest #cdcatdrawer)
              (infos)
  )

  (complete 70)

  (makedir (tackon #cdcatdrawer "scancatalogs"))

  (if (> @user-level 1)
  (
    (if (= 1 (askbool (prompt #installcats)
                      (choices #doinstall #donotinstall)
                      (help @askbool-help)
             )
        )
        (copyfiles (source "/scancatalogs/")
                   (dest (tackon #cdcatdrawer "scancatalogs"))
                   (pattern "#?")
        )
    )



    (complete 80)

    (if (= 1 (askbool (prompt #askprefs)
                     (choices #pd_cdcatdir #pd_sdir)
                     (help @askbool-help)
                     (default 1)
            )
        )

          (tooltype (dest #cdcatprog)
                    (settooltype "PREFS" "CDCat.prefs")
          )

          (tooltype (dest #cdcatprog)
                    (settooltype "PREFS" "S:CDCat.prefs")
          )
    )

    (complete 85)

    (if (= 1 (askbool (prompt #askbuttons)
                     (choices #pd_cdcatdir #pd_sdir)
                     (help @askbool-help)
                     (default 1)
            )
        )

          (tooltype (dest #cdcatprog)
                    (settooltype "BUTTONCONFIG" "CDCat.buttons")
          )

          (tooltype (dest #cdcatprog)
                    (settooltype "BUTTONCONFIG" "S:CDCat.buttons")
          )
    )

    (complete 90)

    (if (= 1 (askbool (prompt #askmemolist)
                     (choices #pd_cdcatdir #pd_sdir)
                     (help @askbool-help)
                     (default 1)
            )
        )

          (tooltype (dest #cdcatprog)
                    (settooltype "MEMOLIST" "CDCat.memolist")
          )

          (tooltype (dest #cdcatprog)
                    (settooltype "MEMOLIST" "S:CDCat.memolist")
          )
    )
  )
  (
        (copyfiles (source "/scancatalogs/")
                   (dest (tackon #cdcatdrawer "scancatalogs"))
                   (pattern "#?")
        )
        (tooltype (dest #cdcatprog)
                  (settooltype "PREFS" "CDCat.prefs")
        )
        (tooltype (dest #cdcatprog)
                  (settooltype "BUTTONCONFIG" "CDCat.buttons")
        )
        (tooltype (dest #cdcatprog)
                  (settooltype "MEMOLIST" "CDCat.memolist")
        )

  ))


  (complete 92)

  (tooltype (dest #cdcatprog)
            (settooltype "DOC" "CDCat.guide")
  )

  (tooltype (dest #cdcatprog)
            (settooltype "REGITOOL" "RegiTool")
  )

  (if (< (/ (getversion) 65536) 38)
      (tooltype (dest (tackon #cdcatdrawer "CDCat.guide"))
                (setdefaulttool "sys:utilities/AmigaGuide")
      )

      (tooltype (dest (tackon #cdcatdrawer "CDCat.guide"))
                (setdefaulttool "sys:utilities/Multiview")
      )

  )

  (tooltype (dest (tackon #cdcatdrawer "CDCat.guide"))
            (setposition  60 80)
  )

  (tooltype (dest (tackon #cdcatdrawer "Deinstall"))
            (setposition  160 85)
  )

  (complete 96)

    (if (exists "CDCat.key")
      (P_installkey)
    )
  (complete 100)

  (if #keyfilecopied
      (set #schlusstext #keyfileuser)
      (set #schlusstext #demouser)
  )

  (exit #schlusstext)
)
)
;->fe
;->fs P_installupdate
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;Updateinstallation

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


(procedure P_installupdate
(
  (if (= #cdcatprog "")

    (until (= "CDCat" (fileonly #cdcatprog))

      (set #cdcatprog (askfile (prompt #askcdcatprog)
                               (default "SYS:")
                               (help @askfile-help)
                      )
      )
    )
  )

  (set #cdcatdrawer (pathonly #cdcatprog))
  (set @default-dest #cdcatdrawer)

  (complete 15)

  (copyfiles  (source "/CDCat")
              (dest #cdcatdrawer)
  )

  (complete 35)


  (set doclanguage (askchoice (prompt #askdoc)
                              (choices "English" "Deutsch" "Français")
                              (help @askchoice-help)
                              (default default_doc)
                   )
  )

  (set language (select doclanguage
                          "english"
                          "deutsch"
                          "français"
                          "italiano"
                          "nederlands"
                          "norsk"
                          ""
                 )
  )

  (copyfiles (source (cat "/docs/" language ".guide"))
             (dest #cdcatdrawer)
             (infos)
  )


  (delete (tackon #cdcatdrawer "CDCat.guide" (infos)))
  (rename (tackon #cdcatdrawer (cat language ".guide")) (tackon #cdcatdrawer "CDCat.guide"))
  (rename (tackon #cdcatdrawer (cat language ".guide.info")) (tackon #cdcatdrawer "CDCat.guide.info"))

  (tooltype (dest (tackon #cdcatdrawer "CDCat.guide"))
            (setposition 180 21)
  )

  (complete 45)

  (set lang (askoptions (prompt #chooselang)
                        (help #chooselang-help)
                        (choices "Deutsch" "Français" "Italiano" "Nederlands" "Norsk")
                        (default default_lang)
            )
  )

  (set n 0)
  (while (set language (select n
                                 "deutsch"
                                 "français"
                                 "italiano"
                                 "nederlands"
                                 "norsk"
                                 ""
                        )
          )
  (
    (if (IN lang n)
    (
        (makedir (tackon (tackon #cdcatdrawer "Catalogs/") language))
        (copyfiles
           (source (tackon (tackon "/Catalogs/" language) "CDCat.catalog"))
           (dest (tackon (tackon #cdcatdrawer "Catalogs/") language))
        )
    ))
    (set n (+ n 1))
  ))

  (copyfiles (source "/catalogs/CDCat.cd")
             (dest (tackon #cdcatdrawer "catalogs"))
  )

  (copyfiles  (source "/RegiTool")
              (dest #cdcatdrawer)
              (infos)
  )


  (copyfiles  (source (cat @language ".info"))
              (dest #cdcatdrawer)
  )

  (delete (tackon #cdcatdrawer (cat "Deinstall.info")))
  (rename (tackon #cdcatdrawer (cat @language ".info")) (tackon #cdcatdrawer "Deinstall.info"))

  (copyfiles  (source "Installer_script")
              (dest #cdcatdrawer)
  )

  (complete 55)

  (makedir (tackon #cdcatdrawer "pics"))

  (copyfiles (source "/docs/pics/")
             (dest (tackon #cdcatdrawer "pics"))
             (pattern "#?")
  )


  (complete 60)

  (copyfiles  (source "/DArc_converter")
              (dest #cdcatdrawer)
              (infos)
  )

  (complete 85)

  (if (> @user-level 1)
  (
    (if (= 1 (askbool (prompt #installcats)
                      (choices #doinstall #donotinstall)
                      (help @askbool-help)
             )
        )
        (copyfiles (source "/scancatalogs/")
                   (dest (tackon #cdcatdrawer "scancatalogs"))
                   (pattern "#?")
        )
    )
  )
  (
    (copyfiles (source "/scancatalogs/")
               (dest (tackon #cdcatdrawer "scancatalogs"))
               (pattern "#?")
    )
  ))

  (tooltype (dest (tackon #cdcatdrawer "CDCat.guide"))
            (setposition  60 80)
  )

  (tooltype (dest (tackon #cdcatdrawer "Deinstall"))
            (setposition  160 85)
  )

  (complete 90)

    (if (exists "/CDCat.key")
      (P_installkey)
    )
  (complete 100)

  (if #keyfilecopied
      (set #schlusstext #keyfileuser)
      (set #schlusstext #demouser)
  )

  (exit #schlusstext)

))
;->fe
;->fs P_deinstall
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;Deinstallation

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


(procedure P_deinstall
(
  (if (= #cdcatprog "")

    (until (= "CDCat" (fileonly #cdcatprog))

      (set #cdcatprog (askfile (prompt #askcdcatprog)
                               (default "CDCat")
                               (help @askfile-help)
                      )
      )
    )
  )

  (set #cdcatdrawer (pathonly #cdcatprog))

  (if (= @user-level 1)
  (
      (set #proceed (askbool (prompt #askdeinstall)
                      (choices #dodeinstall #donotdeinstall)
                      (help @askbool-help)
                      (default 0)
                    )
      )
      (if (= 0 #proceed) (exit #di_aborted (quiet)) )
  ))

;  (set #prefsfile "")
;  (iconinfo (dest (tackon #cdcatdrawer "CDCat")) (gettooltype "PREFS" #prefsfile))
;  (set #buttonfile "")
;  (iconinfo (dest (tackon #cdcatdrawer "CDCat")) (gettooltype "BUTTONCONFIG" #buttonfile))
;  (set #memolistfile "")
;  (iconinfo (dest (tackon #cdcatdrawer "CDCat")) (gettooltype "MEMOLIST" #memolistfile))
;  (set #keyfile "")
;  (iconinfo (dest (tackon #cdcatdrawer "CDCat")) (gettooltype "KEYFILE" #keyfile))

  (if (> @user-level 1)
    (set #proceed (askbool (prompt (cat #askdelete "CDCat"))
                           (choices #dodelete #donotdelete)
                           (help @askbool-help)
                           (default 0)
                  )
    )
    (set #proceed 1)
  )

  (if (= 1 #proceed)
    (delete (tackon #cdcatdrawer "CDCat") (infos))
  )

  (if (> @user-level 1)
    (set #proceed (askbool (prompt (cat #askdelete "CDCat.guide + pics/"))
                           (choices #dodelete #donotdelete)
                           (help @askbool-help)
                           (default 0)
                  )
    )
    (set #proceed 1)
  )

  (if (= 1 #proceed)
    (delete (tackon #cdcatdrawer "CDCat.guide") (infos))
  )

  (if (= 1 #proceed)
    (run (cat "c:delete \"" (tackon #cdcatdrawer "pics/") "\" all"))
  )

  (if (> @user-level 1)
    (set #proceed (askbool (prompt (cat #askdelete "catalogs/"))
                           (choices #dodelete #donotdelete)
                           (help @askbool-help)
                           (default 0)
                  )
    )
    (set #proceed 1)
  )

  (if (= 1 #proceed)
    (run (cat "c:delete \"" (tackon #cdcatdrawer "catalogs/") "\" all"))
  )

  (if (> @user-level 1)
    (set #proceed (askbool (prompt (cat #askdelete "RegiTool"))
                           (choices #dodelete #donotdelete)
                           (help @askbool-help)
                           (default 0)
                  )
    )
    (set #proceed 1)
  )

  (if (= 1 #proceed)
    (delete (tackon #cdcatdrawer "RegiTool") (infos))
  )

  (if (> @user-level 1)
    (set #proceed (askbool (prompt (cat #askdelete "DArc_converter"))
                           (choices #dodelete #donotdelete)
                           (help @askbool-help)
                           (default 0)
                  )
    )
    (set #proceed 1)
  )

  (if (= 1 #proceed)
    (delete (tackon #cdcatdrawer "DArc_converter") (infos))
  )

  (if (> @user-level 1)
    (set #proceed (askbool (prompt (cat #askdelete "Installer_script"))
                           (choices #dodelete #donotdelete)
                           (help @askbool-help)
                           (default 0)
                  )
    )
    (set #proceed 1)
  )

  (if (= 1 #proceed)
    (delete (tackon #cdcatdrawer "Installer_script"))
  )

  (if (= 1 #proceed)
    (delete (tackon #cdcatdrawer "Install.info"))
  )

  (if (> @user-level 1)
    (set #proceed (askbool (prompt (cat #askdelete "scancatalogs/"))
                           (choices #dodelete #donotdelete)
                           (help @askbool-help)
                           (default 0)
                  )
    )
    (set #proceed 1)
  )

  (if (= 1 #proceed)
    (run (cat "c:delete \"" (tackon #cdcatdrawer "scancatalogs/") "\" all"))
  )

;  (if (> @user-level 1)
;    (set #proceed (askbool (prompt (cat #askdelete #prefsfile))
;                           (choices #dodelete #donotdelete)
;                           (help @askbool-help)
;                           (default 0)
;                  )
;    )
;    (set #proceed 1)
;  )
;
;  (if (= 1 #proceed)
;    (delete (tackon #cdcatdrawer #prefsfile) (infos))
;  )

;  (delete #cdcatdrawer (infos))

  (exit #di_complete (quiet))
))
;->fe
;->fs P_installkey
(procedure P_installkey
(
  (if (= "" #cdcatprog)
    (until (= "CDCat" (fileonly #cdcatprog))
      (set #cdcatprog (askfile   (prompt #askcdcatprog)
                                 (help @askfile-help)
                                 (default @default-dest)
                      )
      )
    )
  )

  (if (> @user-level 1)

    (set #keydest (askdir (prompt #askkeydest)
                          (help @askdir-help)
                          (default (pathonly #cdcatprog))
                  )
    )

    (
      (if (= 1 (askbool (prompt #askkeydest)
                          (choices #pd_cdcatdir #pd_sdir)
                          (help @askbool-help)
                          (default 1)
               )
          )

          (set #keydest (pathonly #cdcatprog))
          (set #keydest "S:")
      )

    )
  )

  (copyfiles (source "/CDCat.key")
             (dest #keydest)
  )

  (set #keyfilecopied 1)

  (if (= #keydest (pathonly #cdcatprog))
    (tooltype (dest #cdcatprog)
              (settooltype "KEYFILE" "CDCat.key")
    )
    (tooltype (dest #cdcatprog)
              (settooltype "KEYFILE" (tackon #keydest "CDCat.key"))
    )
  )
)
)
;->fe

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

; Eigentlicher Start

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

(complete 0)
(message #info)
(complete 5)

(set #default-dir "SYS:")
(set @default-dest "SYS:")
(set #cdcatprog "")

(if (exists "CDCat.key")
  (set #installkey #installkey)
  (set #installkey "")
)


(if (exists "Deinstall.info")
(

  (set #mode (askchoice
                  (prompt #selectinstallmode)
                  (help @askchoice-help)
                  (choices #im_deinstall)
                  (default 0)
             )
  )
  (set #mode 3)
)
  (set #mode (askchoice
                  (prompt #selectinstallmode)
                  (help @askchoice-help)
                  (choices #im_new #im_update #installkey)
                  (default 0)
             )
  )
)
(if (= #mode 0)
  (   (set #dest (askdir (prompt #selectdest)
                         (help #selectdest_help)
                         (default @default-dest)
                 )
      )

      (set #cdcatdrawer (tackon #dest "CDCat"))
      (set @default-dest #dest)

      (if (exists #cdcatdrawer)
         (if (= 1 (askbool
                               (prompt #installedtwice)
                               (choices #it_update #it_renameolddir)
                               (help @askbool-help)
                               (default 1)
                  )
             )
             (
               (set #mode 1)
               (set #cdcatprog (tackon #cdcatdrawer "CDCat"))
             )
             (
               (rename #cdcatdrawer (cat #cdcatdrawer "_old"))
             )
         )
   )
      (if (= #mode 0) (P_installnormal))
  )
)

(if (= #mode 1) (P_installupdate))

(if (= #mode 2) (P_installkey))

(if (= #mode 3) (P_deinstall))