; ***************************************
; *                                     *
; *   Play16Start-Installationsskript   *
; *                                     *
; *  $VER: 0.1 (07.03.99) by J.Reinert  *
; *                                     *
; ***************************************



; *************************************************************************
; Definition der globalen Konstanten
; *************************************************************************

(set #liesmichtext  "Lies_mich.TXT")        ; Schlusswort
(set #progsource    "play16start")          ; Programm
(set #docsource     "play16start.guide")    ; Anlaitung
(set #envdest       "ENV:P16STARTPLAYER")
(set #envarcdest    "ENVARC:P16STARTPLAYER")

; *************************************************************************
; Version der Workbench bestimmen
; *************************************************************************

(set #os_version (/ (getversion "libs:version.library") 65536))

; *************************************************************************
; Definition der deutschen Texte
; *************************************************************************

(set #msg2
  (cat "\nMit \"Play16Start\" können Sie das Programm \"Play16\" als "
       "Shell-Kommando starten und die Soundwiedergabe trotzdem per "
       "Mausklick abbrechen. Dieses Feature wird von Play16 bisher "
       "nicht unterstützt.\n\n"
       "\"Play16\" ist (C) by Thomas Wenzel"
  )
)

(set #bad-kick
  (cat ""@app-name" benötigt Amiga-OS 2.0 oder höher!\n"
       "Dies wäre jetzt der richtige Zeitpunkt, Ihren "
       "Amiga aufzuwerten. "
  )
)

(set #askprogdirmsg
  (cat "Wo möchten Sie "@app-name" installieren?.\nEine Schublade "
       "wird NICHT erzeugt"
  )
)

(set #askprogdirhelp
  (cat "Als Ziel sollten Sie eine Schublade auswählen, auf der "
       "ein Suchpfad gesetzt ist. z.B. C: "
  )
)

(set #askdocdirmsg
  (cat "Wo möchten Sie die Anleitung zu "@app-name" installieren?. Eine Schublade "
       "wird NICHT erzeugt"
  )
)

(set #askdocdirhelp
  (cat "Wählen Sie ein beliebiges Ziel. Falls Sie die "
       "Anleitung später nochmal lesen möchten, sollten "
       "Sie sich merken, wo sie ist :)"
  )
)

(set #askplayer
  (cat "Bitte wählen Sie den Sound-Player aus, den Sie mit "@app-name" nutzen "
       "möchten"
  )
)

(set #askplayerhelp
  (cat "Wählen Sie bitte nur Soundplayer aus, die sich per Tastenkombination "
       "CTRL-C abbrechen lassen. Dies sind z.B. Play16 (bevorzugt verwenden) "
       "und der ToccataPlayer.\n"
       "Es wird dann die benötigte ENV-Variable erzeugt"
  )
)

; *************************************************************************
; Beginn der Installation
; *************************************************************************

(complete 0)
(if (< #os_version 37)
  (
    (abort #bad-kick)
  )
)
(message #msg2)
(welcome)
(complete 5)

; *************************************************************************
; Zielverzeichnis für Programm auswählen lassen
; *************************************************************************

(set progdest
  (askdir
    (prompt  #askprogdirmsg)
    (help    #askprogdirhelp)
    (default "C:")
  )
)
(complete 10)

; *************************************************************************
; Zielverzeichnis für Anleitung auswählen lassen
; *************************************************************************

(set docdest
  (askdir
    (prompt  #askdocdirmsg)
    (help    #askdocdirhelp)
    (default "HELP:")
  )
)
(complete 20)

; *************************************************************************
; Welcher Player wird verwendet
; *************************************************************************

(set usedplayer
  (askfile
    (prompt  #askplayer)
    (help    #askplayerhelp)
    (default "C:")
  )
)
(if (= (fileonly usedplayer) "")
  (message "Es wurde kein Player-Programm ausgewählt!")
)
(complete 30)

; *************************************************************************
; Kopieren des Programms
; *************************************************************************

(copyfiles 
  (prompt "Kopieren des Programmes")
  (help "")
  (source #progsource)
  (dest progdest)
  (confirm "EXPERT")
)
(complete 40)

; *************************************************************************
; Kopieren der Anleitung
; *************************************************************************

(copyfiles 
  (prompt "Kopieren der Anleitung")
  (help "")
  (source #docsource)
  (dest docdest)
  (confirm "EXPERT")
)
(complete 70)

; *************************************************************************
; Erzeugen einer ENV-Variable
; *************************************************************************

(if (<> (fileonly usedplayer) "")
  (
    (textfile
       (prompt (cat "\nErzeugen der ENV-Datei" #envdest))
       (help "")
       (dest #envdest)
       (append usedplayer)
       (confirm "EXPERT")
    )
    (textfile
       (prompt (cat "\nErzeugen der ENVARC-Datei" #envarcdest))
       (help "")
       (dest #envarcdest)
       (append usedplayer)
       (confirm "EXPERT")
    )
  )
)
(complete 80)

; *************************************************************************
; Aktuelles Verzeichnis setzen
; *************************************************************************

(set @default-dest progdest)

(complete 90)

; *************************************************************************
; Falls vorhanden, einen LiesMich-Text anzeigen
; *************************************************************************

(if (exists #liesmichtext)
  (run (cat "run sys:utilities/more " #liesmichtext))
)

(complete 100)

; *************************************************************************
; Ende der Installation
; *************************************************************************