; $VER: Install OverCD © ARCHOS 1994
; Script to install ARCHOS Overdrive CD Software
; Version AMIGA 600

        (complete 0)

        (welcome "(C) ARCHOS 1994 - OVERDRIVE CD Installation - Ver 9.0")

        (message "\nUpdating Libraries...\n"
                 "\nnonvolatile.library\n"
                 "lowlevel.library\n"
                 "freeanim.library\n"
                 "debox.library\n"
                 "playerprefs.library\n"
                 "\n(Please confirm operation below : Proceed/Abort)")
        
        (copylib
            (source "OverCD:Libs/debox.library")
            (dest   "LIBS:")
        )

        (complete 10)

        (copylib
            (source "OverCD:Libs/playerprefs.library")
            (dest   "LIBS:")
        )

        (complete 20)

        (copylib
            (source "OverCD:Libs/lowlevel.library")
            (dest   "LIBS:")
        )

        (complete 30)

        (copylib
            (source "OverCD:Libs/freeanim.library")
            (dest   "LIBS:")
        )

        (complete 40)

        (copylib
            (source "OverCD:Libs/nonvolatile.library")
            (dest   "LIBS:")
        )

        (complete 50)

        (message "\nUpdating Handler...\n"
                 "\nL:overcd-handler\n"
                 "\n(Please confirm operation below : Proceed/Abort)")

        (copyfiles
            (source "OverCD:L/overcd-handler")
            (dest   "L:")
        )

        (complete 60)

        (message "\nUpdating Commands...\n"
                 "\ncdboot\n"
                 "\n(Please confirm operation below : Proceed/Abort)")

        (if (exists "C:cdboot")
            (delete "C:cdboot")
        )

        (copyfiles
            (source "OverCD:c/cdboot600")
            (dest   "C:")

       )
        (copyfiles
            (source "OverCD:c/runback")
            (dest   "C:")
        )

        (rename "C:cdboot600" "C:cdboot")

        (complete 70)

        (message "\nUpdating Mountlist...\n"
                 "\n(Please confirm operation below : Proceed/Abort)")

        (if (= (run "C:search DEVS:mountlist CD0:") 5)
            (
            ; no CD0: in mountlist
            (run "C:join DEVS:mountlist OverCD:devs/mountlist600 as T:mountlist")
            (copyfiles
                (source "T:mountlist")
                (dest   "DEVS:")
            )
            (delete "T:mountlist")
            )
        )

        (complete 80)

        (if (not (exists "S:startup-sequence.std"))            
            (rename "S:startup-sequence" "S:startup-sequence.std")
        )

        (run "copy OverCD:S/startup-sequence600 to S:startup-sequence.cd")

        (run "copy OverCD:s/startup-sequence600 to S:startup-sequence") 

        (run "C:execute INSTALL:nv_script")
        
        (complete 90)

        (set ch 
            (askoptions
                (prompt "\nSelect the CD utilities to install...\n")
                (help @askoptions-help)
                (choices 
                    "CDDA (CD Digital Audio player)"
                    "CDDoor (Open/Close CD Drive Tray)"
                )
            )
        )

        (set utilsdir 
            (askdir
                (prompt "OverDrive-CD utilities will be copied\n"
                        "to the Selected Drawer below.\n"
                        "Select the destination directory:"
                )
                (help @askdir-help)
                (default "SYS:Utilities")
                (disk)
            )
        )

        (if (in ch 0)
            (
            (copyfiles
                (source "Install:CDDA")
                (dest   utilsdir)
            )
            (copyfiles
                (source "Install:CDDA.info")
                (dest   utilsdir)
            )
            (copyfiles
                (source "Install:CDDA.iff")
                (dest   utilsdir)
            )
            )
        )

        (if (in ch 1)   
            (
            (copyfiles
                (source "Install:CDDoor")
                (dest   utilsdir)
            )
            (copyfiles
                (source "Install:CDDoor.info")
                (dest   utilsdir)
            )
            )
        )

        (complete 100)

        (exit)