/*
** SimPrint.fred
**
** $VER: SimPrint.fred 1.1.0 (23.10.93)
**
** This program can be run from an InvokeADPro list to run the current
** frame through the Sim_Print operator.
**
** Clips Imported:
**	FREDSimPrintDither	-	Dither to use.
**	FREDSimPrintMaskSize	-	Dither mask size.
**
** NOTE: Clip names are case sensitive.
**
** This script requires FRED v1.4.0 (or higher) to run.  Also required is
** ADPro v2.5.0 (or higher).
**
** Copyright © 1993 ASDG, Incorporated
** All Rights Reserved
*/


ADDRESS "ADPro"
OPTIONS RESULTS

PARSE ARG FrameNum FrameFName Length LoadFlag FirstCallSeq FirstCallCell

NL = '0A'X
SQ = '27'X
DQ = '22'X
TRUE  = 1
FALSE = 0


/*
** Get the required clips.  Error if any are missing.
*/

SimPrintDither = GETCLIP( "FREDSimPrintDither" )
IF (SimPrintDither = "") THEN DO
	ADPRO_TO_FRONT
	OKAY1 "Required clip, FREDSimPrintDither," || NL ||,
		"is not specified."
	SCREEN_TO_FRONT "FRED"
	EXIT 10
END

SimPrintMaskSize = GETCLIP( "FREDSimPrintMaskSize" )
IF (SimPrintMaskSize = "") THEN DO
	ADPRO_TO_FRONT
	OKAY1 "Required clip, FREDSimPrintMaskSize," || NL ||,
		"is not specified."
	SCREEN_TO_FRONT "FRED"
	EXIT 10
END


/*
** See what type of data is loaded in ADPro/MorphPlus.
*/

CALL "FREDSCRIPTS:FREDFunctions/CheckForRawImageData" TRUE
IF (RESULT ~= 0) THEN
	EXIT 10


/*
** Perform the Sim_Print operation.
*/

OPERATOR "SIM_PRINT" SimPrintDither SimPrintMaskSize
IF (RC ~= 0) THEN DO
	Why = ADPRO_RESULT
	ADPRO_TO_FRONT
	OKAY1 "The operator, Sim_Print," || NL ||,
		"failed to execute." || NL ||,
		Why || NL ||,
		"Arguments:" || NL ||,
		"Dither: " || SimPrintDither || NL ||,
		"Mask Size: " || SimPrintMaskSize
	SCREEN_TO_FRONT "FRED"
	EXIT 10
END

EXIT 0