/*
** SaveAsWAVEFRONT.fred
**
** $VER: SaveAsWAVEFRONT.fred 1.0.0 (29.10.93)
**
** This program can be run from an InvokeADPro list to save images in
** WAVEFRONT format.  Including this program automatically causes a pre script
** to be executed as well (to select the WAVEFRONT file extension).
**
** Clips Imported:
**	FREDWAVEFRONTFNameSelect	-	String describing how the filename
**						should be modified
**	FREDWAVEFRONTSeqFileSelect	-	Name of sequence file created
**
** NOTE: Clip names are case sensitive.
**
** This script requires FRED v1.4.0 (or higher) to run.  Also required is
** ADPro v2.5.0 (or higher) and Professional Conversion Pack v2.5.0
** (or higher).
**
** Copyright © 1993 ASDG, Incorporated
** All Rights Reserved
*/


ADDRESS "ADPro"
OPTIONS RESULTS

PARSE ARG FrameNum FrameFName Length LoadFlag FirstCallSeq FirstCallCell

NL = '0A'X
SQ = '27'X
DQ = '22'X
TRUE  = 1
FALSE = 0

FrameFName = STRIP(STRIP(FrameFName , "B" , " ") , "B" , '"')


/*
** Get the required parameters.  Error if any are missing.
*/

FNameSelect = GETCLIP( "FREDWAVEFRONTFNameSelect" )
IF (FNameSelect = "") THEN DO
	ADPRO_TO_FRONT
	OKAY1 "Required clip, FREDWAVEFRONTFNameSelect," || NL ||,
		"is not specified."
	SCREEN_TO_FRONT "FRED"
	EXIT 10
END

SeqFileSelect = GETCLIP( "FREDWAVEFRONTSeqFileSelect" )
IF (SeqFileSelect = "") THEN DO
	ADPRO_TO_FRONT
	OKAY1 "Required clip, FREDWAVEFRONTSeqFileSelect," || NL ||,
		"is not specified."
	SCREEN_TO_FRONT "FRED"
	EXIT 10
END


/*
** See what type of data is loaded in ADPro/MorphPlus.
*/

CALL "FREDSCRIPTS:FREDFunctions/CheckForRawImageData" TRUE
IF (RESULT ~= 0) THEN
	EXIT 10


/*
** Do the save.  If we aren't using the same filename, we will use the
** same basename and make every effort possible to replace the
** perceived filename extension with the selected WAVEFRONT extension.
*/

CALL "FREDSCRIPTS:FREDFunctions/ModifyFilename" FNameSelect '"'FrameFName'"' FrameNum FALSE
NewFName = '"'RESULT'"'

SAVER "WAVEFRONT" NewFName "RAW"
IF (RC ~= 0) THEN DO
	Why = ADPRO_RESULT
	ADPRO_TO_FRONT
	OKAY1 "WAVEFRONT save failed:" || NL || Why || NL ||,
		"Argument Information:" || NL ||,
		"Filename = " || NewFName || NL ||,
		"Type = " || "RAW"
	SCREEN_TO_FRONT "FRED"
	EXIT 10
END

CALL "FREDSCRIPTS:FREDFunctions/SeqFileAppend" SeqFileSelect NewFName 1

EXIT 0