;Install script for WebPlug v1.0
;© 1996 Esteve Boix
;
;Ask for everything needed and install the appropiate files.
;
(set #directory
	(askdir
		(prompt "Dónde quieres instalar WebPlug ?\n(SE CREARÁ un directorio 'WebPlug')")
		(help @askdir-help)
		(default "Sys:")
	)
)
(set #adddocs
	(askbool
		(prompt "\n\nQuieres copiar la documentación (HTML) ?")
		(help @askbool-help)
	)
)
(set #locales
	(askoptions
		(prompt "Qué catálogos quieres instalar ?")
		(help @askoptions-help)
		(choices "Español" "Catalán")
		(default %01)
	)
)
(set #fullinstdir (tackon #directory "WebPlug"))
(set @default-dest #fullinstdir)
(makedir
	(#fullinstdir)
	(prompt "Voy a crear el directorio de WebPlug")
	(help @makedir-help)
	(infos)
)
(copyfiles
	(source '//WebPlug.info' )
	(dest (tackon #fullinstdir '/'))
	(infos)
	(help @copyfiles-help)
)
(copyfiles
	(source "/bin/BrowserLinks")
	(dest (tackon #fullinstdir "BrowserLinks"))
	(prompt "Voy a copiar el directorio de BrowserLinks")
	(all)
	(help @copyfiles-help)
)
(if (= 1 #adddocs)
	(copyfiles
		(source "/docs")
		(dest (tackon #fullinstdir "Docs"))
		(prompt "Voy a copiar la documentación HTML")
		(help @copyfiles-help)
		(all)	
	)
)
(set tempversion (getversion))
(set osversion (/ tempversion 65536))
(if (>= osversion 39)
	(copylib
		(source "/bin/classes/gadgets/textfield.gadget")
		(dest "sys:classes/gadgets")
		(prompt "Voy a instalar el Textfield.gadget (OS v3.0+)")
	)
	(copylib
		(source "/bin/classes/gadgets/textfield.gadget")
		(dest (tackon #fullinstdir "gadgets"))
		(prompt "Voy a instalar el Textfield.gadget (OS v2.0+)")
	)
)
(copyfiles
	(source "/bin/WebPlug")
	(dest #fullinstdir)
	(prompt "Voy a copiar el ejecutable WebPlug's")
	(help @copyfiles-help)
	(infos)
)
(if (in #locales 0)
	(copyfiles
		(source "/bin/locale/catalogs/español")
		(dest "locale:catalogs/español")
		(prompt "Instalando catálogos en español")
		(all)
		(help @copyfiles-help)
	)
)
(if (in #locales 1)
	(copyfiles
		(source "/bin/locale/catalogs/català")
		(dest "locale:catalogs/català")
		(prompt "Instalando catálogos en catalán")
		(all)
		(help @copyfiles-help)
	)
)