echo off
REM (C) Copyright 1988-1993 by Alan J. Avery, Springfield, Illinois
REM ALL RIGHTS RESERVED
REM
REM This installs ELFTREE in the directory/disk specified.
goto ELFINST
:HELP
cls
echo Correct Usage:
echo     INSTALL (drive) (disk) (directory), where:
echo  (drive) is the drive the floppy is in (A, B)
echo     (NOTE: do not use a colon!)
echo  (disk) is the disk to install to (C, D, E, ...)
echo  (directory) is the directory to install to  (TREE, ELFTREE, etc.)
echo     (NOTE: do not use a beginning backslash!)
echo  Here's an example of how to correctly specify these parameters:
echo     INSTALL  A C TREE
goto exit
:ELFINST
if .%1==. goto HELP
if .%1==.A: goto HELP
if .%1==.a: goto HELP
if .%1==.b: goto HELP
if .%1==.B: goto HELP
if .%2==. goto HELP
REM Switch to disk to copy to.
%2:
if errorlevel 1 goto HELP
REM Switch to the directory to copy this to.
cd \
if .%3==. goto skipmd
if NOT exist %3\NUL md %3
:skipmd
cd %3
REM Copy files needed for program.
cls
echo    Copying program files...
copy %1:\ET.EXE >NUL
echo echo off>ETT.BAT
echo rem  DO NOT DELETE THIS FILE!!!>>ETT.BAT
echo %2:\%3\ET.EXE>>ETT.BAT
copy %1:\ELFTREE.CHL >NUL
copy %1:\ASKET.EXE >NUL
:COPYHELP
echo     Copying auxiliary files...
copy %1:\! >NUL
copy %1:\README.DOC >NUL
copy %1:\ORDER.DOC >NUL
copy %1:\AUTOEXEC.DOC >NUL
if exist MENU.ETU copy %1:\SAMPLE.ETU >NUL
if not exist MENU.ETU copy %1:\SAMPLE.ETU MENU.ETU >NUL
copy %1:\SNOOZE.ELF >NUL
copy %1:\SITELICE.DOC >NUL
copy %1:\VENDOR.DOC >NUL
copy %1:\ELFTREE.HLP >NUL
copy %1:\WHATSNEW.ES >NUL
copy %1:\FEATURES.ET >NUL
copy %1:\ELFTREE.NTE >NUL
copy %1:\DESCRIPT.ION >NUL
copy %1:\TITLES.PF  >NUL
cls
echo		ELFTREE is successfully installed.
echo ÿ
echo		To start it, type: ET   and tap [Enter]
echo ÿ
echo		Please read the files README.DOC and AUTOEXEC.DOC now.
:exit