; ===================================
;
; EasyTM installer script
; $VER: EasyTM-Install 1.1 (28.05.96)
;
; Copyright © 1996 Tak Tang
;
; ===================================

; ==== English strings

(set #bad-kick-msg "EasyTM requires AmigaOS 2.04 or above.")

(set #hello-msg
   (cat "\n\nThank you for trying EasyTM, the"
        "\nlite tool manager for the Amiga."
        "\n"
        "\nNothing will be deleted from your"
        "\nsystem with this installation program."
        "\n"
        "\nIf you don't understand any part of the"
        "\ninstallation, click on the \"Help\" gadget found"
        "\nthroughout the installation for more information."
        "\n\nCLICK TO PROCEED"))

(set #alltime-msg
   (cat "\n\n"
	"Do you want EasyTM to be run every\n"
        "time you turn on your machine?\n"))

(set #alltime-help
   (cat "\n\n"
	"Selecting YES will copy EasyTM to your WBStartUp\n"
   	"drawer, where it will be started every time you\n"
   	"boot your machine.  Selecting NO will copy EasyTM\n"
   	"to your SYS:Tools/Commodities drawer.\n"))

(set #choosetool-msg
   (cat "\n"
	"Where shall I copy EasyTM (the main program)?\n"))

(set #choosetool-help
   (cat "\n"
	"If you want EasyTM to start automatically, each\n"
	"time you reboot, place EasyTM in SYS:WBStartUp.\n"
	"\n"
	"Otherwise, select the directory where\n"
	"you store all your commodities.\n"
	"This is usually SYS:Tools/Commodities.\n"))

(set #exit-msg
   (cat "You can run EasyTM now - just double click\n"
        "on the icon, or reboot your machine.\n"
        "\n"
        "You should run the prefs program\n"
        "to set up your tools menu.\n"
        "\n"
        "Enjoy easyTM!"))

(set #tooldir "SYS:WBStartUp")
(set #prefdir "SYS:Prefs")


; ===== Check Kickstart Version


(if (< (getversion "LIBS:version.library") (* 37 65536))
        (abort #bad-kick-msg)
)

(message #hello-msg)


; ===== Install main program

(if (= 1 @user-level)
	(if (= 0 (askbool (prompt #alltime-msg) (help #alltime-help) ) )
	    (set #tooldir "SYS:Tools/Commodities")
	)
)

(if (= 2 @user-level)
	(set #tooldir
		(askdir (prompt #choosetool-msg)
			(help #choosetool-help)
			(default #tooldir)
		)
	)
)

(copyfiles
	(prompt "Copying EasyTM")
	(help @copyfiles-help)
	(source "EasyTM")
	(dest #tooldir)
	(infos)
)


; ===== Install prefs program

(copyfiles
	(prompt "Copying EasyTM-Prefs")
	(help @copyfiles-help)
	(source "EasyTM-Prefs")
	(dest #prefdir)
	(infos)
)


; ===== Install config files

(copyfiles
	(prompt "Copying EasyTM.Config")
	(help @copyfiles-help)
	(source "EasyTM.Config")
	(dest "ENVARC:")
	(infos)
)

(copyfiles
	(prompt "Copying EasyTM.Config")
	(help @copyfiles-help)
	(source "EasyTM.Config")
	(dest "ENV:")
	(infos)
)

; ==== Exit

(exit #exit-msg)

; ==== End of installer script