; Lezione5e.s	DIMEZZAMENTO DELL'ALTEZZA DI UNA FIGURA MODIFICANDO I MODULI

	SECTION	CiriCop,CODE

Inizio:
	move.l	4.w,a6		; Execbase in a6
	jsr	-$78(a6)	; Disable - ferma il multitasking
	lea	GfxName(PC),a1	; Indirizzo del nome della lib da aprire in a1
	jsr	-$198(a6)	; OpenLibrary
	move.l	d0,GfxBase	; salvo l'indirizzo base GFX in GfxBase
	move.l	d0,a6
	move.l	$26(a6),OldCop	; salviamo l'indirizzo della copperlist vecchia

;	 PUNTIAMO I NOSTRI BITPLANES

	MOVE.L	#PIC,d0		; in d0 mettiamo l'indirizzo della PIC,
	LEA	BPLPOINTERS,A1	; puntatori nella COPPERLIST
	MOVEQ	#2,D1		; numero di bitplanes -1 (qua sono 3)
POINTBP:
	move.w	d0,6(a1)	; copia la word BASSA dell'indirizzo del plane
	swap	d0		; scambia le 2 word di d0 (es: 1234 > 3412)
	move.w	d0,2(a1)	; copia la word ALTA dell'indirizzo del plane
	swap	d0		; scambia le 2 word di d0 (es: 3412 > 1234)
	ADD.L	#40*256,d0	; + lunghezza bitplane -> prossimo bitplane
	addq.w	#8,a1		; andiamo ai prossimi bplpointers nella COP
	dbra	d1,POINTBP	; Rifai D1 volte POINTBP (D1=num of bitplanes)
;
	move.l	#COPPERLIST,$dff080	; Puntiamo la nostra COP
	move.w	d0,$dff088		; Facciamo partire la COP

	move.w	#0,$dff1fc		; Disattiva l'AGA
	move.w	#$c00,$dff106		; Disattiva l'AGA

mouse:
	cmpi.b	#$ff,$dff006	; Siamo alla linea 255?
	bne.s	mouse		; Se non ancora, non andare avanti
frame:
	cmpi.b	#$fe,$dff006	; Siamo alla linea 254? (deve rifare il giro!)
	bne.s	frame		; Se non ancora, non andare avanti
frame2:
	cmpi.b	#$fd,$dff006	; Siamo alla linea 253?
	bne.s	frame2		; Se non ancora, non andare avanti
frame3:
	cmpi.b	#$fc,$dff006	; Siamo alla linea 252?
	bne.s	frame3
frame4:
	cmpi.b	#$fb,$dff006	; Siamo alla linea 251?
	bne.s	frame4

	btst	#2,$dff016	; se il tasto destro e' premuto salta
	beq.s	NonMuovere	; la routine dello scroll, bloccandolo

	bsr.s	MuoviCopper	; Routine dei moduli

NonMuovere
	btst	#6,$bfe001	; tasto sinistro del mouse premuto?
	bne.s	mouse		; se no, torna a mouse:

	move.l	OldCop(PC),$dff080	; Puntiamo la cop di sistema
	move.w	d0,$dff088		; facciamo partire la vecchia cop

	move.l	4.w,a6
	jsr	-$7e(a6)	; Enable - riabilita il Multitasking
	move.l	gfxbase(PC),a1	; Base della libreria da chiudere
	jsr	-$19e(a6)	; Closelibrary - chiudo la graphics lib
	rts			; USCITA DAL PROGRAMMA

;	Dati

GfxName:
	dc.b	"graphics.library",0,0	

GfxBase:		; Qua ci va l'indirizzo di base per gli Offset
	dc.l	0	; della graphics.library

OldCop:			; Qua ci va l'indirizzo della vecchia COP di sistema
	dc.l	0

; Con questa routine aggiungiamo o sottraiamo 40 ai registri dei moduli per
; accorciare la figura. Ho mantenuto le label dell'esempio precedente per
; risparmiare tempo.

MuoviCopper:
	TST.B	SuGiu		; Dobbiamo salire o scendere?
	beq.w	VAIGIU
	tst.w	MOD1		; Siamo al valore normale del modulo? (ZERO)
	beq.s	MettiGiu	; se si, dobbiamo aumentare il valore
	sub.w	#40,MOD1	; sottraiamo 40, ossia 1 linea, facendo
				; scorrere in BASSO la figura (ingrandendola)
	sub.w	#40,MOD2	; sottraiamo 40 al modulo 2
	rts

MettiGiu:
	clr.b	SuGiu		; Azzerando SuGiu, al TST.B SuGiu il BEQ
	rts			; fara' saltare alla routine VAIGIU

VAIGIU:
	cmpi.w	#40*20,MOD1	; abbiamo dimezzato abbastanza??
	beq.s	MettiSu		; se si, dobbiamo far tornare la pic normale
	add.w	#40,MOD1	; Aggiungiamo 40, ossia 1 linea, facendo
				; scorrere in ALTO la figura (dimezzandola)
	add.w	#40,MOD2	; Aggiungiamo 40 al modulo 2
	rts

MettiSu:
	move.b	#$ff,SuGiu	; Quando la label SuGiu non e' a zero,
	rts			; significa che dobbiamo risalire.


;	Questo byte, indicato dalla label SuGiu, e' un FLAG.

SuGiu:
	dc.b	0,0


	SECTION	GRAPHIC,DATA_C

COPPERLIST:
	dc.w	$120,$0000,$122,$0000,$124,$0000,$126,$0000,$128,$0000 ; SPRITE
	dc.w	$12a,$0000,$12c,$0000,$12e,$0000,$130,$0000,$132,$0000
	dc.w	$134,$0000,$136,$0000,$138,$0000,$13a,$0000,$13c,$0000
	dc.w	$13e,$0000

	dc.w	$8e,$2c81	; DiwStrt	(registri con valori normali)
	dc.w	$90,$2cc1	; DiwStop
	dc.w	$92,$0038	; DdfStart
	dc.w	$94,$00d0	; DdfStop
	dc.w	$102,0		; BplCon1
	dc.w	$104,0		; BplCon2
	dc.w	$108
MOD1:
	dc.w	0		; Bpl1Mod
	dc.w	$10a
MOD2:
	DC.W	0		; Bpl2Mod

		    ; 5432109876543210
	dc.w	$100,%0011001000000000	; bits 13 e 12 accesi!! (3 = %011)
					; 3 bitplanes lowres, non lace
BPLPOINTERS:
	dc.w $e0,$0000,$e2,$0000	;primo	 bitplane
	dc.w $e4,$0000,$e6,$0000	;secondo bitplane
	dc.w $e8,$0000,$ea,$0000	;terzo	 bitplane

	dc.w	$0180,$000	; color0
	dc.w	$0182,$475	; color1
	dc.w	$0184,$fff	; color2
	dc.w	$0186,$ccc	; color3
	dc.w	$0188,$999	; color4
	dc.w	$018a,$232	; color5
	dc.w	$018c,$777	; color6
	dc.w	$018e,$444	; color7
	dc.w	$FFFF,$FFFE	; Fine della copperlist

;	figura


PIC:
	incbin	"amiga.320*256*3"	; qua carichiamo la figura in RAW,
					; convertita col KEFCON, fatta di
					; 3 bitplanes consecutivi
	end

Per fare una cosa piu' "pulita" avrei dovuto mettere un wait sotto la figura
che mi togliesse di mezzo le "impurita" che si vedono in basso, ossia i byte
in memoria dopo la figura e i bitplanes che "spuntano" sotto il primo e il
secondo. Ma lo scopo principale e' quello di spiegare la funzione dei moduli.
La routine tra l'altro viene eseguita una volta ogni 4 fotogrammi per
rallentarla.