;************************************************************************
; This Command Post menu file creates a Windows front-end for some of 	*
; the Norton Advanced Utilities version 4.50.				*
;									*
;WHAT?  You DON'T have Command Post, the best custom menu system for	*
;MS Windows?  It's available on finer BBS'es the world over.  Or call	*
;Wilson WindowWare @ (800)762-8383 & order your registered copy today!	*
;************************************************************************
;						Jennifer Palonus  08jun90

; To run CP with this menu alone, run "CMDPOST.EXE NORTON.CPM"
; To run CP with the default menu + this one, modify the "#NextFile"
; statement in CMDPOST to read "#NextFile NORTON.CPM", then re-run
; Command Post.

	WinTitle ("", "The Norton Utilities® from Windows!")
	HTab = Num2Char (09)
	CRLF = strcat(Num2Char(13),Num2Char(10))
        CP   ="CmdPost"

;These menus call The Norton Utilities Advanced Edition ©1987-1989 by Peter Norton.
;Note some of the Norton Utilities not included here will lock up your computer
;if run from within Windows.

&Norton Utilities
 &Find Files
	Title = "Find a File"
	TheFile = askline (Title, "Filename to Find:", FileItemize(""))
	fAll = AskYesNo (Title, "Search all drives?")
	All = strsub("  /A", fAll*2+1, 2)
	Run ("FF.EXE", "%TheFile% %All%")

 &Search for Text
	Title = "Find Text in Files"
	TheFile = strcat (FileItemize (""), " ")
	TheFile = strsub (TheFile, 1, strindex(TheFile, " ", 1, @FWDSCAN)-1)
	IfNot = strsub ("; ", (TheFile=="")+1, 1)
	execute %IfNot% TheFile = AskLine (Title, "Files to search:", "*.*")
	Text = AskLine (Title, "Text to search for:", "")
	Run ("TS.EXE", "%TheFile% ""%Text%"" /T")

 Files with &Attributes
	Title = "List Files with Attributes"
	Attribs = "Archive,Hidden,Read Only,System,[All of the above]"
	TheAt = ItemSelect ("List files with which attributes?", Attribs, ",")
	terminate (TheAt=="", Title, "No attributes selected.")
	TheAt = strsub(TheAt, 1, 1)
	AtTemplate = "[U  AA  HHIDRR  SSYS "
	Attrib = strsub (AtTemplate, strscan (AtTemplate, TheAt, 1, @FWDSCAN)+1, 3)
	Run ("FA.EXE", "/%Attrib%")

 Delete && &Wipe Files
	Title = "Delete & Wipe Files"
	TheFiles = FileItemize ("")
	IfNot = strsub("; ",1+(TheFiles==""),1)
	execute %IfNot% TheFiles = AskLine (Title, "Files to delete", "")
	Terminate (TheFiles=="", Title, "No files selected")
	Run ("Wipefile.EXE", "%TheFiles% /P")

 Disk &Info for This Drive
	Run ("DI.EXE", "")

 Compute &SI Index
	Run ("SI.EXE", "/N")

 _Reset && Start Timer
	Title = "Start Timer"
	RunHide ("TM.EXE", "START")
	Yield
	WinClose ("(Inactive Norton Time Mark)")
	Display (2, Title, "Timer is running.")

 Time Since Last "Start"
	RunZoom ("TM.EXE", "STOP")