;Install script for WebPlug v1.0
;Š 1996 Esteve Boix
;
;Ask for everything needed and install the appropiate files.
;
(set #directory
	(askdir
		(prompt "On vols instal.lar el WebPlug ?\n(Es crearā un directori 'WebPlug')")
		(help @askdir-help)
		(default "Sys:")
	)
)
(set #adddocs
	(askbool
		(prompt "\n\nVols copiar la documentaciķ (HTML) ?")
		(help @askbool-help)
	)
)
(set #locales
	(askoptions
		(prompt "Quins catālegs vols instal.lar ?")
		(help @askoptions-help)
		(choices "Espanyol" "Catalā")
		(default %10)
	)
)
(set #fullinstdir (tackon #directory "WebPlug"))
(set @default-dest #fullinstdir)
(makedir
	(#fullinstdir)
	(prompt "Vaig a crear el directori WebPlug")
	(help @makedir-help)
	(infos)
)
(copyfiles
	(source '//WebPlug.info' )
	(dest (tackon #fullinstdir '/'))
	(infos)
	(help @copyfiles-help)
)
(copyfiles
	(source "/bin/BrowserLinks")
	(dest (tackon #fullinstdir "BrowserLinks"))
	(prompt "Vaig a copiar el directori BrowserLinks")
	(all)
	(help @copyfiles-help)
)
(if (= 1 #adddocs)
	(copyfiles
		(source "/docs")
		(dest (tackon #fullinstdir "Docs"))
		(prompt "Vaig a copiar la documentaciķ HTML")
		(help @copyfiles-help)
		(all)	
	)
)
(set tempversion (getversion))
(set osversion (/ tempversion 65536))
(if (>= osversion 39)
	(copylib
		(source "/bin/classes/gadgets/textfield.gadget")
		(dest "sys:classes/gadgets")
		(prompt "Vaig a instal.lar el Textfield.gadget (OS v3.0+)")
	)
	(copylib
		(source "/bin/classes/gadgets/textfield.gadget")
		(dest (tackon #fullinstdir "gadgets"))
		(prompt "Vaig a instal.lar el Textfield.gadget (OS v2.0+)")
	)
)
(copyfiles
	(source "/bin/WebPlug")
	(dest #fullinstdir)
	(prompt "Vaig a copiar l'executable del WebPlug")
	(help @copyfiles-help)
	(infos)
)
(if (in #locales 0)
	(copyfiles
		(source "/bin/locale/catalogs/espaņol")
		(dest "locale:catalogs/espaņol")
		(prompt "Instal.lant catālegs en espanyol")
		(all)
		(help @copyfiles-help)
	)
)
(if (in #locales 1)
	(copyfiles
		(source "/bin/locale/catalogs/catalā")
		(dest "locale:catalogs/catalā")
		(prompt "Instal.lant catālegs en catalā")
		(all)
		(help @copyfiles-help)
	)
)