;script to install Ami-Back Plus Tools

(complete 0)

;Get directory to install Ami-Back Plus Tools in.
(set destdir 
	(askdir 
		(prompt "In which drawer should Ami-Back Plus Tools be installed?") 
		(help @askdir-help)
		(default (tackon @default-dest "Tools"))
	)
)

(set vernum (getversion))
(set ver (/ vernum 65536))
(set rev (- vernum (* ver 65536) ) )

;Get the WB version that sould be installed.
(if (> @user-level 1)
 (
	(set abversion
		(askchoice
			(prompt "Which version of workbench should Ami-Back Plus Tools be installed for:\n")
			(choices "1.3 Version" "2.0 Version")
			(default (> ver 36))
			(help "The 1.3 version of Ami-Back will run under WB 1.3 or WB 2.0. "
				  "The 2.0 version supports the additional features of WB 2.0 such "
				  "as links and faster directory scanning. ABTools will run under either "
				  "version of workbench, but both require the 1.3 libraries to be "
				  "installed to work under WB 1.3"
			)
		)
	)
	
	(if (> abversion 0)
	 (
		(set ver 37)
	 )
	 (
		(set ver 34)
	 )
	)
 )
)

(complete 10)

;Determine system version and copy appropriate libraries.
(if (> ver 36)
 (
	(copylib 
		(source "AB+Tools Disk 1:Libs2.0/amigaguide.library")
		(dest "LIBS:")
	)
 )
 (
	(copylib 
		(source "AB+Tools Disk 1:Libs1.3/gadtools13.library")
		(dest "LIBS:")
	)
	(copylib 
		(source "AB+Tools Disk 1:Libs1.3/asl13.library")
		(dest "LIBS:")
	)
 )
)

(complete 30)

;Copy AmigaGuide files to destination.
(if (> ver 36)
 (
	(copyfiles
		(source "AB+Tools Disk 1:S")
		(dest "S:")
		(all)
	)
 )
)

(complete 40)

;Copy ABTools program file to destination.
(copyfiles
	(source "AB+Tools Disk 1:ABTools")
	(dest destdir)
	(infos)
)

;Copy Ami-Sched II to destination.
(if (> ver 36)
 (
	(copyfiles
		(source "AB+Tools Disk 1:Ami-SchedII")
		(dest destdir)
		(infos)
	)
 )
)

(copyfiles
	(source "AB+Tools Disk 1:C/Person")
	(dest "RAM:")
)

(askdisk 
	(prompt "\nInsert Ami-Back Plus Tools Disk 2") 
	(dest "AB+Tools Disk 2")
	(help @askdisk-help)
	(newname "Disk2")
)

;Copy Ami-Back programs.
(if (> ver 36)
 (
	(copyfiles
		(source "Disk2:Ami-Back20")
		(dest destdir)
		(infos)
	)
	
	(set aboffset 215058)
	(set abname "Ami-Back20")
 )
 (
	(copyfiles
		(source "Disk2:Ami-Back13")
		(dest destdir)
		(infos)
	)
	(copyfiles
		(source "Disk2:Ami-Sched13")
		(dest destdir)
		(infos)
	)
	(set aboffset 217234)
	(set abname "Ami-Back13")
 )
)

(complete 90)

;Personalize the two programs.

(set pname
	(askstring 
		(prompt "What is your name?") 
		(help "You must enter your name or company name so that your copy of Ami-Back Plus Tools can be personalized.")
	)
)

(set pserial
	(askstring
		(prompt "What is your serial number?") 
		(help "You can find your serial number on the front of you Ami-Back Plus Tools master disk.")
	)
)

(run ('\"%s\"' "RAM:Person" )
	('\"%s\"'
		(tackon destdir "ABTools")
	)	

	('\"%s\"'
		pname
	)
	
	pserial
	
	238020
)

(run ('\"%s\"' "RAM:Person" )
	('\"%s\"'
		(tackon destdir abname)
	)	

	('\"%s\"'
		pname
	)
	
	pserial
	
	aboffset
)

(delete "RAM:Person")

;Correct @default-dest so that final information is correct.
(set @default-dest destdir)

(complete 100)

(exit)