Message-ID: <880711124432.000008B0.AAQT.AA@DGIHRZ01> (UMass-Mailer 4.03)
Date:     Mon, 11 Jul 88  12:44:32 CET
From:     Garry@DGIHRZ01
          (Garry FH Fulda W.Germany)
Subject:  BBAVNF
To:       FYS-MA@fintuvm
 
        ;***********************
        ;* BootBlock AntiVirus *
        ;* against SCA and     *
        ;* ByteBandit          *
        ;*  +    NoFastMem     *
        ;* written 1988 by     *
        ;* Garry Glendown      *
        ;***********************
 
allocmem = -198
mem = $20004
availmem = -216
 
 
        move.l  4,a6                            ; Standardprogram
        lea.l   dosname(pc),a1                  ;
        jsr     -96(a6)
        move.l  d0,a0
        tst.l   d0
        beq.L   err
        move.l  22(a0),a0
        movem.l d0-d7/a0-a6,-(a7)               ; save registers
 
doit:   move.l  #mem,d1                         ; NoFast Routine
        jsr     availmem(a6)                    ; MEMF_LARGESTüMEMF_FAST
        tst.l   d0                              ; >0 ?
        beq.s   EA                              ; no free Mem left
        move.l  #mem,d1                         ;
        jsr     allocmem(a6)                    ; get Mem
        bra.s   doit                            ; once more
 
EA:     move.w  #0,$dff180                      ; Screen black
        move.l  4,a6                            ; ExecBase
        move.l  46(a6),d0                       ; CoolCapture ?
        bne.s   scavir                          ;  used    !
        move.w  148(a6),d0                      ; IntVek[5] = VBI Int.
        cmp.w   #$fc,d0                         ; in the kickstart-mem ?
        bne.s   vir1                            ; no
        move.l  550(a6),d0                      ; KickTagPtr ?
        beq.s   ende                            ; not used !
        vir1:
        bsr.s   maus
        beq.s   ende
        move.l  #0,550(a6)                      ; clear KickTagPtr
        move.l  #0,554(a6)                      ; clear KickCheck
        bra.s   ende                            ; flash Screen
        scavir:
        move.w  #$f00,$dff180                   ; screen red
        move.l  $7ecc4,d0
        cmp.l   #$444f5300,d0                   ; still aktive ?
        bne.s   ende                            ; no
        bsr.s   maus
        beq.s   ende
        move.l  #$01020304,$7ecc4               ; deaktivate
        maus:                                   ; flash screen
        move.w  #$f0,$dff180
        btst    #6,$bfe001                      ; until left or right MB
        beq.s   ende
        move.w  #$f,$dff180
        btst    #6,$bfe001
        beq.s   set
        btst    #2,$dff016
        bne.s   maus
        moveq   #0,d0
        rts
set:    moveq   #1,d0
        rts
 
        ende:
        movem.l (a7)+,d0-d7/a0-a6               ; get Registers
        clr.l   d0
        rts
        err:
        moveq   #-1,d0
        rts
        dosname:
                dc.b    'dos.library',0
        dc.b    '******************************'
        dc.b    ' BootBlock Antivirus & NoFast '
        dc.b    ' 1988 by G.Glendown '
        dc.b    '******************************'