/*
** Emboss.fred
**
** $VER: Emboss.fred 1.2.0 (23.10.93)
**
** This program can be run from an InvokeADPro list to emboss the current
** frame of a FRED sequence.
**
** Clips Imported:
**	FREDEmbossDirection	-	1 to emboss in;
**					0 to emboss out.
**
** NOTE: Clip names are case sensitive.
**
** This script requires FRED v1.4.0 (or higher) to run.  Also required is
** ADPro v2.5.0 (or higher).
**
** Copyright © 1992-1993 Elastic Reality, Inc.
** All Rights Reserved
*/


ADDRESS "ADPro"
OPTIONS RESULTS

PARSE ARG FrameNum FrameFName Length LoadFlag FirstCallSeq FirstCallCell

NL = '0A'X
SQ = '27'X
DQ = '22'X
TRUE  = 1
FALSE = 0
TempEmbossImage = "T:TempEmbossImage"


/*
** Get the required clips.  Error if any are missing.
*/

Direction = GETCLIP( "FREDEmbossDirection" )
IF (Direction = "") THEN DO
	ADPRO_TO_FRONT
	OKAY1 "Required clip, FREDEmbossDirection," || NL ||,
		"is not specified."
	SCREEN_TO_FRONT "FRED"
	EXIT 10
END


/*
** See what type of data is loaded in ADPro/MorphPlus.
*/

CALL "FREDSCRIPTS:FREDFunctions/CheckForRawImageData" TRUE
IF (RESULT ~= 0) THEN
	EXIT 10


/*
** Emboss the image.
*/

SAVER "IFF" TempEmbossImage "RAW"
IF (RC ~= 0) THEN DO
	ADPRO_TO_FRONT
	OKAY1 "Saving copy of image failed." || NL ||,
		"Argument Information:" || NL ||,
		"Filename = " || TempEmbossImage || NL ||,
		"Type = " || "RAW"
	SCREEN_TO_FRONT "FRED"
	EXIT 10
END

OPERATOR "NEGATIVE"
IF (RC ~= 0) THEN DO
	ADPRO_TO_FRONT
	OKAY1 "The operator NEGATIVE" || NL ||,
		"failed to execute."
	SCREEN_TO_FRONT "FRED"
	EXIT 10
END

IF (Direction = 1) THEN DO
	XOff = 1
	YOff = 1
END
ELSE DO
	XOff = (-1)
	YOff = (-1)
END

LOADER "UNIVERSAL" TempEmbossImage XOff YOff 50
IF (RC ~= 0) THEN DO
	ADPRO_TO_FRONT
	OKAY1 "Reloading image failed." || NL ||,
		"Argument Information:" || NL ||,
		"X Offset = " || XOff || NL ||,
		"Y Offset = " || YOff || NL ||,
		"Mix = " || 50
	SCREEN_TO_FRONT "FRED"
	EXIT 10
END


/*
** See what type of data is loaded in ADPro/MorphPlus.
*/

CALL "FREDSCRIPTS:FREDFunctions/CheckForGrayImageData" TRUE
IF (RESULT ~= 0) THEN
	EXIT 10


CONTRAST 50

OPERATOR "APPLY_MAP"
IF (RC ~= 0) THEN DO
	ADPRO_TO_FRONT
	OKAY1 "The operator APPLY_MAP" || NL ||,
		"failed to execute."
	SCREEN_TO_FRONT "FRED"
	EXIT 10
END

EXIT 0