(*----------------------------------------------------------------------*)
(*      Update_Kermit_Display --- Update display of Kermit transfer     *)
(*----------------------------------------------------------------------*)

PROCEDURE Update_Kermit_Display;

BEGIN (* Update_Kermit_Display *)

   IF ( NOT Logging_Out_Server ) THEN
      BEGIN

         GoToXY( 25 , 1 );
         IF Sending_File THEN
            WRITE( Packets_Sent : 8 )
         ELSE
            WRITE( Packets_Received : 8 );

         GoToXY( 25 , 2 );
         WRITE( Buffer_Num : 8 : 0 );

         GoToXY( 25 , 3 );
         WRITE( Packets_Bad : 8 );

      END;

END   (* Update_Kermit_Display *);

(*----------------------------------------------------------------------*)
(*  Display_Kermit_Message --- Display Kermit reception status message  *)
(*----------------------------------------------------------------------*)

PROCEDURE Display_Kermit_Message( Status_Text: AnyStr );

BEGIN (* Display_Kermit_Message *)

   Update_Kermit_Display;

   GoToXY( 25 , 5 );
   WRITE( Status_Text );
   ClrEol;

END   (* Display_Kermit_Message *);

(*----------------------------------------------------------------------*)
(*  Display_Kermit_Init_Params --- Display Kermit init. parameters      *)
(*----------------------------------------------------------------------*)

PROCEDURE Display_Kermit_Init_Params;

VAR
   Quote_8: CHAR;

BEGIN (* Display_Kermit_Init_Params *)

   GoToXY( 2 , 7 );
   WRITE('8th bit quoting is ');

   IF Sending_File THEN
      Quote_8 := Kermit_Quote_8_Char
   ELSE
      Quote_8 := His_Quote_8_Char;

   IF Quoting THEN
      WRITE('ON using <',Quote_8,'>')
   ELSE
      WRITE('OFF');

   ClrEol;

   GoToXY( 2 , 8 );
   WRITE('Block check is ');

   CASE His_Chk_Type OF
      '1':  WRITE('1 character checksum');
      '2':  WRITE('2 character checksum');
      '3':  WRITE('3 character CRC');
   END (* CASE *);

   ClrEol;

END   (* Display_Kermit_Init_Params *);