;
; Skript zur Installation von pnmview_grf 1.16
; Version 1.00, 22.04.98
; (c) 1998 Stefan Diener
;

(set @pretend 0)
(set @user-level 2)
(set @default-dest "")

(complete 0)

(if (= @language "deutsch")
 (
   ; deutsche Textausgaben
   (set #yes "Ja")
   (set #no "Nein")
   (set #gruss "\n\n\n\npnmview_grf 1.16\n© 1997/98 by Stefan Diener\n\n\nWillkommen zur Installation von pnmview_grf 1.16 !\nDieses Skript wird pnmview_grf auf Ihrer Festplatte installieren.\n")
   (set #destimsg "Wo wollen Sie pnmview_grf installieren ?\n(Ein Verzeichnis namens STIMP wird dort automatisch erzeugt.)")
   (set #addlines "\nZwei Zeilen müssen zur Datei S:User-Startup hinzugefügt werden:\n")
   (set #fertig "\n\npnmview_grf ist nun auf Ihrer Festplatte in folgendem\nVerzeichnis installiert:\n")
   (set #whichcpu "\n\n\nDiese Shareware-Version enthält nur eine\nunoptimierte 68000er Version.\n\nOptimierte Versionen sind für registrierte Benutzer verfügbar.")
   (set #ultraconv "\nUltraconv3-Unterstützung:\n\nErgänzen Sie in der Datei 'UConv:Ultraconv.info'\nfolgende Zeile, um pnmview_grf als voreingestellten\nAnzeiger für Previews zu verwenden:\n\nPREVVIEWER=STIMP:bin/pnmview -2 %f\n\n(Alle anderen Zeilen, die den Tooltype PREVVIEWER\nenthalten, müssen eingeklammert werden !!!)")
   (set #library "\npnmview_grf benötigt die graffiti.library ...\n")
 )
 (
   ; english text output
   (set #yes "Yes")
   (set #no "No")
   (set #gruss "\n\n\n\npnmview_grf 1.16\n© 1997/98 by Stefan Diener\n\n\nWelcome to the pnmview_grf 1.16 installation !\nThis script will install pnmview_grf on your harddisk.\n")
   (set #destimsg "Where do you want to install pnmview_grf ?\n(A directory called STIMP will be automaticly created.)")
   (set #addlines "\nTwo lines have to be added to your S:User-Startup:\n")
   (set #fertig "\n\npnmview_grf is now installed on your harddisk at:\n")
   (set #whichcpu "\n\n\nThis shareware version contains an unoptimized\nexecuteable for 68000 only.\n\nOptimized versions are available for registered users.")
   (set #ultraconv "\nUltraconv3 support:\n\nAdd the following line to the file 'UConv:Ultraconv.info'\nto install pnmview_grf as default preview program:\n\nPREVVIEWER=STIMP:bin/pnmview -2 %f\n\n(All other lines including the tooltype PREVVIEWER\nhave to be in clauses !!!)")
   (set #library "\npnmview_grf needs the graffiti.library ...\n")
 )
)

; kleine Begruessung
(message #gruss
)

; Zielpfad ermitteln
(set #destidir
  (askdir
    (prompt #destimsg)
    (help @askdir-help)
    (default "GFX:")
  )
)

(complete 15)

(set #dstdir
  (tackon #destidir "STIMP")
)

; ggf. Verzeichnis fuer STIMP erst erzeugen
(if (= (exists #dstdir) 0)
 (makedir #dstdir)
)

(complete 25)

; alle Pfade definieren
(set #binpath
  (tackon #dstdir "bin")
)

(set #docpath
  (tackon #dstdir "doc")
)

(set #helppath
  (tackon #dstdir "help")
)

; leider nur 68000er Variante verfuegbar
(message #whichcpu
)

(complete 30)

; Dokumentation kopieren
(copyfiles
  (source "doc")
  (dest #docpath)
  (pattern "#?")
)

(complete 45)

; Help-Dateien kopieren
(copyfiles
  (source "help")
  (dest #helppath)
  (pattern "#?")
)

(complete 60)

; Programm selbst kopieren
; nur 68000
(copyfiles
  (source "bin")
  (dest #binpath)
  (pattern "#?")
)

(complete 70)

(set #linetoadd1
  (cat "Assign STIMP: " #dstdir)
)

(set #linetoadd2 "Assign C: STIMP:bin add")

; Assign-Zeilen in S:User-Startup einfuegen
(startup "STIMP"
  (prompt #addlines
          #linetoadd1 "\n"
          #linetoadd2)
  (help "These lines have to be added in order to make the STIMP programs run properly !")
  (command #linetoadd1 "\n" #linetoadd2)
)

; auch jetzt schon Assign wirksam werden lassen
(makeassign "STIMP" #dstdir)

; Hier muesste stehen: "Assign C: STIMP:bin add".
; Stattdessen wird ein kleines Shell-Skript
; aufgerufen -> umstaendlich, aber noetig ...
(execute "Assign.Skript")

(complete 80)

; graffiti.library kopieren
(copylib
  (prompt #library)
  (help "This library is REALLY needed for pnmview_grf !!!")
  (source "libs/graffiti.library")
  (dest "LIBS:")
  (confirm)
)

(complete 95)

; Hinweis zu Ultraconv3
(message #ultraconv
)

(complete 100)

; das war es schon -> Verabschiedung
(message #fertig #dstdir "\n\n\nHave fun !"
)