/*
** SaveAsQRT.fred
**
** $VER: SaveAsQRT.fred 1.1.0 (24.10.93)
**
** This program can be run from an InvokeADPro list to save images in
** QRT format.  Including this program automatically causes a pre script
** to be executed as well (to select the QRT save format).
**
** Clips Imported:
**	FREDQRTFNameSelect	-	String describing how the filename
**					should be modified
**	FREDQRTSeqFileSelect	-	Name of sequence file created
**
** NOTE: Clip names are case sensitive.
**
** This script requires FRED v1.4.0 (or higher) to run.  Also required is
** ADPro v2.5.0 (or higher).
**
** Copyright © 1993 ASDG, Incorporated
** All Rights Reserved
*/


ADDRESS "ADPro"
OPTIONS RESULTS

PARSE ARG FrameNum FrameFName Length LoadFlag FirstCallSeq FirstCallCell

NL = '0A'X
SQ = '27'X
DQ = '22'X
TRUE  = 1
FALSE = 0

FrameFName = STRIP( STRIP( FrameFName, "B", " " ), "B", '"' )


/*
** Get the required clips.  Error if any are missing.
*/

FNameSelect = GETCLIP( "FREDQRTFNameSelect" )
IF (FNameSelect = "") THEN DO
	ADPRO_TO_FRONT
	OKAY1 "Required clip, FREDQRTFNameSelect," || NL ||,
		"is not specified."
	SCREEN_TO_FRONT "FRED"
	EXIT 10
END

SeqFileSelect = GETCLIP( "FREDQRTSeqFileSelect" )
IF (SeqFileSelect = "") THEN DO
	ADPRO_TO_FRONT
	OKAY1 "Required clip, FREDQRTSeqFileSelect," || NL ||,
		"is not specified."
	SCREEN_TO_FRONT "FRED"
	EXIT 10
END


/*
** See what type of data is loaded in ADPro/MorphPlus.
*/

CALL "FREDSCRIPTS:FREDFunctions/CheckForRawImageData" TRUE
IF (RESULT ~= 0) THEN
	EXIT 10

CALL "FREDSCRIPTS:FREDFunctions/CheckForColorImageData" TRUE
IF (RESULT ~= 0) THEN
	EXIT 10


/*
** Do the save.
*/

CALL "FREDSCRIPTS:FREDFunctions/ModifyFilename" FNameSelect '"'FrameFName'"' FrameNum FALSE
NewFName = '"'RESULT'"'

SAVER "QRT" NewFName "RAW"
IF (RC ~= 0) THEN DO
	Why = ADPRO_RESULT
	ADPRO_TO_FRONT
	OKAY1 "QRT save failed:" || NL ||,
		Why || NL || NL ||,
		"Arguments:" || NL ||,
		"Filename = " || NewFName || NL ||,
		"Save Type = " || "RAW"
	SCREEN_TO_FRONT "FRED"
	EXIT 10
END

CALL "FREDSCRIPTS:FREDFunctions/SeqFileAppend" SeqFileSelect NewFName 1

EXIT 0