; $VER: Install_McFiler 4.3 (1.12.96) by Alex Pagnoni

;Italian strings

(procedure italiano
	(
		(set badkick "\nMcFiler richiede il Kickstart 2.0+ per funzionare!")
		(set selectdir "\nScegli la directory in cui installare McFiler\n(NOTA: verrà creata una directory)")
		(set mkdir "\nVerrà creata la directory per McFiler")
		(set tools "\nVuoi i programmi e gli script aggiuntivi?")
		(set icons "\nVuoi altre icone MagicWB e Dock per Tool Manager?")
		(set mex "\nMcFiler 4.3 è stato installato!\n\nRicordati che è Shareware!!\n\n\nMcFiler 4.3 © 1994-1996 Roberto Bizzarri\n\n\Script d'installazione di Alex Pagnoni\n")
		(set catlgs "\nScegli il linguaggio:\n(NOTA: l'inglese è il linguaggio di default)")
		(set docs "\nScegli il linguaggio del manuale:")
		(set ttype "PROGDIR:Docs/McF4.3_ita.guide")
	)
)

;English strings

(procedure english
	(
		(set badkick "\nMcFiler requires KickStart 2.0+ to run!")
		(set selectdir "\nSelect the directory where install McFiler\n(NOTE: a directory will be created)")
		(set mkdir "\nA directory for McFiler will be created")
		(set tools "\nDo you want any useful tools and scripts?")
		(set icons "\nDo you want more MagicWB icons and Docks to use with ToolManager?")
		(set mex "\nMcFiler 4.3 has been installed!\n\nRemember that it's Shareware!\n\n\nMcFiler 4.3 © 1994-1996 Roberto Bizzarri\n\nInstallation script by Alex Pagnoni\n")
		(set catlgs "\nSelect a language:\n(NOTE: English is the built-in one)")
		(set docs "\nSelect the doc's language:")
		(set ttype "PROGDIR:Docs/McF4.3_eng.guide")
	)
)

;Insert here others localized strings

;Main script

;Select installer language

(if (= @language "italiano") (italiano))
(if (= @language "english") (english))

;(if (= @language "français") (français)) ...for example

;Check os version

(set osversion (/ (getversion) 65536))

(if (< osversion 37) (abort badkick))

(if (>= osversion 39)
	(set aguide "MultiView")
	(set aguide "Amigaguide")
)

(if (>= osversion 38)
	(set catalogs 1)
)

(welcome "McFiler 4.3 © 1994-1996 Roberto Bizzarri\n")

;Ask destination

(set @target-dir
	(askdir
		(help @askdir-help)
		(prompt selectdir)
		(default @default-dest)
		(disk)
	)
)

(set @target-dir (tackon @target-dir "McFiler"))
(set @default-dest @target-dir)

(complete 0)

(makedir
	@target-dir
	(help)
	(prompt mkdir)
	(infos)
)

;Check CPU

(if (< "68010" (database "cpu"))
	(set mcfsource "/McFiler_020")
	(set mcfsource "/McFiler")
)

;Copy McFiler

(complete 5)
(copyfiles
	(prompt copymcf)
	(source mcfsource)
	(newname "McFiler")
	(dest @target-dir)
	(infos)
)

;Ask for tools and scripts

(complete 15)
(if
	(askbool
		(help @askchoice-help)
		(prompt tools)
		(default 0)
	)
	(
		(copyfiles
			(source "/Tools/")
			(all)
			(dest (tackon @target-dir "Tools"))
			(infos)
		)
		(copyfiles
			(source "/Tools.info")
			(dest @target-dir)
		)
	)
)

;Ask for icons

(complete 30)
(if
	(askbool
		(help @askchoice-help)
		(prompt icons)
		(default 0)
	)
	(
		(copyfiles
			(source "/MagicWB/")
			(all)
			(dest (tackon @target-dir "MagicWB"))
			(infos)
		)
		(copyfiles
			(source "/MagicWB.info")
			(dest @target-dir)
		)
	)
)

;Copy docs

(complete 60)
(set docchoice
	(askchoice
		(prompt docs)
		(help @askchoice-help)
		(choices
			"Italiano"
			"English"
		)
		(default
			(if (= @language "italiano") 0 1)
		)
	)
)

(makedir (tackon @target-dir "Docs"))
(copyfiles
	(source "/Docs.info")
	(dest @target-dir)
)

(if (= docchoice 0)
	(set guidefile "McF4.3_ita.guide")
)

(if (= docchoice 1)
	(set guidefile "McF4.3_eng.guide")
)

(copyfiles
	(source (tackon "/docs" guidefile))
	(prompt copy)
	(infos)
	(dest (tackon @target-dir "Docs"))
)

(tooltype
	(dest (tackon @target-dir (cat "Docs/" guidefile)))
	(setdefaulttool aguide)
	(noposition)
)

(tooltype
	(dest (tackon @target-dir "McFiler"))
	(settooltype "HELP" (tackon "Docs" guidefile))
)

;Copy catalogs

(complete 80)
(if (= catalogs 1)
	(
		(set catchoice
			(askchoice
				(prompt catlgs)
				(help @askchoice-help)
				(choices
					"Italiano"
					"English"
					"Suomi"
				)
				(default
					(if (= @language "italiano") 0 1)
				)
			)
		)
		(makedir (tackon @target-dir "Catalogs"))
		(copyfiles
		(source "/Catalogs.info")
		(dest @target-dir)
		)
		(if (= catchoice 0)
			(
				(copyfiles
					(source "/catalogs/italiano/")
          (all)
					(dest (tackon @target-dir "catalogs/Italiano"))
				)
				(set lang "italiano")
			)
		)
		(if (= catchoice 1)
			(set lang "english")
		)
		(if (= catchoice 2)
			(
				(copyfiles
					(source "/catalogs/suomi/")
					(all)
					(dest (tackon @target-dir "catalogs/Suomi"))
				)
				(set lang "suomi")
			)
			(tooltype
				(dest (tackon @target-dir "McFiler"))
				(settooltype "LANGUAGE" lang)
			)
		)
	)
)

;Installation done!

(complete 100)
(message mex)

;End of installer script