/*
** SaveAsPCX.fred.pre
**
** $VER: SaveAsPCX.fred.pre 1.4.0 (24.10.93)
**
** If the SaveAsPCX.fred script appears in the InvokeADPro list,
** this program will ask the user to enter the save parameters for the
** IFF'd file.  These parameters will be stuffed into REXX clips.
**
** If they fail to answer, the InvokeADPro list will be aborted.
**
** Clips Exported:
**	FREDPCXSaveType		-	Image type to save
**	FREDPCSSaveOpt		- 	Image save options (CGA,EGA,VGA)
**	FREDPCXFNameSelect	-	String describing how the filename
**					should be modified
**	FREDPCXSeqFileSelect	-	Name of sequence file selected
**
** NOTE: Clip names are case sensitive.
**
** This script requires FRED v1.4.0 (or higher) to run.  Also required is
** ADPro v2.5.0 (or higher).
**
** Copyright © 1993 ASDG, Incorporated
** All Rights Reserved
*/


ADDRESS "ADPro"
OPTIONS RESULTS

PARSE ARG NumberOfCells NumberOfFrames

NL = '0A'X
SQ = '27'X
DQ = '22'X
TRUE  = 1
FALSE = 0


/*
** Ask the user which type of data should be saved out.
*/

ADPRO_TO_FRONT

OKAYN '"SaveAsPCX.fred"' '"Select save data type"' '"Image|Raw|Cancel"'
SaveType = RC

IF (RC = 0) THEN DO
	SCREEN_TO_FRONT "FRED"
	EXIT 10
END
ELSE IF (RC = 1) THEN DO
	SavePCXType = "IMAGE"

	ADPRO_TO_FRONT

	OKAYN '"SaveAsPCX.fred"' '"Select saver option"' '"CGA|EGA|VGA|Cancel"'
	SaveOpt = RC
	IF (RC = 0) THEN DO
		SCREEN_TO_FRONT "FRED"
		EXIT 10
	END
	ELSE IF (RC = 1) THEN
		SavePCXOpt = "CGA"
	ELSE IF (RC = 2) THEN
		SavePCXOpt = "EGA"
	ELSE IF (RC = 3) THEN
		SavePCXOpt = "VGA"
END
ELSE IF (RC = 2) THEN
	SavePCXType = "RAW"


/*
** Specify whether the given filename should be reused for the
** PCX'd filename.
*/

CALL "FREDSCRIPTS:FREDFunctions/ModifyFilenameSelect" '"'".pcx"'"' 4 1 10
FNameSelect = RESULT
IF (RESULT = 10) THEN
	EXIT RESULT

CALL "FREDSCRIPTS:FREDFunctions/SeqFileSelect" SeqFileSelect NewFName 1
SeqFileSelect = RESULT
IF (RESULT = 10) THEN
	EXIT RESULT


/*
** Update the clips.
*/

SETCLIP( "FREDPCXSaveType", SavePCXType )
SETCLIP( "FREDPCXSaveOpt", SavePCXOpt )
SETCLIP( "FREDPCXFNameSelect", FNameSelect )
SETCLIP( "FREDPCXSeqFileSelect", SeqFileSelect )

EXIT 0