ECHO OFF
IF NOT %1. == ?. GOTO START
ECHO                       RBBS-PC COMPILE UTILITY
ECHO This batch file will help you quickly compile RBBS-PC, should you
ECHO wish to make modifications to the source.  The syntax is:
ECHO ÿ
ECHO %0 [parms]
ECHO ÿ
ECHO If you do not specify any parameters, %0 will compile ALL RBBS-PC
ECHO source modules, then link them into RBBS-PC.EXE.  If you specify one
ECHO or more parameters, %0 will compile only the modules you specify,
ECHO and will then link them.  To specify modules, use the following
ECHO number(s) separated by a space:
ECHO ÿ
ECHO   MODULE       NUMBER     MODULE       NUMBER
ECHO   RBBS-PC.BAS    0        RBBSSUB3.BAS   3
ECHO   RBBSSUB1.BAS   1        RBBSSUB4.BAS   4
ECHO   RBBSSUB2.BAS   2        RBBSSUB5.BAS   5
ECHO ÿ
ECHO NOTE: Results of each compile will be saved in the file $$RBBS.TXT.
ECHO
ECHO THIS FILE IS CONFIGURED FOR QB 3.0 - SEE COMMANDS FOR QB 4.5 CHANGES!
GOTO EXIT
:START
IF EXIST $$RBBS.TXT DEL $$RBBS.TXT
if %1. == 0. GOTO RBBSCOMP
if %1. == 1. GOTO SB1COMP
if %1. == 2. GOTO SB2COMP
if %1. == 3. GOTO SB3COMP
if %1. == 4. GOTO SB4COMP
if %1. == 5. GOTO SB5COMP
ECHO COMPILING ALL MODULES...
:RBBSCOMP
ECHO Errors while compiling RBBS-PC.BAS include: >> $$RBBS.TXT
QB RBBS-PC.BAS /C:4096 /O/E/S; >> $$RBBS.TXT
REM FOR QB4.5, USE: BC RBBS-PC.BAS /C:4096 /O/E/S/MBF; >> $$RBBS.TXT
IF %1. == 0. GOTO LOOP
:SB1COMP
ECHO Errors while compiling RBBSSUB1.BAS include: >> $$RBBS.TXT
QB RBBSSUB1.BAS /X /O; >> $$RBBS.TXT
REM FOR QB4.5, USE: BC RBBSSUB1.BAS /X /O /MBF; >> $$RBBS.TXT
IF %1. == 1. GOTO LOOP
:SB2COMP
ECHO Errors while compiling RBBSSUB2.BAS include: >> $$RBBS.TXT
QB RBBSSUB2.BAS /O/E; >> $$RBBS.TXT
REM FOR QB4.5, USE: BC RBBSSUB2.BAS /O/E/MBF; >> $$RBBS.TXT
IF %1. == 2. GOTO LOOP
:SB3COMP
ECHO Errors while compiling RBBSSUB3.BAS include: >> $$RBBS.TXT
QB RBBSSUB3.BAS /O/E; >> $$RBBS.TXT
REM FOR QB4.5, USE: BC RBBSSUB3.BAS /O/E/MBF; >> $$RBBS.TXT
IF %1. == 3. GOTO LOOP
:SB4COMP
ECHO Errors while compiling RBBSSUB4.BAS include: >> $$RBBS.TXT
QB RBBSSUB4.BAS /O/E; >> $$RBBS.TXT
REM FOR QB4.5, USE: BC RBBSSUB4.BAS /O/E/MBF; >> $$RBBS.TXT
IF %1. == 4. GOTO LOOP
:SB5COMP
ECHO Errors while compiling RBBSSUB5.BAS include: >> $$RBBS.TXT
QB RBBSSUB5.BAS /O/E; >> $$RBBS.TXT
REM FOR QB4.5, USE: BC RBBSSUB5.BAS /O/E/MBF; >> $$RBBS.TXT
IF %1. == 5. GOTO LOOP
:LOOP
IF %2. == . GOTO LINKIT
SHIFT
GOTO START
:LINKIT
LINK @RBBSQB3.LNK
REM FOR QB4.5, USE: LINK @RBBSQB45.LNK
TYPE $$RBBS.TXT
:EXIT