/*
** SaveAsJPEG.fred
**
** $VER: SaveAsJPEG.fred 1.3.0 (11.1.94)
**
** This program can be run from an InvokeADPro list to save images in
** JPEG format.  Including this program automatically causes a pre script
** to be executed as well (to select the JPEG quality settings).
**
** Clips Imported:
**	FREDJPEGQuality		-	Quality level of JPEG'd files
**	FREDJPEGFNameSelect	-	String describing how the filename
**					should be modified
**	FREDJPEGSeqFileSelect	-	Name of sequence file created
**
** NOTE: Clip names are case sensitive.
**
** This script requires FRED v1.4.0 (or higher) to run.  Also required is
** ADPro v2.5.0 (or higher).
**
** Copyright © 1992-1994 ASDG, Incorporated
** All Rights Reserved
*/


ADDRESS "ADPro"
OPTIONS RESULTS

PARSE ARG FrameNum FrameFName Length LoadFlag FirstCallSeq FirstCallCell

NL = '0A'X
SQ = '27'X
DQ = '22'X
TRUE  = 1
FALSE = 0

FrameFName = STRIP(STRIP(FrameFName , "B" , " ") , "B" , '"')


/*
** Get the predefined JPEG parameters.  Error if they aren't defined.
*/

Quality = GETCLIP( "FREDJPEGQuality" )
IF (Quality = "") THEN DO
	ADPRO_TO_FRONT
	OKAY1 "Required clip, FREDJPEGQuality," || NL ||,
		"is not specified."
	SCREEN_TO_FRONT "FRED"
	EXIT 10
END

FNameSelect = GETCLIP( "FREDJPEGFNameSelect" )
IF (FNameSelect = "") THEN DO
	ADPRO_TO_FRONT
	OKAY1 "Required clip, FREDJPEGFNameSelect," || NL ||,
		"is not specified."
	SCREEN_TO_FRONT "FRED"
	EXIT 10
END

SeqFileSelect = GETCLIP( "FREDJPEGSeqFileSelect" )
IF (SeqFileSelect = "") THEN DO
	ADPRO_TO_FRONT
	OKAY1 "Required clip, FREDJPEGSeqFileSelect," || NL ||,
		"is not specified."
	SCREEN_TO_FRONT "FRED"
	EXIT 10
END


/*
** See what type of data is loaded in ADPro/MorphPlus.
*/

CALL "FREDSCRIPTS:FREDFunctions/CheckForRawImageData" TRUE
IF (RESULT ~= 0) THEN
	EXIT 10


/*
** Do the save.
*/

CALL "FREDSCRIPTS:FREDFunctions/ModifyFilename" FNameSelect '"'FrameFName'"' FrameNum FALSE
NewFName = '"'RESULT'"'

SAVER "JPEG" NewFName "RAW" "QUALITY" Quality
IF (RC ~= 0) THEN DO
	Why = ADPRO_RESULT
	ADPRO_TO_FRONT
	OKAY1 "JPEG save failed:" || NL || Why
	SCREEN_TO_FRONT "FRED"
	EXIT 10
END

CALL "FREDSCRIPTS:FREDFunctions/SeqFileAppend" SeqFileSelect NewFName 1

EXIT 0