;
; AHelp installer Script - by Software Failure/Airsoft
;
; if there are any problems, email me: Andreas.Falkenhahn@gmx.de
;
; last modified on 25-Dec-99

(message (cat "\n\nAHelp V1.5 \n\n(c) 1997-99 by Andreas Falkenhahn\nArtworks by The Falconer\n\n"
              "This script installs AHelp and the prefs "
              "program to your harddisk and makes it ready "
              "to use."
         )
)

(welcome)

(set lang
    (askchoice
        (prompt "Please select your preferred language")
        (choices "english" "deutsch" "español")
        (help @askchoice-help)
    )
)

(if (= lang 0) (
   (set #install "Installing AHelp...")
   (set #dir1 "Where do you want AHelp to be installed?\n(WBStartup is recommended)")
   (set #dir2 "Where do you want AHelp Prefs to be installed?") 
   (set #dir3 "Where do you want the AHelp documentation to be installed?") 
   (set #dir4 "Where do you want the developer files to be installed?")
   (set #finished "\nAHelp was successfully installed on your harddisk!\n\nHave fun!")
   (set #language "Select the language you want to use for AHelp")
   (set #developer "\nWould you like to get the developer files\n(cd+ct) for translators installed?")
))

(if (= lang 1) (
   (set #install "Installiere AHelp...")
   (set #dir1 "Wo soll AHelp installiert werden?\n(empfohlen wird WBStartup)")
   (set #dir2 "Wo soll der Voreinsteller für AHelp installiert werden?") 
   (set #dir3 "Wo soll die Dokumentation für AHelp installiert werden?") 
   (set #dir4 "Wo sollen die Entwicklerdateien installiert werden?")
   (set #finished "\nAHelp wurde erfolgreich installiert!\n\nViel Spaß!")
   (set #language "Wählen Sie Ihre bevorzugte Sprache für AHelp")
   (set #developer "\nMöchten Sie Entwicklerdateien\n(cd+ct) für Übersetzer installiert bekommen?")
))

(if (= lang 2) (
   (set #install "Instalando AHelp...")
   (set #dir1 "¿Dónde desea instalar AHelp?\n(se recomienda en el cajón WBStartup)") 
   (set #dir2 "¿Dónde desea instalar el programa de preferencias de AHelp?")
   (set #dir3 "¿Dónde desea instalar la documentación AHelp?")
   (set #dir4 "¿Dónde desea instalar los ficheros de desarrollo?")
   (set #finished "\n¡AHelp ha sido instalado con éxito en su sistema!\n\n¡Que lo disfrute!")
   (set #language "Elija el idioma que desea utilizar con AHelp")
   (set #developer "\n¿Desea instalar los ficheros de\ndesarrollo para los traductores (cd+ct)?")
))

(set desti
    (askdir
        (prompt #dir1)
        (help @askdir-help)
        (default "SYS:WBStartup")
    )
)

(set dest1
     (askdir
            (prompt #dir2)
            (help @askdir-help)
            (default "SYS:Prefs")
     )
)

(set dest2
     (askdir
           (prompt #dir3)
           (help @askdir-help)
           (default "Help:")
     )
)

(set lang
     (askchoice
           (prompt #language)
           (help @askchoice-help)
           (choices "english" "deutsch" "español" "français")
     )
)

(set dev
     (askbool
           (prompt #developer)
           (help @askbool-help)
     )
)

(if (= dev 1) (
   (set devdir
       (askdir
              (prompt #dir4)
              (default "LOCALE:")
              (help @askdir-help)
       )
   )
)) 
  
(working #install)

(copyfiles
   (source "WBStartup/AHelp")
   (dest desti)
   (nogauge)
   (infos)
)

(copyfiles
   (source "Prefs/AHelp")
   (dest dest1)
   (nogauge)
   (infos)
)

(copyfiles
   (source "AHelp.guide")
   (dest   dest2)
   (nogauge)
   (infos)
)

(textfile
   (dest "S:AHelp.prefs")
   (append (cat desti "\n"))
   (append (cat dest1 "\n"))
   (append (cat dest2 "\n"))
)

(if (= lang 1) (
   (copyfiles
      (source "Catalogs/deutsch/AHelp.catalog")
      (dest "Locale:Catalogs/deutsch")
      (nogauge)
   )
))

(if (= lang 2) (
   (copyfiles
      (source "Catalogs/español/AHelp.catalog")
      (dest "Locale:Catalogs/español")
      (nogauge)
   )
))

(if (= lang 3) (
   (copyfiles
      (source "Catalogs/français/AHelp.catalog")
      (dest "Locale:Catalogs/français")
      (nogauge)
   )
))

(if (= dev 1) (
   (copyfiles
      (source "Catalogs")
      (dest devdir)
      (pattern "AHelp#?")
      (nogauge)
   )
))

(message #finished)

(exit (quiet))