;MPN Installer script 1.2 by MNT'96

;Experience Ninjutsu!

(Set inst
	 (askbool
		   (prompt "Willkommen zur MagicParNET Installation!\n\nDieses Script Installiert MagicParNET \noder entfernt es wieder.\n\n\nBitte wählen Sie eine Aktion:")
		   (help @askbool-help)
		   (choices "MPN Installieren" "MPN Entfernen")
		   (default 1)
	 )
)

(if (= inst 1)
(

      (copylib
	      (prompt "Kopiere Parnet-Device")
	      (help @copylib-help)
	      (source "parnet.device")
	      (dest "devs:")
	      (confirm)
      )

      (copylib
	      (prompt "Kopiere NetPNet-Handler")
	      (help @copylib-help)
	      (source "netpnet-handler")
	      (dest "l:")
	      (confirm)
      )

      (copylib
	      (prompt "Kopiere Pitnet-Device")
	      (help @copylib-help)
	      (source "pitnet.device")
	      (dest "devs:")
	      (confirm)
      )

      (copylib
	      (prompt "Kopiere NetPitNet-Handler")
	      (help @copylib-help)
	      (source "netpitnet-handler")
	      (dest "l:")
	      (confirm)
      )

      (copylib
	      (prompt "Kopiere Mouse-Handler")
	      (help @copylib-help)
	      (source "mouse-handler")
	      (dest "l:")
	      (confirm)
      )

      (complete 25)

      (set mpnpath
	  (askdir
	       (prompt "Wohin soll die MagicParNET-\nSchublade kopiert werden?")
	       (help @askdir-help)
	       (default "sys:system/")
	  )
      )


      (copyfiles
	       (prompt "Kopiere MagicParNET...")
	       (source "inst/")
	       (help @copyfiles-help)
	       (dest mpnpath)
	       (all)
	       (infos)
      )

      (copyfiles
	    (prompt "Wohin soll die Dokumentation\nkopiert werden?")
	    (source "Doks")
	    (help @copyfiles-help)
	    (dest "sys:system/")
	    (confirm)
	    (all)
	    (infos)
      )

      (complete 50)

      (set whi
	      (askbool
		      (prompt "Bitte geben Sie nun an,als was\ndieser Amiga dienen soll.Im einem\nParNET-Netzwerk muss ein Amiga\nClient und der andere Server sein.\n(Wie herum,ist egal.)")
		      (help @askbool-help)
		      (choices "Client" "Server")
		      (default 0)
	      )
      )

      (if (= whi 1)
	  (set sel "0\n")
	  (set sel "1\n")
      )

      (textfile
       (prompt "Lege Variablen an...")
       (Dest "env:ParNET")
       (append sel)
      )

      (textfile
       (prompt "Lege Variablen an...")
       (dest "envarc:ParNET")
       (append sel)
      )

      (complete 75)

      (copyfiles
	(source "parnet-drivelist")
	(dest "s:")
	(help @copyfiles-help)
      )

      (run "c:run >nil: c:ed s:parnet-drivelist")

      (message "Bitte passen Sie jetzt die Laufwerksliste\nan DIESEN Amiga an,in dem Sie vor den ent-\nsprechenden Laufwerken das ';' entfernen.\n\nBitte alles vor der ###-Zeile\nvorerst nicht verändern!\n\n(Der normale AmigaDos-Editor wird mit\n[Escape] [x] [Return] verlassen)")

	(copyfiles
	    (prompt "Kopierte Standart-Netzwerk-Piktogramm")
	    (source "inst/magicparnet/node.rinfo")
	    (dest "SYS:")
	    (Help @copyfiles-help)
	)

      (complete 100)

      (message "Wenn beide Amigas installiert sind,\nkönnen Sie mit mit dem 'Start'-programm\nParNET initialisieren.Es erscheint dann\neine Laufwerk namens 'NET' in dem die\nLaufwerke des jeweils anderen Amigas\nzu finden sind.")
      (exit "Vorher sollte das Programm\n'Vorbereiten' gestartet werden.\n\nDies sollte auch nach jeder änderung der\nS:ParNET-Drivelist geschehen.")
)
(
       (if (= 1 (exists "NET:" (noreq)))
       (abort "ParNET läuft noch!\nDeinstallation nicht möglich!")
       )

       (message "Es werden nun alle Files entfernt,\ndie bei der MagicParNET-installation\nauf Ihre Festplatte kopiert wurden.")

       (working) ;Beam me up,Scotty!

       (delete "l:netpnet-handler"  )
       (delete "l:netpitnet-handler")
       (delete "l:mouse-handler"    )
       (delete "devs:parnet.device" )
       (delete "devs:pitnet.device" )
       (delete "envarc:ParNET"      )
       (delete "env:ParNET"         )
       (delete "s:parnet-drivelist" )

       (set mpndir
	(askdir
	   (prompt "Bitte MagicParNET-Schublade\nauswählen")
	   (help @askdir-help)
	   (default "sys:system/magicparnet")
	)
       )

       (if (<> mpndir "")
	   (delete mpndir )
;           (delete "" (force))
       )

       (exit "MagicParNET wurde entfernt." (quiet))
) ;endif deinstall
) ;endif de/in