.key PRVCNF/F,DEBUG/S,NOSRV/S,UMS/S
.bra {
.ket }
;
; "NOSRV" if servers are not used, _nothing_ otherwise
.def NOSRV
.def PRVCNF provider
;
; AmiTCP/IP 4.3 startnet script
;
; Copyright © 1996 AmiTCP/IP Group,
;                  NSDi - Network Solutions Development Inc., Finland
;                  All rights reserved.
;
; *NOTE*  YOU SHOULD NOT NEED TO EDIT ANYTHING BELOW. IF YOU NEED TO START
; *NOTE*  UTILITIES, DO IT IN THE AmiTCP:db/User-Startnet.
; *NOTE*  YOU CAN STOP THESE UTILITIES IN AmiTCP:db/User-Stopnet.
;
; Set the failat level so that the errors can be handled by the script
FailAt 21

If NOT Exists AmiTCP:db/provider.conf
  Echo AmiTCP/IP is not configured
  Echo Starting the configuration tool...
  Stack 20000   ; Installer needs this
  Run >nil: <nil: AmiTCP:bin/Installer SCRIPT "AmiTCP:Config AmiTCP" APPNAME AmiTCP/IP MINUSER AVERAGE
  Quit 20
EndIf

Version bsdsocket.library >nil:
If NOT Warn
  Echo AmiTCP/IP is already running
  Echo Exiting...
  Quit 20
EndIf

Cpu Check 68020 >nil:
If NOT Warn
  If Exists AmiTCP:AmiTCP.020
    If X EQ "X{DEBUG}"
      Run >nil: <nil: AmiTCP:AmiTCP.020 {DEBUG}
    Else
      Run AmiTCP:AmiTCP.020 {DEBUG}
    EndIf
    Skip started
  EndIf
EndIf
If X EQ "X{DEBUG}"
  Run >nil: <nil: AmiTCP:AmiTCP {DEBUG}
Else
  Run AmiTCP:AmiTCP {DEBUG}
EndIf
Lab started
WaitForPort AMITCP
If NOT Warn
  ; Log in with the default user name (ENV:LOGNAME)
  AmiTCP:bin/login -f
  ; Configure AmiTCP, configure lo0 if using servers
  If X EQ "X{NOSRV}"
    Set LOOPBACK LOOPBACK
  Else
    Set LOOPBACK ""
  EndIf
  AmiTCP:bin/bootpconfig PROVIDERFILE=AmiTCP:db/{PRVCNF}.conf $LOOPBACK {DEBUG}
  If NOT Warn
    ;
    ; Mount TCP:
    ;
    Assign TCP: Exists >NIL:
    IF Warn
      Mount TCP: from AmiTCP:devs/Inet-Mountlist
    EndIf
    ;
    ; Start inetd if requested
    ;
    If X EQ "X{NOSRV}"
      If X EQ "X{DEBUG}"
        Run <NIL: >NIL: AmiTCP:bin/inetd
      Else
        Run AmiTCP:bin/inetd {DEBUG}
      EndIf
    EndIf
    ;
    ; Start utilities in AmiTCP:db/User-Startnet
    ;
    If {UMS}
        If Exists AmiTCP:db/User-Startnet
          Execute AmiTCP:db/User-Startnet
        EndIf
    Else
        run amitcp:bin/httpproxy cache eh0:tmp del 5184000 expire 604800 log eh0:uue/Spool/httpproxy.log get unread
    Endif
    ;
    ; Successfull end
    ;
    Echo AmiTCP/IP 4.3 is now on-line. Your host name is $HOSTNAME.
  Else
    Echo Interface {IFACE} configuration failed!
    Echo Stopping AmiTCP
    AmiTCP:bin/stopnet FLUSH
  EndIf
Else
  Echo AmiTCP couldn't be started!
EndIf

; EOF