incdir	System:includes/

	include	lvo3.0/Exec_lib.i
	include	lvo3.0/Intuition_lib.i
	include	lvo3.0/graphics_lib.i
	include	intuition/intuition.i
	include	intuition/screens.i

WindowIDCMP	equ		CLOSEWINDOW
WindowFlags	equ		WFLG_CLOSEGADGET!WFLG_DRAGBAR!WFLG_DEPTHGADGET!WFLG_SMART_REFRESH!WFLG_ACTIVATE


j	bsr	OpenLibs			; megnyitjuk a library-kat
	bsr	OpenWindow			; kinyitjuk az ablakot
	bsr	DrawToWindow			; rajzolunk az ablakba
	bsr	Main				; várunk hogy bezárják
	bsr	CloseWindow			; bezárjuk az ablakot
	bsr	CloseLibs			; ..és a library-ket is
	rts					; viszlát!

DrawToWindow
	move.l	WinBase,a0
	move.l	wd_RPort(a0),RPort		; kiolvassuk a RastPort címét

	bsr	PrintText			; a szöveg kiírása
	bsr	PutBorder			; a border kirakása
	bsr	PutImage			; a rajz kirakása

	rts

PrintText
	move.l	IntBase,a6
	move.l	RPort,a0
	lea	IText,a1
	moveq	#50,d0
	moveq	#50,d1
	jsr	_LVOPrintIText(a6)
	rts

PutBorder
	move.l	IntBase,a6
	move.l	RPort,a0
	lea	MyBord,a1
	moveq	#40,d0
	moveq	#40,d1
	jsr	_LVODrawBorder(a6)
	rts

PutImage
	move.l	IntBase,a6
	move.l	RPort,a0
	lea	MyImage,a1
	moveq	#50,d0
	moveq	#70,d1
	jsr	_LVODrawImage(a6)
	rts

Main	move.l	4.w,a6
	move.l	WinBase,a0
	move.l	wd_UserPort(a0),a0

	jsr	_LVOGetMsg(a6)
	tst.l	d0
	beq	Main

	move.l	d0,a0
	move.l	im_Class(a0),d7
	move.l	a0,a1
	jsr	_LVOReplyMsg(a6)

	cmpi.l	#IDCMP_CLOSEWINDOW,d7
	bne.s	Main

	rts

OpenWindow
	move.l	IntBase,a6
	lea	NewWindow0,a0
	jsr	_LVOOpenWindow(a6)		; kinyitjuk az ablakot
	move.l	d0,WinBase
	rts

CloseWindow
	move.l	IntBase,a6
	tst.l	WinBase
	beq	ok1
	move.l	WinBase,a0
	jsr	_LVOCloseWindow(a6)		; becsukjuk az ablakot
ok1	rts

OpenLibs
	move.l	4.w,a6
	lea	IntName,a1
	jsr	_LVOOldOpenLibrary(a6)
	move.l	d0,IntBase

	lea	GFXName,a1
	jsr	_LVOOldOpenLibrary(a6)
	move.l	d0,GFXBase

	rts

CloseLibs
	move.l	4.w,a6
	move.l	IntBase,a1
	jsr	_LVOCloseLibrary(a6)

	move.l	GFXBase,a1
	jsr	_LVOCloseLibrary(a6)

	rts

IntName			dc.b	`intuition.library`,0
GFXName			dc.b	`graphics.library`,0
WinTitle		dc.b	"My Own window..",0
MyText			dc.b	"Ez itt egy IntuiText",0
MyFont			dc.b	"topaz.font",0
			even
IntBase			dc.l	0
GFXBase			dc.l	0
WinBase			dc.l	0
RPort			dc.l	0

MyTextAttr		dc.l	MyFont			; a font neve
			dc.w	8			; mérete
			dc.b	0,0			; flagek

NewWindow0		dc.w	70,28,350,160
			dc.b	1,3
			dc.l	WindowIDCMP,WindowFlags
			dc.l	0,0,WinTitle
			dc.l	0,0
			dc.w	50,40,30,20,WBENCHSCREEN

IText			dc.b	1,0			; színek
			dc.b	0,0			; rajzmód
			dc.w	0,0			; x,y
			dc.l	MyTextAttr		; textattr
			dc.l	MyText			; szöveg
			dc.l	0			; nincs következő

MyBord			dc.w	0,0			; x,y
			dc.b	2,0,0			; színek, rajzmód
			dc.b	3			; pontok
			dc.l	MyCoords0		; koordináták
			dc.l	MyBord1			; következő a fekete
							; rész a 3d-s keretben
MyBord1			dc.w	0,0			; x,y
			dc.b	1,0,0			; színek, rajzmód
			dc.b	3			; pontok
			dc.l	MyCoords1		; koordináták
			dc.l	0			; nincs több

MyCoords0		dc.w	0,80
			dc.w	0,0
			dc.w	200,0

MyCoords1		dc.w	200,0
			dc.w	200,80
			dc.w	0,80

MyImage			dc.w	0,0			; x,y
			dc.w	32,16,1			; méret, mélység
			dc.l	ImageData		; a rajz
			dc.b	%01,%10
; a rajz egyetlen plane-jét a 0. plane-re tesszük, az 1-esre meg megy a
; fillezés
			dc.l	0			; nincs több

ImageData		dc.l	%11111111111111111111111111111111
			dc.l	%11000000000000000000000000000011
			dc.l	%11000000000000000000000000000011
			dc.l	%11000000000000000000000000000011
			dc.l	%11000000000000000000000000000011
			dc.l	%11000000000000000000000000000011
			dc.l	%11000000000000000000000000000011
			dc.l	%11000000000000000000000000000011
			dc.l	%11000000000000000000000000000011
			dc.l	%11000000000000000000000000000011
			dc.l	%11000000000000000000000000000011
			dc.l	%11000000000000000000000000000011
			dc.l	%11000000000000000000000000000011
			dc.l	%11000000000000000000000000000011
			dc.l	%11000000000000000000000000000011
			dc.l	%11111111111111111111111111111111