; This is the slide show WBT file.
; After a BMP file is displayed, hold the shift key down a second to
; move to the next BMP file

; First we initialize a variable...
Tab=Num2Char(9)

; Then we iconize all windows so we can see the background.

Windows=WinItemize()              ; Get a list of all the Windows
WinCount=ItemCount(Windows,Tab)   ; How many? Windows are delimited by tabs

:winloop
if WinCount==0 then goto winexit  ; No more windows, goto next section
ThisWindow=ItemExtract(WinCount,Windows,Tab) ;Pull out next window name
WinIconize(ThisWindow)            ; And iconize it
WinCount=WinCount-1               ; Decrement counter
goto winloop                      ; Go and do the next window

:winexit
DirChange(FilePath(FileLocate("WIN.INI")))  ; Change to Windows directory
ListOfBmpFiles=FileItemize("*.BMP")         ; Get a list of all BMP files
CurrentBmpNumber=1                          ; Initialize a counter
MaxBmpNumber=ItemCount(ListOfBmpFiles," ")  ; How many BMP files are there?

                                            ; Display instructions
Display(6,"The Wallpaper Show","Press the SHIFT key to move to the next Wallpaper.")

:loop
if CurrentBmpNumber>MaxBmpNumber then Exit   ; Showed them all, byebye
ShowBmpFile=ItemExtract(CurrentBmpNumber,ListOfBmpFiles," ")   ;Get next file
TileTheWallpaper=@FALSE                      ; Take a guess at tiling
if FileSize(ShowBmpFile)<40000 then TileTheWallpaper=@TRUE  
Wallpaper(ShowBmpFile,TileTheWallpaper)      ; Change the wallpaper
currentBmpNumber=CurrentBmpNumber+1          ; Increment counter

:wait
Yield                                        ; Give other apps a chance at CPU
if !IsKeyDown(@SHIFT) then goto wait         ; Is the Shift key down?
goto loop                                    ; Shift Down?  Do next picture