/* ===================================================== */
/* Makes currently selected objects' lineweight thinner. */
/* FinalWriter macro written by Ric Fischer - 7/9/93     */
/* $VER: GfxLineWt_Decr 3.0 (21.7.93)                    */
/* ===================================================== */

Options Results

I = 0
X = 0

/* --------------------------------------- */
/* Get the id of the first selected object */
/* --------------------------------------- */
FirstObject SELECTED

/* ----------------------------------------- */
/* If there are no selected object then quit */
/* ----------------------------------------- */
IF ( Result = 0 ) THEN
   EXIT

/* ----------------------------------------------- */
/* Collect all the ids of all the selected objects */
/* ----------------------------------------------- */
DO WHILE RESULT~=0
   I = I + 1
   Objects.I = Result
   NextObject Objects.I SELECTED
   END

/* --------------------------------------------- */
/* For each object we have determine its current */
/* line weight and and then set it to the next   */
/* thinner line weight.                          */
/* --------------------------------------------- */
DO WHILE X < I
   X = X + 1
   GetObjectParams Objects.X LINEWT
   SELECT
      WHEN Result='12' THEN SetObjectParams Objects.X LINEWT '10'
      WHEN Result='10' THEN SetObjectParams Objects.X LINEWT '8'
      WHEN Result='8' THEN SetObjectParams Objects.X LINEWT '6'
      WHEN Result='6' THEN SetObjectParams Objects.X LINEWT '4'
      WHEN Result='4' THEN SetObjectParams Objects.X LINEWT '2'
      WHEN Result='2' THEN SetObjectParams Objects.X LINEWT '1'
      WHEN Result='1' THEN SetObjectParams Objects.X LINEWT '.5'
      WHEN Result='.5' THEN SetObjectParams Objects.X LINEWT 'Hairline'
      WHEN UPPER(Result)='HAIRLINE' THEN SetObjectParams Objects.X LINEWT 'None'
      OTHERWISE ITERATE
   END
END

/* ----------------------------------------- */
/* Now redraw the screen to show the changes */
/* ----------------------------------------- */
Redraw

/* ------------------------ */
/* Reselect all the objects */
/* ------------------------ */
X = 0
DO WHILE X < I
   X = X + 1
   SelectObject Objects.X MULTIPLE
   END