; Photogenics Installer script. © Almathera 1994-6. All rights reserved.

; $VER: Photogenics_1.2b_Installer 1.221 (12.3.96)

; Authored & Hacked To Death by THP / Citrus'95.

;                                   <The idiot wing of Almathera>

; Translation done by Mono / RBM Computertechnik ´96

;                                   <call me slave>

; If he´s still alive... Greetings to THP.. so much info in tricky sentences ... I start hating GERMAN language.

;  pain / adrenalin / alcohol / irony. all else is futile. <not futile - natural.. mono>

;                And now over to Tom with the weather.


; /**************************************************************************/
;                  The "wurdZ": Complicated weirdshit, this.
; /**************************************************************************/

                          ; global messages

(set #GOINGIN
	(cat "\n\nWillkommen zur Photogenics (TM) Installation \n\n\n"
	     "Lesen Sie die READ.ME Datei auf Disk 3 um "
	     "Information über Photogenics 1.2b zu bekommen, die "
	     "noch nicht im Handbuch aufgenommen werden konnten."
	     "\n\n\n Photogenics © 1994-6 Paul Nolan & Almathera Systems Ltd."
	     " Alle Rechte vorbehalten.")
)

(set #TOOSMALLBOX-HELP
	(cat "\n\nWarnung:\n\nInstallation von Photogenics auf einem Rechner"
	     " mit Harddisk aber ohne extra FAST Ram ist nicht *NOT*"
	     " empfohlen aufgrund des Speicher-Overheads der"
	     " Harddisk.\n\n"
	     " Zusätzliches FAST RAM wird die System-Performence Ihres Rechners "
	     " ungefähr um den Faktor 2 verbessern und erlaubt Ihnen"
	     " mit wesentlich größeren Bildern in Photogenics zu arbeiten.")
)

(set #WAYS-TO-INSTALL
	(cat "Photogenics ist ein modulares Programm - Sie müssen nicht das"
	     " vollständige Paket installieren, um es zu nutzen. Die meisten"
	     " User können einfach nur das Hauptprogramm installieren - wenn"
	     " Sie extra Grafikhardware besitzen oder Sie mehr Lade/Speicher-"
	     " Formate nutzen möchten, können Sie zusätzlich die Extra-Module"
	     " installieren.\n\n"
	     " Die Farbzeichensätze werden genutzt wie unter 'Spezial Text Effekte"
	     " in der Alpha Channels Anleitung beschrieben.Es sind 8-Farb "
	     " Zeichensätze die in einer gerichten Graustufen-Palette genutzt werden.."
	     " Sie sind sehr GROß (ca. 900K), stellen Sie bitte zuvor sicher "
	     " daß genügend Festplattenspeicher zur Verfügung ist.\n\n"
	     " Die Grafiken und Beispiele der Übung sind: die Bilder "
	     " wie im Handbuch beschrieben und zusätzlich eine Gruppe von"
	     " anderem passenden Material für Photogenics. Bitte nehmen Sie"
	     " zur Kenntnis, das diese Bilder urheberrechtlich geschützt sind und "
	     " nur zu Testzwecken mitgeliefert werden - sie sind nicht zur"
	     " kommerziellen Nutzung ohne besondere Erlaubnis des entsprechenden "
	     " Besitzers freigegeben.")
)

(set #DOTHEPROGRAMFIRST
	(cat " Sie müssen das Photogenics Hauptprogramm installieren"
	     " bevor Sie die optionalen GIOs, Zeichensätze, Bilder etc."
	     " installieren können ;->\n\n"
	     " Stellen Sie sicher das die Checkbox für 'Hauptprogramm und Standardmodule'"
	     " gewählt ist, wenn das HauptOptionsMenu nach dem Starten dieses Installers"
	     " erscheint. <Sie können zur selben Zeit durch Wahl aller Checkboxen und"
	     " Bestätigung ´Weiter´ alles andere installieren.>")
)

(set #OLDBOX-HELP "\n Sie müssen für Photogenics KickStart 3.0 (V39) oder höher nutzen!")

(set #MAIN-PROMPT
	(cat "Welche Teile von Photogenics möchten Sie installieren?\n"
	     "(Nutzen Sie die Checkboxen um zu wählen <Proceed>)")
)

(set #CHOICE-MAIN "Hauptprogramm & Standard Module (850K)")

(set #CHOICE-EXTRA "Extra Module (370K)")

(set #CHOICE-FONTS "Extra Farbzeichensätze (900K)")

(set #CHOICE-GFX "Anleitung & Beispielbilder (760K)")

(set #DISK "Bitte legen Sie die Photogenics Disk %s in ein Laufwerk")

(set #FINAL-MESSAGE
	(cat "\n"
	     "Nach dieser letzten Bestätigung folgt eine Liste von Änderung,"
	     " Updates und Erweiterungen von Photogenics die noch nicht im"
	     " Handbuch enthalten hin - in diesem Text sind wichtige Informationen"
	     " enthalten, deshalb lesen Sie ihn bitte sorgfältig. Gehen Sie dann"
	     " weiter und starten Sie Photogenics durch Doppelklicken des Icons -"
	     " dieses Icon finden Sie in dem Verzeichnis, in dem Sie das Photogenics"
	     " Paket installiert haben.\n\n( %s )\n\n Los gehts !.")
)

(set #FONTS-INSTALLED "\n\n\nFarbzeichensätze installiert.")

(set #GFX-INSTALLED "\n\n\nÜbungen & Beispielgrafiken installiert.")

                        ; main code messages

(set #REINCARNATION
	(cat "\n\nEine alte Installation des Photogenics Pakets"
	     " wurde gefunden in\n\n%s\n\nWähle 'Weiter' um Ihre"
	     " Installation mit der neusten Version upzudaten, oder" 
	     " ´Abbrechen´ um Abzubrechen.")
)

(set #PREFS-OLD
	(cat "\n\nEs sieht so aus als würden Sie eine Photogenics Version updaten,die"
	     " älter als 1.1a ist. Leider ergab es sich im Laufe der Programmentwicklung"
	     " das Preference Dateien vor V1.1a nicht kompartibel zur aktuellen"
	     " Version sind und leider gelöscht werden müssen. Wenn Sie das nächste"
	     " Mal Photogenics starten, müssen Sie sich noch einmal registrieren."
	     " Wenn Sie nicht ´Weiter´ drücken um die Datei zu löschen, müssen Sie dies"
	     " von Hand tun.")
)

(set #PREFS-SE-OLD
	(cat "\nSie möchten eine SE Version von Photogenics auf Version 1.2 updaten"
	     " Das Format der SE Preference Datei unterscheidet sich jedoch "
	     " zur Datei der 1.2 Version, sie muß deshalb leider gelöscht werden."
	     " Wenn Sie das nächste Mal Photogenics starten, müssen Sie sich mit"
	     " mit Ihrer neuen ´V1.2 Nummer´ registrieren.\n\nLöschen: %s\n\n")
)

(set #MAINPROG-PROMPT
	(cat "Wo möchten Sie Photogenics installieren?\n"
	     "(Ein Verzeichnis names 'Photogenics' wird in jedem Fall"
	     " angelegt)")
)

(set #MAINPROG-HELP
	(cat "\nDas Photogenics Paket ist extrem modular - Effekte, Loader und"
	     " Saver, Pinsel und Bildbearbeiter sind extra Dateien, die "
	     " das Hauptprogramm aufruft, wenn cs sie benötigt. Dies ergibt"
	     " eine effizientere Nutzung des Speichers.\n\n"
	     " Nach der Installation finden Sie das Hauptprogramm im Photogenics"
	     " Verzeichnis und in Unterverzeichnissen die vielfältigen externen "
	     " Module - diese werden gleich ebenfalls installiert.")
)

(set #SCRATCH-PROMPT
	(cat "Wohin soll Photogenics seine temporären Dateien speichern?\n"
	     "(Falls Sie dafür GROßEN Speicherbedarf haben, sollte dies"
	     " ein Festplatten-Verzeichnis sein)")
)

(set #SCRATCH-HELP
	(cat "\nPhotogenics kann manchmal extra Speicherplatz benötigen, um"
	     " temporäre Dateien anzulegen, insbesondere um Daten zu anderen"
	     " Programmen zu portieren - Der Umfang dieser Daten kann einige"
	     " MegaByte betragen, falls Sie viel RAM benutzen <mehr als 10 MB"
	     " FAST>, sollten Sie 'PGStemp:' mit einem möglichst großen"
	     " Verzeichnis Ihrer Festplatte verknüpfen.\n\n"
	     "Das Verzeichnis das Sie auf der nächsten Seite wählen, wird für"
	     " 'PGStemp:' verwendet und in die S:User-StartUP eingetragen")
)

(set #DEPLODE "Okay, Los gehts ...")

(set #SUPPORT-HELP
	(cat "\n\n\n\nDieser Teil installiert die allgemeinen Loader, Saver, Pinsel"
	     " und Effekt-Module, die das Photogenics Hauptprogramm aufruft."
	     " Diese befinden sich in diversen Unterverzeichnissen, deshalb ist es nur"
	     " eine einfache Kopierroutine ohne VersionsCheck.")
)

(set #PGXDIR "Erstelle Photogenics Verzeichnis...")

(set #PGX-SCRATCHPROMPT "Erstelle Verzeichnis \n%s\n für Photogenics temporäre Dateien...")

(set #PGX-CODEPLODE "Installiere Photogenics Version 1.2b Hauptprogramm...")

(set #GENIXFONT-HELP
	(cat "\n\n\n\n\nInstalliere Photogenics Zeichensatz in FONTS: - dies ist"
	     " der interne Zeichensatz des Programms.")
)

(set #PGX-SCRUB "\n\nLösche redundanten Programmcode:\n\n%s\n\n")

(set #PGX-ICONPROMPT "Installiere Photogenics Icon...")

(set #PGX-ICONPOSPROMPT "Setze Icon Position")

(set #PGX-ENVARC "Erstelle Photogenics Verzeichnis in ENVARC:...")

(set #PGX-ENV "Erstelle Photogenics Verzeichnis in ENV:...")

(set #PREFS-DELETE "\n\n\n\nIhre Voreinstellungen wurden in ENV: und ENVARC kopiert, können nun also aus dem Verzeichnisbaum gelöscht werden.")

(set #PREFS-HELP "\n\n\n\n\n\n Installation von V1.2b erfordert das Löschen dieser Datei.")

(set #PREFS-MOVE
	(cat "\nKopiere nun Ihre Photogenics Voreinstellungen in %s\n"
	     "(Photogenics v1.2b nutzt Umgebungsvariablen anstatt"
	     " des Photogenics Verzeichnisbaumes)")
)

(set #PGX-DATA-PROMPT "Installiere Photogenics Daten-Dateien ...")

(set #PGX-FONT-PROMPT "Installiere Photogenics Zeichens. in FONTS:")

(set #PGX-ASL "Prüfe und update ASL.library, falls nötig...")

(set #PGX-DISKFONT "Prüfe und update DiskFont.library, falls nötig...")

(set #PGX-SETPATCH "Prüfe und update SetPatch. Photogenics *benötigt* v40.16")

(set #PGX-MANUAL-PROMPT "Kopiere Handbuchzusätze")

                       ; colorfonts messages 

(set #COLOURFONT-PROMPT
	(cat "\n\n\nMöchten Sie die Farbzeichensätze in das vorgegebene"
	     " Systemverzeichnis FONTS: kopieren, das normalerweise mit"
	     " sys:Fonts verknüpft ist?")
)

(set #WHEREFONT-HELP
	(cat "\nDer Photogenics 'Text' GIO Loader kann Amiga Farbzeichensätze,"
	     " die allerdings sehr groß sind, nutzen. Diese sind größer als 900K,"
	     " deshalb sollten Sie diese nicht unbedingt auf der SystemPlatte "
	     " speichern <sinnvoll wenn Sie Farbzeichensätze in einem gesonderten"
	     " Verzeichnis speichern oder wenig SystemPlattenSpeicher haben>. "
	     " Speichern in ´Fonts:´ das Einfachste aber unhandlich , in einem anderen"
	     " Verzeichnis bedeutet einen weiteren Eintrag in S:User-StartUP.\n\n"
	     " Wählen Sie 'FONTS:' um ins FONTS: zu installieren oder 'Elsewhere' um"
	     " Ihr eigenes Verzeichnis zu wählen.")
)

(set #ELSEWHERE-PROMPT "Okay, wählen Sie ein Verzeichnis.\n")

(set #MAKEFONTDIR-PROMPT "Wähle ein Verzeichnis '%s' für die Farbzeichensätze")

(set #INSTALL-COLFONTS
	(cat "Entpacke und installiere Farbzeichensätze...\n\n\n\n\n"
	     "(Das ist viel Arbeit, bitte gedulden Sie sich etwas...)")
)

(set #INSTALL-COLFONTS-ERROR
	(cat "\n\n"
	     " Der Installer konnte das Entpacken der Farbzeichensätze im"
	     " gewählten Verzeichnis nicht beenden."
	     " Stellen Sie sicher, daß genügend Festplattenspeicher vorhanden ist,"
	     " und falls die zu kopierende  Datei schon existiert, diese "
	     " nicht kopier- oder löschgeschützt ist.")
)

                       ; userstartup messages

(set #FONTSTARTUP-HELP
	(cat "\nWeil Sie die Farbzeichensätze nicht in das Standard-Verzeichnis"
	     " SYS:Fonts installiert haben , kann Photogenics sie so lange nicht"
	     " finden, bis FONTS: nicht mit ihrem gewählten Verzeichnis verknüpft"
	     " ist. Der 'Assign' Befehl unter WorkBench 3.x hat die Option ´ADD´, die"
	     " FONTS: um Verzeichnisse erweitern kann - ROM Routinen können dem ganzen"
	     " AmigaDOS Pfad folgen, aber DOpus und Filerequester können dies nicht.\n\n"
	     " Der beste Weg FONTS: zu erweitern ist ein Eintrag in S:User-Startup.")
)

(set #USERSTARTUP-HELP
	(cat "\n\nPhotogenics benötigt eine AmigaDOS Verknüpfung um alle seine"
	     " Programm Module zu finden.\n\nDie Verknüpfung PHOTOGENICS: wird "
	     " am besten beim Booten angelegt - normalerweise wird dies mit ein"
	     " paar Zeilen in der S:User-Startup bewerkstelligt.\n\nDieser Teil"
	     " des Installers wird diese Zeilen für Sie einfügen.")
)

(set #STARTUP-1
	(cat "\n\n\nMöchten Sie, daß der Installer automatisch die "
	     " benötigten Änderungen für %s in S:User-StartUP einfügt?\n\n"
	     "Falls nicht, Wird er eine Skript Datei erzeugen, die die Befehle"
	     " enthält, welche Sie zu Ihrer S:User-StartUP hinzufügen sollten.")
)

(set #STARTUP-2
	(cat "\n\n\nFüge nun die %s Zeilen in S:User-StartUP ein.\n\n"
	     "Diese sind:\n\n%s")
)

(set #STARTUP-3
	(cat "\n\n\n\nDie Datei:\n\n%s\n\nwurde "
	     "erzeugt. Fügen Sie diese manuell in S:User-StartUP ein.")
)

                           ; GIO messages

(set #BIGBOX-PROMPT "Bitte wählen Sie die Loader/Saver, die Sie benötigen:")

(set #BIGBOX-HELP
	(cat "\nPhotogenics unterstützt eine Vielfalt von spezieller Grafik-Hardware" 
	     " die Liste dieser Hardware wird zukünftig zu finden sein auf a\n\n"
	     "    'wenn-wir-infos-von-den-entwickler-docs-bekommen'\n\n"
	     " Dort ist außerdem eine Sammlung von weniger bekannten oder"
	     " gebräuchlichen GIO Modulen für eine Vielfalt von Hardware und"
	     " Software Formate zur Auswahl, bitte wählen Sie, was Sie installieren"
	     " möchten aus der Liste auf der folgenden Seite und drücken 'Weiter'")
)

(set #BIGBOX-UNPACK "Entpacke Ihre GIO Auswahl im Photogenics Verzeichnisbaum...")

(set #INSTALL-GIO-ERROR
	(cat "\n\n"
	     " Der Installer konnte das Entpacken Ihrer GIO Auswahl im"
	     " Photogenics Verzeichnisbaum nicht beenden."
	     " Stellen Sie sicher, daß genügend Festplattenspeicher vorhanden ist,"
	     " und falls die zu kopierende  Datei schon existiert, diese "
	     " nicht kopier- oder löschgeschützt ist.")
)




(set #TOASTER-OPTION "\n\n\n\n\n\nMöchten Sie die VideoToaster GIOs installieren?")

(set #TOASTER-HELP "\n\n\n\n\nHinweis:Sie brauchen die GIOs um die Toaster Hardware zu nutzen")

(set #COPYINGTOASTER-PROMPT "Entpacke und installiere Video Toaster Treiber...")

(set #TOASTER-ERROR
	(cat "\n\n"
	     " Der Installer konnte das Entpacken der Video Toaster Treiber im"
	     " Photogenics Verzeichnisbaum nicht beenden."
	     " Stellen Sie sicher, daß genügend Festplattenspeicher vorhanden ist,"
	     " und falls die zu kopierende  Datei schon existiert, diese "
	     " nicht kopier- oder löschgeschützt ist.") 
)


(set #WAY-COOL-NEW-STUFF
	(cat "\n\n\n\nIm 1.2b Update gibt es eine Vielzahl von neuen Features"
	     " und Updates von einigen der Zeichenmodi und GIOs - wir löschen"
	     " gerade eine der nicht mehr benötigten Dateien. Dies wird ungefähr"
	     " 4 Ihrer 'ErdenMinuten' dauern. Besten Dank.")
)

(set #BACKWARDS-COMPATIBILITY
	(cat "\n\n\nWenn Sie Ihre jetzige Installation nicht upgraden, werden"
	     " Sie nicht in der Lage sein, zukünftige Erweiterungmodule zu nutzen,"
	     " die sich auf die Funktionalität dieser Photogenics Version"
	     " stützen, die sich auf dieser Diskette befindet.\n\n\n"
	     " Also bitte...Upgraden Sie .Es tut nicht weh ! Ehrlich. ;->\n")
)

                         ; graphics messages

(set #GFXDIR-PROMPT
	(cat "Wo möchten Sie die Übungsanleitung und die\n"
	     "Beispielgrafiken installieren?\n"
	     "(Ein Verzeichnis names '%s' wird in jedem Fall"
	     " dafür angelegt)")
)

(set #MAKE-GFXDIR "Erstelle Verzeichnis für die Grafiken...")

(set #ALPHACLIPS "Installiere Photogenics Beispiele/Übungen...\n\nAlphaClips")

(set #TEXTURES "Installiere Photogenics Beispiele/Übungen...\n\nTextures")

(set #TUTORIALS "Installiere Photogenics Beispiele/Übungen...\n\nTutorialImages")

(set #DISPLACEMAPS "Installiere Photogenics Beispiele/Übungen...\n\nDisplace Maps")

(set #COPYRIGHT "Kopiere Copyright Information")



; /**************************************************************************/
;               Right, ditching old kack we don't need...
; /**************************************************************************/

(procedure scrub
	(
	(if (> (exists (tackon BINARIES OLDKACK) ) 0 )
		(
		(delete (tackon BINARIES OLDKACK)
			(prompt (#PGX-SCRUB (tackon BINARIES OLDKACK) ))
			(help #WAY-COOL-NEW-STUFF)
			(confirm)
			)
		)
	)
	)
)


; /**************************************************************************/
;         And now, over to alt.binaries.pictures.tasteless...
; /**************************************************************************/


(procedure dead_beavers
	(
	(copyfiles
		(prompt HEREITCOMES)
		(help @copyfiles-help)
		(source (tackon "Photogenics_2:" FINALDIR))
		(dest (tackon GRAPHICS FINALDIR))
		(pattern "#?.JPG")
		(confirm)
		)
	)
)


; /**************************************************************************/
;                   there's something dead in here
; /**************************************************************************/


(procedure do-the-startup
	(
	(if
		(askbool
			(prompt
				(#STARTUP-1 SECTION-NAME)
				)
			(help STARTUP-HELP))
		(startup SECTION-NAME
			(prompt
				(#STARTUP-2 SECTION-NAME ADD-TO-USER-STARTUP)
				)
			(help STARTUP-HELP)
			(command ADD-TO-USER-STARTUP))
		(
		(textfile
			(dest (tackon OUTPUT STARTUP-FILE))
			(append ADD-TO-USER-STARTUP))

		(message
			(#STARTUP-3 (tackon OUTPUT STARTUP-FILE))
			)
		)
	)
	)
)


; /**************************************************************************/
;                          Who? What? Where?
; /**************************************************************************/

(procedure hunt_the_wiener
	(
	(set OLDINSTALL (getassign "photogenics"))

	(if (AND (= OLDINSTALL "") (< (IN WHATTOINSTALL 0) 1 ) )
		(abort #DOTHEPROGRAMFIRST)
		(set RETURNCODE OLDINSTALL)
	)
	)
)


; /**************************************************************************/
;                Install the core program and modules
; /**************************************************************************/

(procedure corebinaries
	(

	(set NEWCODE (+ NEWCODE 2))

	(if (= (getassign "WORK" "v") "" )
		(set NORMAL @default-dest)
		(set NORMAL "WORK:")
	)

	(set CHIP (database "graphics-mem") )
	(set TOTAL (database "total-mem") )

	(if ( <= (- TOTAL CHIP) 0 )
		(
		(message #TOOSMALLBOX-HELP)
		)
	)

	(hunt_the_wiener)
	(set WHEREBINARIES RETURNCODE)

	(if (= WHEREBINARIES "")
		(
		(set BINARIES
			(askdir
				(prompt #MAINPROG-PROMPT)
				(help #MAINPROG-HELP)
				(default NORMAL)
				(disk)
			)
		)
		(set BINARIES (tackon BINARIES "Photogenics"))
		)

		(
		(set BINARIES WHEREBINARIES)
		(set NEWINSTALL
			(askbool
				(prompt (#REINCARNATION BINARIES))
				(help #BACKWARDS-COMPATIBILITY)
				(choices "Proceed" "Abort")
			)
		)

		(if (= 0 NEWINSTALL)
			(
			(exit (quiet))
			)
		)

		(if (exists (tackon BINARIES "Photogenics"))
			(
			(set VERTAG (getsize (tackon BINARIES "Photogenics")))

			; /**** 181704 == v1.1a   243268 == v1.2   ****/

			(if (NOT (OR (= VERTAG 243268)  (= VERTAG 181704) ))
				(
				(delete
					(tackon BINARIES "Data/Preferences")
					(prompt #PREFS-OLD)
					(help #PREFS-HELP)
					(confirm)
				)
				)
			)
			)
		)

		)
	)

	(set @default-dest BINARIES)

	(set PGX-SCRATCH
		(askdir
			(prompt #SCRATCH-PROMPT)
			(help #SCRATCH-HELP)
			(default (tackon @default-dest "Temporary"))
			(newpath)
			(disk)
		)
	)

	(set ADD-TO-USER-STARTUP (cat "assign photogenics: \"" BINARIES "\"\nassign PGStemp: \"" PGX-SCRATCH "\"\n"))

	(copyfiles
		(prompt #DEPLODE)
		(help @copyfiles-help)
		(source "Photogenics_3:c/Deplode")
		(dest "ram:")
	)		

	(askdisk
		(prompt (#DISK "1"))
		(dest "Photogenics_1")
		(help @askdisk-help)
	)

                      ; Copying the main bit...

	(if ( < (exists BINARIES (noreq) ) 2)
		(makedir BINARIES
			(prompt #PGXDIR)
			(help @makedir-help) 
			(infos)
		)
	)

	(if ( < (exists PGX-SCRATCH (noreq) ) 2)
		(makedir PGX-SCRATCH
			(prompt (#PGX-SCRATCHPROMPT (PGX-SCRATCH)))
			(help @makedir-help) 
		)
	)

	(working #PGX-CODEPLODE)

	(run ("ram:Deplode Photogenics_1:Photogenics \"%s\"" (tackon BINARIES "Photogenics") )
		(prompt #PGX-CODEPLODE)
		(help #MAINPROG-HELP)
		(confirm)
	)

	(delete "ram:Deplode")

	(copyfiles
		(prompt #PGX-ICONPROMPT)
		(help #MAINPROG-HELP)
		(source "Photogenics_1:Photogenics.icon")
		(dest BINARIES)
		(newname "Photogenics.info")
	)

	(tooltype
		(prompt #PGX-ICONPOSPROMPT)
		(help #MAINPROG-HELP)
		(dest (tackon BINARIES "Photogenics.info"))
		(noposition)
		(setstack 25000)
	)

;   ENV: is now used for all preference files. GIO and main code...

	(if ( < (exists "envarc:Photogenics" (noreq) ) 2)
		(
		(makedir "envarc:Photogenics"
			(prompt #PGX-ENVARC)
			(help @makedir-help) 
			)

		(makedir "env:Photogenics"
			(prompt #PGX-ENV)
			(help @makedir-help) 
			)
		)
	)

	(if (exists "pgsse:" (noreq))
		(
		(delete "ENVARC:Photogenics/preferences-se"
			(prompt (#PREFS-SE-OLD "ENVARC:Photogenics/preferences-se"))
			(help #PREFS-HELP)
			(confirm)
		)

		(delete"ENV:Photogenics/preferences-se"
			(prompt (#PREFS-SE-OLD "ENV:Photogenics/preferences-se"))
			(help #PREFS-HELP)
			(confirm)
		)
		)
	)

	(if (= 1 (exists (tackon BINARIES "Data/Preferences") (noreq)))
		(
		(copyfiles
			(prompt (#PREFS-MOVE "ENVARC:"))
			(source (tackon BINARIES "Data/Preferences"))
			(dest "ENVARC:Photogenics/")
			(help @copyfiles-help)
			(newname "preferences")
			(confirm)
		)

		(copyfiles
			(prompt (#PREFS-MOVE "ENV:"))
			(source (tackon BINARIES "Data/Preferences"))
			(dest "ENV:Photogenics/")
			(help @copyfiles-help)
			(newname "preferences")
			(confirm)
		)

		(delete (tackon BINARIES "Data/Preferences")
			(prompt #PREFS-DELETE)
			(help #PREFS-HELP)
			(confirm)
		)

		)
	)

; Because of Installer following case of the previous file, and GIOs
; being case sensitive, the only way to be reliable is to zap the lot...

	(set OLDKACK "Data/Paintmodes/Flip-X")
	(scrub)

	(set OLDKACK "Data/Paintmodes/Flip-Y")
	(scrub)

	(set OLDKACK "Data/Paintmodes/AddDust")
	(scrub)

	(set OLDKACK "Data/Paintmodes/NegBright")
	(scrub)

	(set OLDKACK "Data/Paintmodes/LimitMax")
	(scrub)

	(set OLDKACK "Data/Paintmodes/LimitMin")
	(scrub)

	(set OLDKACK "Data/Paintmodes/HeavyBlur")
	(scrub)

	(set OLDKACK "Data/Paintmodes/Maximum")
	(scrub)

	(set OLDKACK "Data/Paintmodes/Minimum")
	(scrub)

	(set OLDKACK "Data/Paintmodes/Highlights")
	(scrub)

	(set OLDKACK "Data/Paintmodes/Lowlights")
	(scrub)

	(set OLDKACK "Data/GIO/ACBM.gio")
	(scrub)

	(set OLDKACK "Data/GIO/AmigaScreen.gio")
	(scrub)

	(set OLDKACK "Data/GIO/Ascii-Art.gio")
	(scrub)

	(set OLDKACK "Data/GIO/Backdrop.gio")
	(scrub)

	(set OLDKACK "Data/GIO/BMP.gio")
	(scrub)

	(set OLDKACK "Data/GIO/CDXL.gio")
	(scrub)

	(set OLDKACK "Data/GIO/ColourNoise.gio")
	(scrub)

	(set OLDKACK "Data/GIO/CyBERgraphics.gio")
	(scrub)

	(set OLDKACK "Data/GIO/GIF.gio")
	(scrub)

	(set OLDKACK "Data/GIO/HAM8.gio")
	(scrub)

	(set OLDKACK "Data/GIO/IFFDeep.gio")
	(scrub)

	(set OLDKACK "Data/GIO/ILBM.gio")
	(scrub)

	(set OLDKACK "Data/GIO/Img.gio")
	(scrub)

	(set OLDKACK "Data/GIO/JPEG.gio")
	(scrub)

	(set OLDKACK "Data/GIO/Opal_HIRES.gio")
	(scrub)

	(set OLDKACK "Data/GIO/Opal_LORES.gio")
	(scrub)

	(set OLDKACK "Data/GIO/Pattern.gio")
	(scrub)

	(set OLDKACK "Data/GIO/PBM.gio")
	(scrub)

	(set OLDKACK "Data/GIO/PCD.gio")
	(scrub)

	(set OLDKACK "Data/GIO/Picasso-II.gio")
	(scrub)

	(set OLDKACK "Data/GIO/Plasma.gio")
	(scrub)

	(set OLDKACK "Data/GIO/PrefsPrinter.gio")
	(scrub)

	(set OLDKACK "Data/GIO/QRT.gio")
	(scrub)

	(set OLDKACK "Data/GIO/QuadAnim.gio")
	(scrub)

	(set OLDKACK "Data/GIO/Raw.gio")
	(scrub)

	(set OLDKACK "Data/GIO/RGB8.gio")
	(scrub)

	(set OLDKACK "Data/GIO/RGBN.gio")
	(scrub)

	(set OLDKACK "Data/GIO/Ripples.gio")
	(scrub)

	(set OLDKACK "Data/GIO/Sculpt.gio")
	(scrub)

	(set OLDKACK "Data/GIO/ShowHam8.gio")
	(scrub)

	(set OLDKACK "Data/GIO/Streaks.gio")
	(scrub)

	(set OLDKACK "Data/GIO/Targa.gio")
	(scrub)

	(set OLDKACK "Data/GIO/Text.gio")
	(scrub)

	(set OLDKACK "Data/GIO/VLab.gio")
	(scrub)

	(set OLDKACK "Data/GIO/WhiteNoise.gio")
	(scrub)

;  Okay, we're in the clear. Nuking from orbit, it's the only way...

	(copyfiles
		(prompt #PGX-DATA-PROMPT)
		(help #SUPPORT-HELP)
		(source "Photogenics_1:Data/")
		(dest (tackon BINARIES "Data") )
		(all)
		(confirm)
	)

	(if (= (exists "FONTS:Photogenics.font" (NOREQ)) 0)
		(
		(copyfiles
			(prompt #PGX-FONT-PROMPT)
			(help #GENIXFONT-HELP)
			(source "Photogenics_1:Fonts/")
			(dest "fonts:")
			(pattern "Photogenics#?")
			(fonts)
			(confirm)
			)
		)
	)

; And other application installers crap up the system libraries sometimes...

	(run ("Protect libs:asl.library +RWED"))

	(copylib
		(prompt #PGX-ASL)
		(help @copylib-help)
		(source "Photogenics_1:libs/asl.library")
		(dest "libs:")
		(confirm)
	)

	(run ("Protect libs:diskfont.library +RWED"))

	(copylib
		(prompt #PGX-DISKFONT)
		(help @copylib-help)
		(source "Photogenics_1:libs/diskfont.library")
		(dest "libs:")
		(confirm)
	)

	(run ("Protect c:SetPatch +RWED"))

	(copylib
		(prompt #PGX-SETPATCH)
		(help @copylib-help)
		(source "Photogenics_1:c/SetPatch")
		(dest "c:")
		(confirm)
	)

	(run "Photogenics_1:c/SetPatch QUIET")

	(askdisk
		(prompt (#DISK "3"))
		(dest "Photogenics_3")
		(help @askdisk-help)
	)

	(copyfiles
		(prompt #PGX-DATA-PROMPT)
		(help #SUPPORT-HELP)
		(source "Photogenics_3:ExtraData/")
		(dest (tackon BINARIES "Data") )
		(all)
		(confirm)
	)

	(copyfiles
		(prompt #PGX-MANUAL-PROMPT)
		(help @copyfiles-help)
		(source "Photogenics_3:READ.ME")
		(dest BINARIES)
		(infos)
	)

	(tooltype 
		(dest ("%s/READ.ME" BINARIES))
		(setdefaulttool "More")
		(setstack 10000)
		(noposition)
	)


	(set SECTION-NAME "Photogenics")
	(set STARTUP-HELP #USERSTARTUP-HELP)
	(set OUTPUT BINARIES)
	(set STARTUP-FILE "add-to-user-startup")
	(do-the-startup)

	(makeassign "photogenics" BINARIES)
	(makeassign "PGStemp" PGX-SCRATCH)

	)

)


; /**************************************************************************/
;                       Install the extra stuff
; /**************************************************************************/

(procedure extrastuff
	(
	(hunt_the_wiener)
	(set BINARIES RETURNCODE)
	(set @default-dest BINARIES)
	(makeassign "pgs_temp" BINARIES)

	(set NEWCODE (+ NEWCODE 1))

	(set BIGBOXGIO
		(askoptions
		(prompt #BIGBOX-PROMPT)
		(help #BIGBOX-HELP)
			(choices
					"ACBM"
					"AmigaScreen"
					"Ascii-Art"
					"CDXL"
					"CyberGraphics"
					"EGS"
					"Ham6"
					"Harlequin"
					"Img"
					"Impulse"
					"OpalVision"
					"Pattern"
					"PBM"
					"Picasso II"
					"Preferences Printer"
					"ProGrab24RT"
			)
		)
	)

	(set BIGBOXGIO2
		(askoptions
		(prompt #BIGBOX-PROMPT)
		(help #BIGBOX-HELP)
			(choices
					"QRT"
					"QuadAnim"
					"Raw"
					"Retina"
					"Sculpt"
					"Streaks"
					"StudioII Printing"
					"Targa"
					"TIFF"
					"VLab"
			)
		)
	)

	(askdisk
		(prompt (#DISK "3"))
		(dest "Photogenics_3")
		(help @askdisk-help)
	)

                          ; loop for BIGBOX1

	(set LOOP-FLAG -1)
	(set FILES-TO-COPY "")

	(while (< LOOP-FLAG 16 )
		(

		(set LOOP-FLAG (+ 1 LOOP-FLAG ))

		(if (IN BIGBOXGIO LOOP-FLAG)
			(
			(set FILES-TO-COPY ("%s %s" FILES-TO-COPY
				(select LOOP-FLAG
					"ACBM.gio"
					"AmigaScreen.gio"
					"Ascii-Art.gio"
					"CDXL.gio"
					"CyberGraphX.gio"
					"EGS.gio"
					"Ham6.gio"
					"Harlequin.gio"
					"Img.gio"
					"Impulse.gio"
					"OpalVision.gio"
					"Pattern.gio"
					"PBM.gio"
					"Picasso-II.gio"
					"PrefsPrinter.gio"
					"ProGrab24RT.gio"
					)
				)
			)
			)
		)
		)
	)

	(if (> FILES-TO-COPY "")
		(
		(working ##BIGBOX-UNPACK)
		(set GIOERROR (run ("Photogenics_3:c/lhex -qfw=pgs_temp:Data/GIO x Photogenics_3:ExtraGIOs.lha %s" FILES-TO-COPY)))
		(if  ( <> GIOERROR 0)
			(
			(abort #INSTALL-GIO-ERROR)
			)
		)
		)
	)

                          ; loop for BIGBOX2

	(set LOOP-FLAG -1)
	(set FILES-TO-COPY "")

	(while (< LOOP-FLAG 10 )
		(

		(set LOOP-FLAG (+ 1 LOOP-FLAG ))

		(if (IN BIGBOXGIO2 LOOP-FLAG)
			(
			(set FILES-TO-COPY ("%s %s" FILES-TO-COPY
				(select LOOP-FLAG
					"QRT.gio"
					"QuadAnim.gio"
					"Raw.gio"
					"Retina.gio"
					"Sculpt.gio"
					"Streaks.gio"
					"StudioII-Print.gio"
					"Targa.gio"
					"TIFF.gio"
					"VLab.gio"
					)
				)
			)
			)
		)
		)
	)

	(if (> FILES-TO-COPY "")
		(
		(working #BIGBOX-UNPACK)
		(set GIOERROR (run ("Photogenics_3:c/lhex -qfw=pgs_temp:Data/GIO x Photogenics_3:ExtraGIOs.lha %s" FILES-TO-COPY)))
		(if  ( <> GIOERROR 0)
			(
			(abort #INSTALL-GIO-ERROR)
			)
		)
		)
	)

                   ; The Toaster optional plug-in

	(if (> (exists "Photogenics_3:Toaster.lha") 0)
		(
		(set BREAD
			(askbool
				(prompt #TOASTER-OPTION)
				(help #TOASTER-HELP)
			)
		)

		(if (= BREAD 1)
			(
			(working #COPYINGTOASTER-PROMPT)

			(set BURNT (run "Photogenics_3:c/lhex -qfw=pgs_temp:Data/GIO x Photogenics_3:Toaster.lha"))
			(if  ( <> BURNT 0)
				(
				(abort #TOASTER-ERROR)
				)
			)
			)
		)
		)
	)

	)
)


; /**************************************************************************/
;                       Install the ColourFonts
; /**************************************************************************/


(procedure colourfonts
	(
	(hunt_the_wiener)
	(set WHEREFONT RETURNCODE)

	(set FONTCHOICE
		(askbool
			(prompt #COLOURFONT-PROMPT)
			(help #WHEREFONT-HELP)
		)
	)

	(if (= 0 FONTCHOICE)
		(

		(set WHEREFONT
			(askdir
				(prompt #ELSEWHERE-PROMPT)
				(help @askdir-help)
				(default @default-dest)
				(newpath)
				(disk)
			)
		)

		(if ( < (exists WHEREFONT (noreq) ) 2)
			(makedir WHEREFONT
				(prompt (#MAKEFONTDIR-PROMPT WHEREFONT))
				(help @makedir-help) 
				(confirm)
			)
		)

		(set ADD-TO-USER-STARTUP (cat "assign fonts: \"" WHEREFONT "\" ADD\n"))
		)

		(
		(set WHEREFONT "fonts:")
		)
	)

	(set @default-dest RETURNCODE)
	(makeassign "pgs_temp" WHEREFONT)

	(askdisk
		(prompt (#DISK "3"))
		(dest "Photogenics_3")
		(help @askdisk-help)
	)

	(working #INSTALL-COLFONTS)

	(set FONTERROR (run "Photogenics_3:c/lhex -qfw=pgs_temp: x Photogenics_3:ColourFonts.lha"))
	(if  ( <> FONTERROR 0)
		(
		(abort #INSTALL-COLFONTS-ERROR)
		)
	)

	(if (= 0 FONTCHOICE)
		(
		(run "c:assign fonts: pgs_temp: add")
		(set SECTION-NAME "Photogenics ColourFonts")
		(set STARTUP-HELP #FONTSTARTUP-HELP)
		(set OUTPUT @default-dest)
		(set STARTUP-FILE "add-fonts-to-user-startup")
		(do-the-startup)
		)
	)
	)
)


; /**************************************************************************/
;            And the test graphics. "Two tits in a canoe"
; /**************************************************************************/

(procedure tutorials
	(
	(hunt_the_wiener)
	(set NORMAL RETURNCODE)
	(set GRAPHICS-DIR "Graphics")

	(set GRAPHICS
		(askdir
			(prompt (#GFXDIR-PROMPT GRAPHICS-DIR ) )
			(help @askdir-help)
			(default NORMAL)
			(newpath)
			(disk)
		)
	)

	(set GRAPHICS (tackon GRAPHICS GRAPHICS-DIR))

	(if ( < (exists GRAPHICS (noreq) ) 2)
		(makedir GRAPHICS
			(prompt #MAKE-GFXDIR)
			(help @makedir-help) 
			(confirm)
			(infos)
		)
	)

	(set @default-dest RETURNCODE)

	(askdisk
		(prompt (#DISK "2"))
		(dest "Photogenics_2")
		(help @askdisk-help)
		)

	(set HEREITCOMES #ALPHACLIPS)
	(set FINALDIR "AlphaClips")
	(dead_beavers)

	(set HEREITCOMES #TEXTURES)
	(set FINALDIR "Textures")
	(dead_beavers)

	(set HEREITCOMES #TUTORIALS)
	(set FINALDIR "TutorialImages")
	(dead_beavers)

	(set HEREITCOMES #DISPLACEMAPS)
	(set FINALDIR "DisplaceMaps")
	(dead_beavers)

	(copyfiles
		(prompt #COPYRIGHT)
		(help @copyfiles-help)
		(source "Photogenics_2:Example Images NOTICE")
		(dest GRAPHICS)
		(infos)
		)

	(tooltype 
		(dest ("%s/Example Images NOTICE" GRAPHICS))
		(setdefaulttool "More")
		(setstack 10000)
		(noposition)
		)

	)
)


; /**************************************************************************/
;                  Oh no, it's the Central Cavern!
; /**************************************************************************/


(if (< (/ (getversion) 65536) 39)
	((abort #OLDBOX-HELP))
)

(run "Avail >nil: <nil: FLUSH")

(message #GOINGIN)

(set NEWCODE 0)

(set WHATTOINSTALL
	(askoptions
		(prompt #MAIN-PROMPT)
		(help #WAYS-TO-INSTALL)
		(choices #CHOICE-MAIN
		         #CHOICE-EXTRA
		         #CHOICE-FONTS
		         #CHOICE-GFX)
		(default 1)
	)
)

(if (= WHATTOINSTALL 0)
	(exit (quiet))
)

(if (= (IN WHATTOINSTALL 0) 1)
	(corebinaries)
)

(if (= (IN WHATTOINSTALL 1) 2)
	(extrastuff)
)

(if (= (IN WHATTOINSTALL 2) 4)
	(colourfonts)
)

(if (= (IN WHATTOINSTALL 3) 8)
	(tutorials)
)


; /******************************************************************************/
;                             Right, that's it.
; /******************************************************************************/

(makeassign "pgs_temp")

(if (> NEWCODE 0)
	(

	(askdisk
		(prompt (#DISK "3"))
		(dest "Photogenics_3")
		(help @askdisk-help)
		)

	(message
		( #FINAL-MESSAGE BINARIES )
		)

	(run "run Photogenics_3:c/More Photogenics_3:READ.ME")

	(exit (quiet))
	)
)

(if (= (IN WHATTOINSTALL 2) 4)
	(set FINALREPLY (cat FINALREPLY #FONTS-INSTALLED))
	)

(if (= (IN WHATTOINSTALL 3) 8)
	(set FINALREPLY (cat FINALREPLY #GFX-INSTALLED))
	)

(message FINALREPLY )
(exit (quiet))