;               *******************************************
;               ****                                   ****
;               ****                xFX                ****
;               **** Multilanguage Installation Script ****
;               ****    © 1997, Alessandro Pedretti    ****
;               ****                                   ****
;               *******************************************


;           $VER:xFX_Install 1.0 (27.7.97) Alessandro Pedretti



;
; Seleziona il linguaggio (default: inglese)
;

(set #DefLang		0)
(set #DefDoc		0)
(if (= @language "italiano")
  (set #DefLang		1)
)
(if (= @language "deutsch")
  (set #DefLang		2)
)

(select #DefLang

; Inglese

  ((set #DefDoc		0)
   (set #ARexxTxt	"Do you want install ARexx scripts ?")
   (set #DirTxt		"Select the directory where the xFX drawer will be created.")
   (set #LangTxt	"Please select your preferred language documentation")
   (set #LangHelpTxt	"You must specify your language.")
  )

; Italiano

  ((set #DefDoc		1)
   (set #ARexxTxt	"Vuoi installare gli scripts ARexx ?")
   (set #DirTxt		"Selezionare la directory dove verrà creato il cassetto xFX.")
   (set #LangTxt	"Selezionare il linguaggio per la documentazione")
   (set #LangHelpTxt	"E' necessario specificare un linguaggio.")
  )

; Tedesco

  ((set #DefDoc		0)
   (set #ARexxTxt	"Wollen Sie die ARexx Scripts installiren ?")
   (set #DirTxt		"Bitte wählen Sie einen Platz für xFX. Ein Verzeichnis namens 'xFX' wird dort automatisch erzeugt.")
   (set #LangTxt	"Bitte wählen Sie die Sprache für die Dokumentation aus.")
   (set #LangHelpTxt	"Sie wählen die Sprache für die Dokumentation aus.")
  )
)


;
; Seleziona la directory di xFX.
;

(complete 20)
(set xFXDir
  (askdir
    (prompt #DirTxt)
    (help @askdir-help)
    (default "SYS:")
    (newpath)
  )
)
(set xFXDir(tackon xFXDir "xFX"))
(set @default-dest xFXDir)


;
; Linguaggio della documentazione
;

(complete 40)
(set DocLang
  (select 
    (askchoice
      (prompt #LangTxt)
      (help #LangTxtHelp)
      (choices "English" "Italiano")
      (default #DefDoc)
    )
    "xFX-Eng.guide" "xFX-Ita.guide"
  )
)
(set DocLang (cat "Docs/" DocLang))

;
; Copia i files
;

(complete 60)

(copyfiles
  (source "")
  (help	@copyfiles-help)
  (infos)
  (dest	@default-dest)
  (choices "xFX"
           "Docs/GuiX_Preview"
  )
)

(complete 70)

(copyfiles
  (source DocLang)
  (help	@copyfiles-help)
  (infos)
  (dest	@default-dest)
  (newname "xFX.guide")
)

;
; Scripts ARexx
;

(complete 80)
(if (askbool (prompt #ARexxTxt) (help @askbool-help))
  (copyfiles
    (source "")
    (help @copyfiles-help)
    (infos)
    (dest @default-dest)
    (choices "ARexx")
  )
)

(complete 100)