;$VER: Audio Thunder Install 1.0 (3.9.96) 
;Copyright ©1996 Asimware Innovations Inc.

(complete 0)


(onerror 
	((makeassign "AMInst")
	(makeassign "AM_Dest")
))

(set @default-dest "SYS:")
(set #theirlevel @user-level )

(set #wbversion (getversion "libs:version.library"))
(set #wbversion (/ #wbversion 65536) )
(if (< #wbversion 37)
	(abort "\n\nAmigaDOS 2.0 or higher is required for Audio Thunder.  "
			 "An upgrade will be needed for your Amiga."
			 "\n\nYou are currently running version " #wbversion ".\n\n"
			 "Also ensure that your libs:version.library file is correct "
			 "for your AmigaDOS version." )
)




(if (exists "l:AsimCDFS")
	((set #version (getversion "devs:asimcdfs.device"))		
	(set #asimversion (/ #version 65536) )
	(set #asimrevision (- #version (* #asimversion 65536) ) )
	(if (< #version 196614)
		((user 2)
		(message "\n\nYou have AsimCDFS v" #asimversion "." #asimrevision " installed on your system.  "
				 "Audio Thunder will function better with AsimCDFS v3.6, or higher.  Consult Asimware Innovations Inc. for update details.\n\n" )
		)
	))
)



(askdisk
	(prompt "Please insert the CD-ROM disc labeled \"Audio_Thunder_MasterCD\".")
	(help	"The Audio Thunder program and files will be copied "
			"from this disk into your system.")
	(dest  "Audio_Thunder_MasterCD")
	(newname "AMInst")
)



(user 2)
(set #AMDir
	(askdir
		(prompt "Specify the directory in which the Audio_Thunder directory will be created:" )
		(help "An Audio_Thunder directory will be created in this specified directory.")
		(default @default-dest)
		(newpath)
	)
)
(user #theirlevel)


(set #AMDir (tackon #AMDir "Audio_Thunder"))


(if (not (exists #AMDir (noreq)))
	(makedir #AMDir
		(prompt "Creating the Audio_Thunder: directory...")
		(help "This will create the specified directory for the program.")
		(infos)
		)
)
(makeassign "AM_Dest" #AMDir)



(set #instAM
	(askbool
		(prompt "\n\nShould Audio Thunder be installed?")
		(help "\n\nThis will copy over the Audio Thunder program "
				"to the " #AMDir " directory\n\nIf you do not "
				"wish the Audio Thunder program to be transferred to your system, "
				"skip this step.\n" )
		(default 1)
	)
)

(if #instAM 
	((protect "AM_Dest:Audio_Thunder" "rwed" )
	(protect "AM_Dest:Audio_Thunder.info" "rwed" )




;***************************************************
; copy over main program 
	(copyfiles
		(prompt "\n\nCopying the Audio_Thunder program to the "
				  #AMDir " directory.\n" )
		(source "AMInst:Audio_Thunder")
		(dest "AM_Dest:")
		(infos)
		(help "\n\nThis will copy over the Audio_Thunder program"
				"to your"  #AMDir " directory.\n" )
		(confirm)
	)

	(tooltype
		(prompt "\n\Setting Audio_Thunder icon.\n" )
		(dest "AM_Dest:Audio_Thunder")
		(noposition)
		(help "\n\nThis will reset the Audio_Thunder icon.\n")
		(confirm)
	)



;***************************************************
; make FlyerBuffer directory
	(set #temp "AM_Dest:FlyerBuffer")
	(if (not (exists #temp (noreq)))
		(makedir #temp
			(prompt "Creating the Audio_Thunder:FlyerBuffer directory...")
			(help "This will create a sub-directory which can be used to buffer Flyer audio clips.")
			(infos)
			)
	)

	



;***************************************************
; make Project directory
	(set #temp "AM_Dest:Projects")
	(if (not (exists #temp (noreq)))
		(makedir #temp
			(prompt "Creating the Audio_Thunder:Projects directory...")
			(help "This will create a sub-directory which can be used to store saved projects.")
			(infos)
			)
	)
))

(protect "S:User-Startup" "rwed" )
(protect "S:Startup-Sequence" "rwed" )

(startup "Audio_Thunder"
	(command (cat "assign Audio_Thunder: \"" #AMDir "\"\n"))
	(prompt "Inserting assignment command into the startup-sequence")
	(help "Assignment commands are being inserted into your "
			"\"S:Startup-Sequence\" or \"S:User-Startup\" file to "
			"allow Audio_Thunder to find the needed files." )
)



(set #Toast "Toaster:ARexx/Editor/StartUpScripts")

(if (exists #Toast (noreq))
	(
	;***************************************************
	; copy over toaster startup
	(copyfiles
		(prompt "\n\nCopying the Audio_Thunder program to the "
				  "Toaster:ARexx/Editor/Asimware directory.\n" )
		(source "AMInst:Audio_Thunder.Rexx")
		(dest #Toast )
		(help "\n\nThis will copy over the Audio_Thunder program"
				"to your " #Toast " directory.\n" )
		(confirm)
	)

	(copyfiles
		(prompt "\n\nCopying the Audio_Thunder icon to the "
				  "Toaster:ARexx/Editor/Asimware directory.\n" )
		(source "AMInst:Audio_Thunder.Rexx.I")
		(dest #Toast )
		(help "\n\nThis will copy over the Audio_Thunder icon"
				"to your " #Toast " directory.\n" )
		(confirm)
	)
	)
)



(set @default-dest #AMDir )

(makeassign "Audio_Thunder" #AMDir)

(makeassign "AMInst")
(makeassign "AM_Dest")