@Echo off
Cls
Echo  ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
Echo  ³                FROM SCRATCH ZIP FILE UTILITY                         ³
Echo  ³                FOR USE BY VENDORS AND SYSOPS                         ³
Echo  ÃÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ´
Echo  ³ This batch file will create two ZIP files:                           ³
Echo  ³ FSCR21.ZIP     - From Scratch version 2.1 (no conversion pgm)        ³
Echo  ³ FSCNVT21.ZIP   - From Scratch conversion pgm (requires above)        ³
Echo  ³                                                                      ³
Echo  ³ This will allow users to download and/or order diskettes for only    ³
Echo  ³ the files they require.                                              ³
Echo  ³ Either zip file will fit on a single 360K diskette.                  ³
Echo  ³                                                                      ³
Echo  ³ The following assumptions are made:                                  ³
Echo  ³ * PKZIP.EXE is available in your search path.                        ³
Echo  ³ * All the files from the FROM SCRATCH distribution diskette are in   ³
Echo  ³   the current directory.                                             ³
Echo  ³ * You have supplied the destination directory for the .ZIP files,    ³
Echo  ³   i.e. MAKEZIPS C:\ZIPS or MAKEZIPS C:                               ³
Echo  ÃÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ´
Echo  ³                    Press CTRL-C to abort, or                         ³
Echo  ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
Pause
IF A%1A==AA GOTO NOPARAM
IF not exist Scratch.ex_ GOTO NotDefDir
IF exist %1\fscr21.zip DEL %1\FScr21.zip
IF exist %1\fscnvt21.zip DEL %1\fscnvt21.zip
Copy Setup.ini Complete.ini > nul
Copy zip1.ini Setup.ini > nul
Pkzip %1\Fscr21.zip @Fscr21.lst -z < Fscr21.zcm
Copy Read.me Complete.rme > nul
Copy Fscnvt21.rme read.me > nul
Copy File_id.diz Complete.diz > nul
Copy Fscnvt21.diz file_id.diz > nul
Copy zip2.ini Setup.ini > nul
Pkzip %1\FScnvt21.zip @Fscnvt21.lst -z < Fscnvt21.zcm
Copy Complete.rme read.me > nul
Copy Complete.diz File_id.diz > nul
Copy Complete.ini setup.ini > nul
del complete.*
Dir %1\*.zip
Echo Done!
GOTO End
:NoParam
Echo You must supply a destination directory!
Echo i.e. MakeZips \Zips
Echo            or
Echo MakeZips c:
Echo Do not include ending backslash in destination pathname...
GOTO End
:NotDefDir
Echo The From Scratch files are not in the current path!
GOTO End
:End