/*
** SaveAsFRAMESTORE.fred.pre
**
** $VER: SaveAsFRAMESTORE.fred.pre 1.1.0 (24.10.93)
**
** If the SaveAsFRAMESTORE.fred script appears in the InvokeADPro list,
** this program will ask the user to enter the save parameters for the
** FRAMESTORE'd file.  These parameters will be stuffed into REXX clips.
**
** If they fail to answer, the InvokeADPro list will be aborted.
**
** Clips Exported:
**	FREDFSFilter		-	Level of filtering.
**	FREDFSCompress		-	Level of compression.
**	FREDFSFNameSelect	-	String describing how the filename
**					should be modified
**	FREDFSSeqFileSelect	-	Name of sequence file
**
** NOTE: Clip names are case sensitive.
**
** This script requires FRED v1.4.0 (or higher) to run.  Also required is
** ADPro v2.5.0 (or higher).
**
** Copyright © 1993 Elastic Reality, Inc.
** All Rights Reserved
*/


ADDRESS "ADPro"
OPTIONS RESULTS

PARSE ARG NumberOfCells NumberOfFrames

NL = '0A'X
SQ = '27'X
DQ = '22'X
TRUE  = 1
FALSE = 0


/*
** Ask the user if the image should be filtered and/or compressed.
*/

CALL "FREDSCRIPTS:FREDFunctions/GetANumber" '"Level of filtering:"' 2 0 4 TRUE
IF (RESULT = (0-1)) THEN
	EXIT 10
Filter = RESULT

ADPRO_TO_FRONT

OKAYN '"SaveAsFRAMESTORE.fred"' '"Compress image?"' '"Compress|Leave Uncompressed|Cancel"'
IF (RC = 0) THEN DO
	SCREEN_TO_FRONT "FRED"
	EXIT 10
END
ELSE
	Compress = 2 - RC


/*
** Specify whether the given filename should be reused for the
** FRAMESTORE'd filename.
*/

CALL "FREDSCRIPTS:FREDFunctions/ModifyFilenameSelect" '"'".FS."'"' 4 1 10
FNameSelect = RESULT
IF (RESULT = 10) THEN
	EXIT RESULT

CALL "FREDSCRIPTS:FREDFunctions/SeqFileSelect"
SeqFileSelect = RESULT
IF (RESULT = 10) THEN
	EXIT RESULT


/*
** Update the clips.
*/

SETCLIP( "FREDFSFilter", Filter )
SETCLIP( "FREDFSCompress", Compress )
SETCLIP( "FREDFSFNameSelect", FNameSelect )
SETCLIP( "FREDFSSeqFileSelect", SeqFileSelect )

EXIT 0