(welcome "Copyright © 2001 Peter d'Alancaisez & Adalbert Jahnz.\n\n"
	 "Welcome to DIGIOchmannumérique!\n\n"
	 "Please note that you need AmigaOS 3.0 or better and the AGA chipset "
	 "to use this programme.")

(if (< @user-level 1)
	(abort  "Please set your user level to INTERMEDIATE to proceed with the "
		"installation.")
)

(complete 0)

(set #dest
	(askdir
		(prompt "Where do you want to install the DIGIOchmann executable and "
			"documentation?\n"
			"No new directory will be created.")
		(help @askfile-help)
		(default @default-dest)
		(disk)
	)
)

(set #files
	(askdir
		(prompt "Where do you want to put DIGIOchmann data files?\nI will "
			"create a directory of that name if it does not exist.")
		(help @askfile-help)
		(newpath)
		(default (tackon #dest "Files"))
	)
)

(makedir #files
	(prompt "Creating the files directory.")
)

(copyfiles 
	(prompt "Installing the necessary fonts.")
	(help @copyfiles-help)
	(source "Fonts")
	(dest "FONTS:")
	(pattern "#?")
	(fonts)
)

(complete 20)

(copyfiles
	(prompt "Copying the executable.")
	(help @copyfiles-help)
	(source "ochmannumérique")
	(dest #dest)
	(infos)
	(noposition)
)

(complete 60)

(copyfiles
	(prompt "Copying the documentation.")
	(help @copyfiles-help)
	(source "Docs")
	(dest #dest)
	(infos)
	(noposition)
	(confirm)
	(pattern "#?")
)

(complete 70)

(copyfiles
	(prompt "Copying the language files.")
	(help @copyfiles-help)
	(source "Locale")
	(pattern "#?.digilang")
	(dest #files)
)

(complete 80)

(startup "Ochmannumérique"
	(prompt "Some instructions need to be added to the "
		"\"S:user-startup\" so that your system will "
		"be properly configured to use DIGIOchmann.")
	(help 	("Please note that if you are using MCP, AssignPrefs or a similar assign manager programme, you can skip this part and then manually assign OCHMANN: to %s." #files))
	(command ("Assign OCHMANN: %s" #files))
)

(complete 90)

(run "FixFonts"
	(prompt "Running the FixFonts utility so that the OS can see the new fonts"
		"installed.")
	(confirm)
	(help "No help is available, sorry.")
)

(makeassign "OCHMANN" #files)

(complete 100)

(message "You can now click on the Ochmannumérique icon to start the programme.")