;
; $VER: MPLS Patch Install v1.85 (27.08.96) Lejardinier Olivier
; Copyright © 1995-96 Lejardinier Olivier
; All Rights Reserved.
;

;***************************************************************************;

;
; English texts
;

(set #bad-amigados-version
(cat "\n"
     "Sorry, this program required AmigaDOS v2.0"
     " or above (v37+)."
))

(set #choice-yes "Yes")

(set #choice-no  "No")

(set #choice-continue "Continue")

(set #ask-language-to-use
(cat "\n"
     "In which language do you want to use MPLS Patch ?"
     "\n"
))

(set #english "English")

(set #french "French")

(set #installing-file
(cat "\n"
     "Installing '%s'"
     "\n"
))

(set #destination-invalid
(cat "\n"
     "You can not use '%s' as destination !"
))

(set #install-intro
(cat "\n"
     "MPLS Patch v1.85 (27.08.96) - SHAREWARE"
     "\n\n"
     "- The (M)agic (P)icture (L)oader (S)ystem -"
     "\n"
     "Copyright © 1995-96 Lejardinier Olivier"
     "\n"
     "All Rights Reserved"
     "\n\n"
     "This program allows any application to handle new"
     " file formats.                                   "
     "\n\n\n"
     "Please, read the (french, sorry) documentation to get"
     " more informations.                                  "
))

(set #beginners-warning
(cat "\n"
     "- NOTE TO BEGINNERS -"
     "\n\n"
     "If you are not an expert with installation procedure,"
     " please always answer 'Yes' or 'Continue' to questions"
     " whose will be ask to you."
))

(set #ask-install-parts
(cat "\n"
     "Select items that you want to install :"
     "\n"
))

(set #old-version-exists
(cat "\n"
     "A previous MPLS Patch version has been installed "
     "in your system."
     "\n\n"
     "To install correctly this update you should used "
     "the same directories than during the last installation"
))

(set #old-main-program-in-wbstartup
(cat "\n"
     "A previous MPLS Patch version of the main program "
     "has been installed in directory 'SYS:WBStartup'."
     "\n\n"
     "Do you want to use this same directory as destination "
     "for the new main program ?"
))

(set #ask-installing-in-wbstartup
(cat "\n"
     "Do you want to run MPLS Patch every time"
     " you reboots your Amiga ?"
))

(set #old-version-path
(cat "\n"
     "A previous MPLS Patch version has been installed "
     "into directory '%s'."
     "\n\n"
     "I suggest you to install this update into it."
))

(set #ask-patch-destination
(cat "\n"
     "Where do you want to install MPLS Patch ?"
     "\n"
     "(A directory named 'MPLS_Patch' will be created)"
     "\n"
))

(set #unarchiving-main-program "Please wait, unarchiving main program...")

(set #installing-main-program
(cat "\n"
     "Installing main program"
     "\n"
))

(set #remove-QUIET-brackets
(cat "\n"
     "To deactivate request 'Patch installed' "
     "you should remove the brackets from the "
     "QUIET tooltype."
))

(set #unarchiving-mpls_patch-library "Please wait, unarchiving 'mpls_patch.library'...")

(set #unarchiving-loaders-modules "Please wait, unarchiving loaders modules...")

(set #installing-loader-module
(cat "\n"
     "Installing '%s' loader module"
     "\n"
))

(set #ask-others-files-dest
(cat "\n"
     "Where do you want to install others files ?"
     "\n"
     "(A directory named 'MPLS_Patch' will be created)"
     "\n"
))

(set #unarchiving-language-files "Please wait, unarchiving language files...")

(set #installing-language-file
(cat "\n"
     "Installing language file"
     "\n"
))

(set #old-config-exists
(cat "\n"
     "An old configuration file has been found :"
     "\n"
))

(set #install-config-use-old "Use old.")

(set #install-config-new-delete-old "Install new, delete old.")

(set #install-config-new-backup-old "Install new, backup old.")

(set #old-config-renamed
(cat "\n"
     "Old configuration file has been renamed to :"
     "\n\n"
     "'ENVARC:MPLS_Patch.Prefs-Bak'"
))

(set #ask-cx_popkey
(cat "\n"
     "Hotkey to show controls panel :"
     "\n"
))

(set #ask-cx_statekey
(cat "\n"
      "Hotkey to activate/deactivate patch :"
      "\n"
))

(set #ask-tempdir_path
(cat "\n"
     "Select a temporary directory :"
     "\n"
))

(set #ask-history-capacity
(cat "\n"
     "Enter history files maximal capacity :"
     "\n"
))

(set #ask-install-prefs-program
(cat "\n"
     "Do you want to install the preferences editor program ?"
     "\n\n"
     "NOTE : This program needs MUI v3.3 or higher to run"
))

(set #ask-prefs-program-dest
(cat "\n"
     "Where do you want to install preferences editor program ?"
     "\n"
))

(set #unarchiving-prefs-program "Please wait, unarchiving preferences editor program...")

(set #installing-prefs-program
(cat "\n"
     "Installing preferences editor program"
     "\n"
))

(set #install-completed
(cat "\n"
     "To start MPLS Patch now, double-click on his icon in"
     " directory '%s'"
     "\n\n"
     "IMPORTANT : If you are a registered user, do not forget"
     " to install your keyfile before using MPLS Patch."
))

;***************************************************************************;

;
; French texts
;

(if (= @language "français")
(
(set #bad-amigados-version
(cat "\n"
     "Désolé, l'AmigaDOS 2.0 ou supérieur est nécessaire"
     " pour utiliser ce programme"
))

(set #choice-yes "Oui")

(set #choice-no "Non")

(set #choice-continue "Continuer")

(set #ask-language-to-use
(cat "\n"
     "Dans quelle langue voulez-vous utiliser MPLS Patch ?"
     "\n"
))

(set #english "Anglais")

(set #french "Français")

(set #installing-file
(cat "\n"
     "Installation de '%s'"
     "\n"
))

(set #destination-invalid
(cat "\n"
     "Vous ne pouvez pas utiliser '%s' comme destination !"
))

(set #install-intro
(cat "\n"
     "MPLS Patch v1.85 (27.08.96) - SHAREWARE"
     "\n\n"
     "- The (M)agic (P)icture (L)oader (S)ystem -"
     "\n"
     "Copyright © 1995-96 Lejardinier Olivier"
     "\n"
     "All Rights Reserved"
     "\n\n"
     "Ce programme permet à n'importe quelle application de gérer"
     " des nouveaux formats de fichiers.                   "
     "\n\n\n"
     "Consultez la documentation pour obtenir plus d'informations."
))

(set #beginners-warning
(cat "\n"
     "- NOTE AUX DEBUTANTS -"
     "\n\n"
     "Si vous n'êtes pas trés habitué aux procédures d'installation,"
     " répondez 'Oui' ou 'Continuer' aux questions qui vous seront"
     " posées."
))

(set #ask-install-parts
(cat "\n"
     "Sélectionnez les éléments que vous voulez installer :"
     "\n"
))

(set #old-version-exists
(cat "\n"
     "Une précédente version de MPLS Patch a étét installé"
     " dans votre système."
     "\n\n"
     "Pour installer correctement cette mise à jour, je vous"
     " conseille d'utiliser les mêmes répertoire que ceux"
     " qui ont été utilisé lors de cette précédente installation."
))

(set #old-main-program-in-wbstartup
(cat "\n"
     "Une précédente version du programme principal de MPLS Patch"
     " a été trouvé dans le répertoire 'SYS:WBStartup'."
     "\n\n"
     "Voulez-vous utiliser ce même répertoire pour y installer cette"
     " nouvelle version ?"
))

(set #ask-installing-in-wbstartup
(cat "\n"
     "Voulez-vous que MPLS Patch soit actif à chaque redémarrage"
     " de votre Amiga ?"
))

(set #old-version-path
(cat "\n"
     "Une précédente version de MPLS Patch a été installé dans le"
     " répertoire '%s'."
     "\n\n"
     "Je vous suggère d'y installer cette mise à jour."
))

(set #ask-patch-destination
(cat "\n"
     "Où voulez-vous installer MPLS Patch ?"
     "\n"
     "(un répertoire 'MPLS_Patch' y sera créé)"
     "\n"
))

(set #unarchiving-main-program "Patientez SVP, désarchivage du programme principal...")

(set #installing-main-program
(cat "\n"
     "Installation du programme principal"
     "\n"
))

(set #remove-QUIET-brackets
(cat "\n"
     "Pour désactiver la requête 'Patch installé'"
     " vous devrez retirer les () autour du tooltype QUIET"
))

(set #unarchiving-mpls_patch-library "Patientez SVP, désarchivage de 'mpls_patch.library'...")

(set #installing-mpls_patch-library
(cat "\n"
     "Installation de 'mpls_patch.library'"
     "\n"
))

(set #unarchiving-loaders-modules "Patientez SVP, désarchivage des modules de chargement...")

(set #installing-loader-module
(cat "\n"
     "Installation du module de chargement '%s'"
     "\n"
))

(set #ask-others-files-dest
(cat "\n"
     "Où voulez-vous installer les autres fichiers ?"
     "\n"
     "(Un répertoire 'MPLS_Patch' y sera créé)"
     "\n"
))

(set #unarchiving-language-files "Patientez SVP, désarchivage des fichiers de localisation...")

(set #installing-language-file
(cat "\n"
     "Installation du fichier de localisation"
     "\n"
))

(set #old-config-exists
(cat "\n"
     "Un ancien fichier de configuration a été trouvé :"
     "\n"
))

(set #install-config-use-old "Utiliser l'ancien.")

(set #install-config-new-delete-old "Installer le nouveau, effacer l'ancien.")

(set #install-config-new-backup-old "Installer le nouveau, sauvegarder l'ancien.")

(set #old-config-renamed
(cat "\n"
     "L'ancien fichier de configuration a été renommé en :"
     "\n\n"
     "'ENVARC:MPLS_Patch.Prefs-Bak'"
))

(set #ask-cx_popkey
(cat "\n"
     "Touche d'appel du panneau de contrôles :"
     "\n"
))

(set #ask-cx_statekey
(cat "\n"
     "Touche d'activation/désactivation du patch :"
     "\n"
))

(set #ask-tempdir_path
(cat "\n"
     "Sélectionnez un répertoire temporaire :"
     "\n"
))

(set #ask-history-capacity
(cat "\n"
     "Entrez la capacité maximale de l'historique de fichiers :"
     "\n"
))

(set #ask-install-prefs-program
(cat "\n"
     "Voulez-vous installer l'éditeur de préférences ?"
     "\n\n"
     "NOTE : Ce programme nécessite MUI v3.3 ou supérieur pour fonctionner"
))

(set #ask-prefs-program-dest
(cat "\n"
     "Où voulez-vous installer l'éditeur de préférences ?"
     "\n"
))

(set #unarchiving-prefs-program "Patientez SVP, désarchivage de l'éditeur de préférences...")

(set #installing-prefs-program
(cat "\n"
     "Installation de l'éditeur de préférences"
     "\n"
))

(set #install-completed
(cat "\n"
     "Pour démarrer MPLS Patch maintenant, double-clickez sur son icône dans"
     " le répertoire '%s'"
     "\n\n"
     "IMPORTANT : Si vous êtes un utilisateur enregistré de MPLS Patch,"
     " n'oubliez pas d'installer votre fichier clé, si cela n'est pas déjà fait."
))

))

;***************************************************************************;

 (set amigados-version (/ (getversion) 65536))

 (if (< amigados-version 37)
  (abort #bad-amigados-version)
 )

 (set cpu-version (database "cpu"))

 (if (>= cpu-version 68020)
  (set cpu-version "68020")
;(else)
  (set cpu-version 68000)
 )

 (complete 0)

 (message #install-intro)

 (message #beginners-warning)

 (set install-parts
  (askoptions
   (prompt #ask-install-parts)
   (help @askoptions-help)
   (choices "MPLS Patch v1.85"
            "MPLS Patch Prefs v1.45"
   )
   (default %11)
  )
 )

 (complete 3)

 (if (<> install-parts 0)
  (
   (set language 0)

   (if (> amigados-version 37)
    (set language
     (askchoice
      (prompt #ask-language-to-use)
      (help @askchoice-help)
      (choices #english
               #french
      )
      (if (= @language "english")
       (default 0)
     ;(else)
       (default 1)
      )
     )
    )
   )

   (set @language
    (select language "english"
                     "français"
    )
   )

   (complete 6)

   (run "C:Copy /LhEx RAM: QUIET")

   (if (IN install-parts 0)
    (
     (makedir "LIBS:mpls_patch")
     (makedir "LIBS:mpls_patch/loaders")

     (if (> amigados-version 37)
      (
       (makedir "LOCALE:catalogs")

       (if (<> @language "english")
        (
         (makedir (tackon (tackon "LOCALE:catalogs" @language) "mpls_patch"))
         (makedir (tackon (tackon "LOCALE:catalogs" @language) "mpls_patch/loaders"))
        )
       )
      )
    ;(else)
      (run "C:Assign LOCALE: SYS:")
     )

     (makedir "LOCALE:help")
     (makedir (tackon "LOCALE:help" @language))

     (complete 10)

;---------------------------------------------------------------------------;

     (if (exists "LIBS:mpls_patch/mpls_patch.keyfile")
      (message #old-version-exists)
     )

;---------------------------------------------------------------------------;

     (run "C:Delete >NIL: SYS:Tools/MPLS_Patch/#? ALL FORCE QUIET")

;---------------------------------------------------------------------------;

     (if (askbool
          (if (exists "SYS:WBStartup/MPLS_Patch")
           (prompt #old-main-program-in-wbstartup)
         ;(else)
           (prompt #ask-installing-in-wbstartup)
          )
          (help @askbool-help)
          (choices #choice-yes
                   #choice-no
          )
         )
      (set patch-dest "SYS:WBStartup")
    ;(else)
      (
       (set patch-dest "SYS:Tools")

       (if (exists (tackon patch-dest "MPLS_Patch"))
        (message (#old-version-path (patch-dest)))
       )

       (set patch-dest
        (askdir
         (prompt #ask-patch-destination)
         (help  @askdir-help)
         (default patch-dest)
        )
       )

       (if (= (expandpath patch-dest) (expandpath "SYS:WBStartup"))
        (abort (#destination-invalid patch-dest))
      ;(else)
        (set patch-dest (tackon patch-dest "MPLS_Patch"))
       )

      )
     )

     (complete 13)

;---------------------------------------------------------------------------;

     (working #unarchiving-main-program)

     (run "RAM:LhEx -fqwT: x /Install_Datas/Patch_Program.LHA")

     (copyfiles
      (prompt #installing-main-program)
      (help @copyfiles-help)
      (source (tackon "T:patch" cpu-version))
      (choices "MPLS_Patch" "/MPLS_Patch.info")
      (dest patch-dest)
      (confirm)
      (optional "oknodelete" "force")
     )

     (run "C:Delete >NIL: T:patch ALL FORCE QUIET")

     (complete 16)

;---------------------------------------------------------------------------;

     (copyfiles
      (source "/Install_Datas/MPLS_Patch.Env")
      (dest "ENVARC:")
      (nogauge)
      (optional "oknodelete" "force")
     )

     (complete 20)

;---------------------------------------------------------------------------;

     (if (= (expandpath patch-dest) (expandpath "SYS:WBStartup"))
      (set tooltype-quiet "QUIET")
    ;(else)
      (
       (message #remove-QUIET-brackets)
       (set tooltype-quiet "(QUIET)")
      )
     )

     (tooltype
      (dest (tackon patch-dest "MPLS_Patch"))
      (settooltype tooltype-quiet "")
     )

     (complete 25)

;---------------------------------------------------------------------------;

     (if (> amigados-version 37)
      (if (<> language 0)
       (
        (working #unarchiving-language-files)

        (run "RAM:LhEx -fqwT: x /Install_Datas/Patch_Catalogs.LHA")

        (copyfiles
         (prompt (#installing-language-file "mpls_patch.catalog"))
         (help @copyfiles-help)
         (source (tackon "T:catalogs" @language))
         (choices "mpls_patch.catalog")
         (dest (tackon (tackon "LOCALE:catalogs" @language) "mpls_patch"))
         (confirm)
         (optional "oknodelete" "force")
        )

        (run "C:Delete >NIL: T:catalogs ALL FORCE QUIET")
       )
     ;(else)
       (run "C:Delete >NIL: LOCALE:catalogs/français/mpls_patch ALL FORCE QUIET")
      )
     )

     (complete 30)

;---------------------------------------------------------------------------;

     (working #unarchiving-mpls_patch-library)

     (run "RAM:LhEx -fqwT: x /Install_Datas/Patch_Libraries.LHA")

     (copylib
      (prompt #installing-mpls_patch-library)
      (help @copylib-help)
      (source (tackon "T:libraries" (tackon cpu-version "mpls_patch.library")))
      (dest "LIBS:mpls_patch")
      (confirm)
      (optional "oknodelete" "force")
     )

     (run "C:Delete >NIL: T:libraries ALL FORCE QUIET")

     (complete 40)

;---------------------------------------------------------------------------;

     (working #unarchiving-loaders-modules)

     (run "RAM:LhEx -fqwT: x /Install_Datas/Patch_Loaders.LHA")

     (foreach (tackon "T:loaders" cpu-version) "#?.loader"
      (copylib
       (prompt (#installing-loader-module @each-name))
       (help @copylib-help)
       (source (tackon "T:loaders" (tackon cpu-version @each-name)))
       (dest "LIBS:mpls_patch/loaders")
       (confirm)
       (optional "oknodelete" "force")
      )
     )

     (run "C:Delete >NIL: T:loaders ALL FORCE QUIET")

     (complete 50)

;---------------------------------------------------------------------------;

     (if (AND (> amigados-version 37) (<> language 0))
      (
       (working #unarchiving-languages-files)

       (run "RAM:LhEx -fqwT: x /Install_Datas/Patch_Loaders_Catalogs.LHA")

       (foreach (tackon "T:catalogs" @language) "#?.catalog"
        (copyfiles
         (prompt (#installing-language-file @each-name))
         (help @copyfiles-help)
         (source (tackon "T:catalogs" @language))
         (choices @each-name)
         (dest (tackon (tackon "LOCALE:catalogs" @language) "mpls_patch/loaders"))
         (confirm)
         (optional "oknodelete" "force")
        )
       )

       (run "C:Delete >NIL: T:catalogs ALL FORCE QUIET")
      )
     )

     (complete 60)

;---------------------------------------------------------------------------;

     (if (OR (= (expandpath patch-dest) (expandpath "SYS:WBStartup"))
             (<> (fileonly patch-dest) "MPLS_Patch"))
      (
       (if (exists "SYS:Tools/MPLS_Patch")
        (message (#old-version-path "SYS:Tools"))
       )

       (set otherfiles-dest
        (askdir
         (prompt #ask-others-files-dest)
         (help @askdir-help)
         (default "SYS:Tools")
        )
       )

       (set otherfiles-dest (tackon otherfiles-dest "MPLS_Patch"))
      )
    ;(else)
      (set otherfiles-dest patch-dest)
     )

     (if (= (expandpath otherfiles-dest) (expandpath "SYS:WBStartup"))
      (abort (#destination-invalid otherfiles-dest))
     )

     (complete 63)

     (copyfiles
      (source "//")
      (choices "Description"
               "MPLS_Patch.Guide"
               "Shareware"
               "Registration"
               "DataTypes.Lisez-Moi"
               "MUI.ReadMe"
               "Bugs_Report"
               "Print.info"
               "Preview")
      (dest otherfiles-dest)
      (infos)
      (noposition)
      (optional "oknodelete" "force")
     )

     (complete 66)

     (copyfiles
      (source "//Help/English/MPLS_Patch.Help")
      (dest "LOCALE:help/english")
      (optional "oknodelete" "force")
     )

     (copyfiles
      (source "//Help/Français/MPLS_Patch.Help")
      (dest "LOCALE:help/français")
      (optional "oknodelete" "force")
     )

     (complete 70)

;---------------------------------------------------------------------------;

     (if (exists "SYS:Tools/MPLS_Patch.Cfg")
      (
       (rename "SYS:Tools/MPLS_Patch.Cfg" "ENVARC:MPLS_Patch.Prefs")
       (run "C:Delete >NIL: SYS:Tools/MPLS_Patch.Cfg#? FORCE QUIET")
      )
     )

     (if (exists "ENVARC:MPLS_Patch.Prefs")
      (set copy-cfg
       (askchoice
        (prompt #old-config-exists)
        (help @askchoice-help)
        (choices #install-config-use-old
                 #install-config-new-delete-old
                 #install-config-new-backup-old
        )
        (default 0)
       )
      )
    ;(else)
      (set copy-cfg 1)
     )

     (complete 75)

     (if (not (= copy-cfg 0))
      (
       (if (= copy-cfg 1)
        (run "C:Delete >NIL: ENVARC:MPLS_Patch.Prefs-Bak#? FORCE QUIET")
      ;(else)
        (
         (run "C:Delete >NIL: ENVARC:MPLS_Patch.Prefs-Bak#? FORCE QUIET")
         (rename "ENVARC:MPLS_Patch.Prefs" "ENVARC:MPLS_Patch.Prefs-Bak")
         (message #old-config-renamed)
        )
       )

       (run "RAM:LhEx -fqwT: x /Install_Datas/Patch_Config.LHA")

       (copyfiles
        (source "T:config")
        (choices "MPLS_Patch.Prefs" "MPLS_Patch_Default.Prefs")
        (dest "ENVARC:")
        (infos)
        (noposition)
        (optional "oknodelete" "force")
       )

       (run "C:Delete >NIL: T:config ALL FORCE QUIET")
      )
     )

     (complete 80)

;---------------------------------------------------------------------------;

     (set tooltype-cx_popkey
      (askstring
       (prompt #ask-cx_popkey)
       (help @askstring-help)
       (default "control alt m")
      )
     )

     (tooltype
      (dest (tackon patch-dest "MPLS_Patch"))
      (settooltype "CX_POPKEY" tooltype-cx_popkey)
     )

     (complete 82)

;---------------------------------------------------------------------------;

     (set tooltype-cx_statekey
      (askstring
       (prompt #ask-cx_statekey)
       (help @askstring-help)
       (default "control alt d")
      )
     )

     (tooltype
      (dest (tackon patch-dest "MPLS_Patch"))
      (settooltype "CX_STATEKEY" tooltype-cx_statekey)
     )

     (complete 84)

;---------------------------------------------------------------------------;

     (set tooltype-tempdir_path
      (askdir
       (prompt #ask-tempdir_path)
       (help @askdir-help)
       (default "T:")
      )
     )

     (tooltype
      (dest (tackon patch-dest "MPLS_Patch"))
      (settooltype "TEMPDIR_PATH" tooltype-tempdir_path)
     )

     (complete 86)

;---------------------------------------------------------------------------;

     (set tooltype-history
      (asknumber
       (prompt #ask-history-capacity)
       (help @asknumber-help)
       (range 1 999)
       (default 10)
      )
     )

     (tooltype
      (dest (tackon patch-dest "MPLS_Patch"))
      (settooltype "HISTORY" ("%lu" tooltype-history))
     )

     (complete 88)

;---------------------------------------------------------------------------;

     (set @default-dest otherfiles-dest)
    )
   )

;***************************************************************************;

   (if (IN install-parts 1)
    (
     (if (askbool
          (prompt #ask-install-prefs-program)
          (help @askbool-help)
          (choices #choice-yes
                   #choice-no
          )
         )
      (
       (set prefs-dest
        (askdir
         (prompt #ask-prefs-program-dest)
         (help @askdir)
         (default "SYS:Prefs")
        )
       )

       (if (= (expandpath prefs-dest) (expandpath "SYS:WBStartup"))
        (abort #destination-invalid)
       )

       (complete 89)

;---------------------------------------------------------------------------;

       (working #unarchiving-prefs-program)

       (run "RAM:LhEx -fqwT: x /Install_Datas/Prefs_Program.LHA")

       (copyfiles
        (prompt #installing-prefs-program)
        (help @copyfiles-help)
        (source (tackon "T:prefs" cpu-version))
        (choices "MPLS_Patch_Prefs" "/MPLS_Patch_Prefs.info")
        (dest prefs-dest)
        (confirm)
        (optional "oknodelete" "force")
       )

       (run "C:Delete >NIL: T:prefs ALL FORCE QUIET")

       (complete 90)
      )
     )

;---------------------------------------------------------------------------;

     (if (AND (> amigados-version 37) (<> language 0))
      (
       (working #unarchiving-language-files)

       (run "RAM:LhEx -fqwT: x /Install_Datas/Prefs_Catalogs.LHA")

       (copyfiles
        (prompt (#installing-language-file "mpls_patch_prefs.catalog"))
        (help @copyfiles-help)
        (source (tackon "T:catalogs" @language))
        (choices "mpls_patch_prefs.catalog")
        (dest (tackon (tackon "LOCALE:catalogs" @language) "mpls_patch"))
        (confirm)
        (optional "oknodelete" "force")
       )

       (run "C:Delete >NIL: T:catalogs ALL FORCE QUIET")
      )
     )

     (complete 95)

;---------------------------------------------------------------------------;

     (if (NOT (IN install-parts 0))
      (set @default-dest prefs-dest)
     )

    )
   )

;***************************************************************************;

   (complete 100)

   (if (IN install-parts 0)
    (message (#install-completed patch-dest))
   )

   (run "C:Delete >NIL: RAM:LhEx FORCE QUIET")

   (exit)
  )
;(else)
  (abort #install-aborted)
 )