; Installationsskript für AmiAtlas Pro V1.3
; erstellt für Installer V1.24, 25.3.97, Autor: Andreas Regul

;   Copyright-Hinweise für Installer:

;     Installer and Installer project icon
;     (c) Copyright 1991-93 Commodore-Amiga, Inc. All Rights Reserved.
;     Reproduced and distributed under license from Commodore.

;     INSTALLER SOFTWARE IS PROVIDED "AS-IS" AND SUBJECT TO CHANGE;
;     NO WARRANTIES ARE MADE. ALL USE IS AT YOUR OWN RISK. NO LIABILITY
;     OR RESPONSIBILITY IS ASSUMED.

(set @user-level 2)
(set @language "deutsch")
(set @abort-button "Installation abbrechen")
(set @special-msg "Ein fataler Fehler ist aufgetreten !\nBitte wiederholen Sie die Installation.")
(set @error-msg (cat "'AmiAtlas Pro' wurde nicht komplett installiert. Bitte wiederholen Sie die Installation, "
                     "um eine lauffähige Version auf Ihrer Festplatte zu erhalten."))

(set sysdir (expandpath "SYS:"))
(set owndevice (expandpath ":"))

(complete 0)

(welcome "Willkommen zur Festplatten-Installation von 'AmiAtlas Pro 1.3'.\n")

; Verzeichnis für AmiAtlas Pro wählen
(set mydir
      (askdir
            (prompt "Bitte wählen Sie das Laufwerk für 'AmiAtlas Pro 1.3'")
            (help "\nHilfe zur Laufwerksauswahl\n\n"
                  "Für 'AmiAtlas Pro' wird ein eigenes Verzeichnis auf der Festplatte benötigt. "
                  "Um dieses Verzeichnis anlegen zu können, müssen Sie hier die Festplatte "
                  "angeben, auf der es installiert werden soll (z.B. Work:, DH0:, etc)."
            )
            (newpath)
            (default @default-dest)
            (disk)
      )
)

(set @default-dest (tackon mydir "AmiAtlas"))
(set routedir (tackon @default-dest "Routen"))
(set mapdir (tackon @default-dest "germany"))
(set icondir (tackon @default-dest "Icons"))
(set demodir (tackon @default-dest "Version3.0"))

; Neues Verzeichnis für AmiAtlas Pro erzeugen
(if (NOT (exists @default-dest))
      (makedir @default-dest
            (infos)
      )
      (message "\nHinweis...\n\n"
               "Es existiert schon eine Version von AmiAtlas auf Ihrem System. "
               "Die neue Installation wird alte Dateien von AmiAtlas überschreiben.\n\n"
               "Wenn Sie dies nicht wünschen, brechen Sie bitte an dieser Stelle die "
               "Installation ab. Beim erneuten Starten der Festplatteninstallation "
               "wählen Sie dann ein anderes Verzeichnis.\n")
)

(complete 4)

; Unterverzeichnis für Routen erzeugen
(if (NOT (exists routedir))
      (makedir routedir)
)

(complete 8)

; Programmdateien kopieren
(message "\nProgrammdateien kopieren\n\n"
         "Bitte klicken Sie 'Proceed' an, um die Programmdateien von 'AmiAtlas Pro' "
         "zu installieren.\n\n")

(copyfiles
      (prompt "Kopiere Programmdateien")
      (help "")
      (source "")
      (dest @default-dest)
      (choices "AmiAtlas"
               "AmiAtlas.info"
               "AmiAtlas.countries"
               "AmiAtlas.prefs")
      (optional force askuser)
)

(complete 30)

; Verzeichnis für Vorgabe-Icons erzeugen
(if (NOT (exists icondir))
      (makedir icondir
      )
)

(complete 32)

; Vorgabe-Icons kopieren
(copyfiles
      (prompt "Kopiere Icons")
      (help "")
      (source "Icons")
      (dest icondir)
      (optional force askuser)
      (all)
)

(complete 40)

(if (askbool
            (prompt "\nBeispielrouten kopieren\n\n"
                    "Auf der Diskette zu 'AmiAtlas Pro' befinden sich einige abgespeicherte "
                     "Beispielrouten.\n\n"
                     "Sollen diese Routen kopiert werden ?")
            (help "\nHilfe zu Beispielrouten\n\n"
                  "Die gespeicherten Routen können Sie selbstverständlich auch selber in der "
                  "Dialogbox für die Streckenbestimmung eingeben. Sie sollen nur als Hilfe "
                  "dienen, um zu zeigen, wie abgespeicherte Routendefinitionen aussehen.")
            (choices "Ja" "Nein")
            (default 0)
      )
      (copyfiles
            (prompt "Kopiere Beispielrouten")
            (help "")
            (source "Routen")
            (dest routedir)
            (optional force askuser)
            (all)
      )
)

(complete 45)

; Dokumentation kopieren
(copyfiles
      (prompt "Kopiere Dokumentation")
      (help "")
      (source "")
      (dest @default-dest)
      (choices "Dokumentation1.3.txt"
               "Drucke Doku 1.3"
               "More"
               "PrintOut")
      (optional force askuser)
      (infos)
)

(complete 48)

; Aktuelle Informationen kopieren, wenn diese vorhanden sind
(if (exists "Aktuelle Infos")
      (copyfiles
            (help "")
            (source "")
            (dest @default-dest)
            (choices "Aktuelle Infos")
            (optional force askuser)
            (infos)
      )
)

(complete 50)

; Infos zur Update-Aktion kopieren
(if (exists "UPDATE-AKTION")
      (copyfiles
            (help "")
            (source "")
            (dest @default-dest)
            (choices "UPDATE-AKTION")
            (optional force askuser)
            (infos)
      )
)

(complete 52)

; Bestellprogramm kopieren
(if (exists "Bestellung")
      (copyfiles
            (help "")
            (source "")
            (dest @default-dest)
            (choices "Bestellung")
            (optional force askuser)
            (infos)
      )
)

(complete 54)

; Beispielbild von AmiAtlas 3.0 kopieren
(if (exists "Version3.0")
      (
         (if (NOT (exists demodir))
               (makedir demodir)
         )
         (copyfiles
               (help "")
               (source "Version3.0")
               (dest demodir)
               (optional force askuser)
               (all)
         )
         (copyfiles
               (help "")
               (source "Version3.0.info")
               (dest @default-dest)
               (optional force askuser)
         )
      )
)

(complete 60)

; Verzeichnis für Deutschland-Karte erzeugen
(if (NOT (exists mapdir))
      (makedir mapdir)
)

(complete 65)

; Deutschland-Karte installieren
(copyfiles
      (prompt "Kopiere Deutschland-Karte")
      (help "")
      (source "germany")
      (dest mapdir)
      (optional force askuser)
      (all)
)

(complete 90)

; Assign in user-startup aufnehmen
(set assigncmd (cat "Assign AmiAtlas: \"" @default-dest "\""))

(startup "AmiAtlas"
         (prompt "\nAssign für 'AmiAtlas Pro'\n\n"
                 "Es wird ein Assign in der Datei 'user-startup' benötigt. "
                 "Bitte 'Proceed' anklicken, um diese Ergänzung automatisch "
                 "durchführen zu lassen.\n\n"
                 "Betätigen Sie stattdessen 'Skip this Part', so wird der "
                 "entsprechende Befehl nicht eingefügt. Ergänzen Sie in diesem "
                 "Fall selber die Datei 'user-startup' durch folgenden Befehl:\n\n"
                 "Assign AmiAtlas: <Pfad>")
         (help "\nHilfe zu Assign\n\n"
               "'AmiAtlas Pro' wird über das logische Laufwerk \"AmiAtlas:\" "
               "angesprochen und benötigt deshalb einen Verweis auf "
               "das entsprechende Festplattenverzeichnis. Dieser Verweis "
               "wird beim Amiga in der Datei 'user-startup' durch einen "
               "Assign-Befehl hergestellt. Die Installation kann den "
               "benötigten Befehl selbständig einfügen.")
         (command assigncmd)
)

(complete 100)

(message "\nInstallation beendet\n\n"
         "'AmiAtlas Pro' befindet sich nun im Verzeichnis:\n\n'" (expandpath @default-dest) "'\n\n"
         "Bitte booten Sie Ihren Amiga erneut.")

(exit (quiet))