;Install script for WebPlug version 1.45 Š 1998 Esteve Boix
;This install script is Š Bo Liljegren (bosse@algonet.se)
;Updated 04/98 Esteve Boix (again :)
;
;Translated into Slovenian language on 21.09.98 by Damir Arh of
;Amiga Computer Club D.A.D. Kranj, Slovenia

(complete 0)

;Pure sequrity. If the Installer, by some strange reason,
; can't find the default language, it will use english
; Actually, I've removed the other languages :P

(set default_lang 2)

;=============================================================================
; Slovenian strings

;(if (= @language "slovensko")
;(
(set default_lang 2)

(set #low-user-level
(cat "\nInstalacija programa WebPlug zahteva vsaj izbiro uporabniške kategorije \"Vajen uporabnik\".\n\n"
     "Še enkrat začnite z instalacijo in izberite ustrezno uporabniško kategorijo."
))

(set #ask-upgrade
(cat "\nJe to nova instalacija ali\n"
     "nadgradnja?\n\n"
     "Ponovna instalacija je enaka nadgradnji"
))

(set #upgr-choice-upgr
(cat "Nadgradnja"
))

(set #upgr-choice-new
(cat "Nova instalacija"
))

(set #which-oldfile
(cat "Kje je program webPlug?\n(Program, NE predal)\n"
))

(set #mess-oldinstaller1
(cat "\nUporabljate staro verzijo\nprograma Installer. (%ld.%ld)\n\n"
))

(set #mess-oldinstaller2
(cat "Prosim uporabite Installer v43.3"
))

(set #mess-obsoletekick
(cat "webPlug potrebuje AmigaDOS verzijo 3.0 ali višjo\nPrejšnje verzije niso več podprto..."
))

(set #mess-nomui
(cat "\nwebPlug potrebuje MUI.\nNe najdem muimaster.library.\n\n"
     "Oprostite, z instalacijo ne morem nadaljevati"
))

(set #mess-oldmui
(cat "\nwebPlug potrebuje MUI verzijo 3.8 ali višjo.\n\n"
     "To pomeni muimaster.library ver 19.35\n"
     "Imate verzijo %ld.%ld\n\n"
     "Oprostite,z instalacijo ne morem nadaljevati"
))

(set #which-directory
(cat "Kam hočete webPlug instalirati?\n(Predal z imenom \"webPlug\" BO ustvarjen)"
))

(set #confirm-adddocs
(cat "\n\nAli želite instalirati (HTML) dokumentacijo?"
))

(set #confirm-custom-dirs
(cat "\n\nAli želite instalirati predala z uporabniškimi oznakami in nizi?"
))

(set #which-language
(cat "\nKatere jezike naj instaliram?\n(angleščina je vgrajena)"
))

(set #prompt-makemaindir
(cat "Ustvarjam predal webPlug"
))

(set #prompt-copybrowserlinks
(cat "Prekopiral bom predal z 'BrowserLinks'-i"
))

(set #prompt-copyplugins
(cat "Prekopiral bom predal z dodatki"
))

(set #prompt-adddocs
(cat "Prekopiral bom (HTML) dokumentacijo"
))

(set #prompt-texteditor
(cat "Instaliral bom Texteditor.mcc"
))

(set #prompt-betterstring
(cat "Instaliral bom BetterString.mcc"
))

(set #prompt-popcolor
(cat "Instaliral bom PopColor.mcc"
))

(set #prompt-customtags
(cat "Instaliral bom predal z uporabniškimi oznakami"
))

(set #prompt-customstrings
(cat "Instaliral bom predal z uporabniškimi nizi"
))

(set #prompt-copytoolicons
(cat "Prekopiral bom ikone za orodno vrstico"
))

(set #prompt-executable
(cat "Prekopiral bom program webPlug"
))

(set #mess-congra
(cat "\nČestitke, webPlug je zdaj instaliran.\n\n"
))

(set #mess-docsfound
(cat "Dokumentacija je v HTML formatu in\n"
     "jo lahko najdete v predalu \"%s\"\n"
     "Prosim, za prebiranje uporabite najljubši brkljalnik.\n"
     "Začnite z datoteko \"webPlug.html\"\n\n"
))

(set #mess-shareware
(cat "webPlug je izdan kot Shareware.\n"
     "Registracija stane le 10 USD, zato se odločite za\n"
     "registracijo, če ga uporabljate.\n\n"
     "Uživajte!"
))

;))

;=============================================================================
; procedure to copy the language catalogs

(procedure P_InstLocale
(
    (set n 0)
    (while (set #language (select n "catalŕ"
                "english"
                "espańol"
;                "italiano"
;                "portuguęs"
                "svenska"
;                "norsk"
                "deutsch"
                "français"
                "slovensko"
                ""
   ))
    (
   (if (IN #locales n)
   (
   ;; The english language is built in. No need to install it
      (if (<> 1 n)
      (
          (copyfiles
         (source (tackon "/bin/locale/catalogs/" #language))
         (dest (tackon "LOCALE:Catalogs" #language))
         (all)
   )))))
   (set n (+ n 1))
))))

;========================================================
; check user-level

(if (< @user-level 1)
    (abort (#low-user-level @app-name))
)

;========================================================
; variable setup

(set #installver (/ @installer-version 65536))
(set #installrev (- @installer-version (* #installver 65536)))
(set #tempversion (getversion))
(set #osversion (/ #tempversion 65536))
(set #osrevision (- #tempversion (* #osversion 65536)))
(set #adddocs 0)
(set #frominstdir (pathonly @icon))
(set #frominstdir (substr #frominstdir 0 (- (strlen #frominstdir) (strlen "/install"))))

;========================================================
; check installer version

(if (< #installver 43)
    (
     (abort (#mess-oldinstaller1 #installver #installrev)
             #mess-oldinstaller2)
))

;========================================================
; check kickstart version

(if (< #osversion 37)
    (
     (abort #mess-obsoletekick)
))

;========================================================
; Display picture

(if (> (exists ("c:multiview")) 0) (set #mv "c:") )
(if (> (exists ("sys:utilities/multiview")) 0) (set #mv "sys:Utilities") )
(if (> (exists ("sys:tools/multiview")) 0) (set #mv "sys:Tools") )

(if (<> #mv 0)
    ((run (cat "run " (tackon #mv "multiview ") "/docs/pics/webPlugS.gif"))))


;========================================================
; check mui (MUI 3.8 = muimaster.library V19.35)

(if (= (exists "LIBS:muimaster.library" (noreq)) 1)
    (
     (set #tempver (getversion "LIBS:muimaster.library"))
     (set #muiver (/ #tempver 65536))
     (set #muirev (- #tempver (* #muiver 65536)))
     (if (< #muiver 19)
    (
     (abort (#mess-oldmui #muiver #muirev))
     )))
  ((abort #mess-nomui))
)

;=============================================================================
; ask new install or upgrade

(set #b-upgrade
   (askbool
      (prompt #ask-upgrade)
      (help @askbool-help)
      (choices #upgr-choice-upgr #upgr-choice-new)
   )
)

;=============================================================================
; where should webPlug be installed

(if (= (exists "Work:" (noreq)) 2)
    (set #def-dest "Work:")
    (set #def-dest "SYS:")
    )

;-----------------------------------------------
; if upgrade, where is the old program?

(if (= 1 #b-upgrade)
(
    (set #oldprogfile
   (askfile
       (prompt #which-oldfile)
       (help @askdir-help)
       (default #def-dest)
   )
    )
    (set #directory (pathonly (#oldprogfile)))

    ;; If Docs directory exists, new documentation will be installed!
    (if (= (exists (tackon #directory "Docs") (noreq)) 2)
   (set #adddocs 1)
    )
)

;-----------------------------------------------
; else new install

((set #directory
   (askdir
       (prompt #which-directory)
       (help @askdir-help)
       (default #def-dest)
))))
(complete 10)

;=============================================================================
; should documentation be installed?

(if (OR (= #adddocs 0) (= @user-level 2))
(
    (set #adddocs
   (askbool
       (prompt #confirm-adddocs)
       (help @askbool-help)
       (default 1)
    ))
))
(complete 20)

;=============================================================================
; should CustomTags and CustomStrins directories be installed?

(
   (set #addcustom
   (askbool
       (prompt #confirm-custom-dirs)
       (help @askbool-help)
       (default 1)
    ))
)
(complete 20)

;=============================================================================
; which languages should be installed?

(set #locales
   (askoptions
      (prompt #which-language)
      (help @askoptions-help)
      (choices
                      "Catalŕ"
                      "English"
                      "Espańol"
;                      "Italiano (not complete)"
;                      "Portuguęs (not complete)"
                     "Svenska"
;                      "Norsk (not complete)"
                      "Deutsch"
                      "Français"
                      "Slovenskega"
                 )
      (default default_lang)
   )
)
(complete 30)

;=============================================================================
; if new installation create the main directory

(if (= 0 #b-upgrade)
(
   (set @default-dest (tackon #directory "webPlug"))
   (makedir
    (@default-dest)
    (prompt #prompt-makemaindir)
    (help @makedir-help)
    (infos)
   )
   (complete 40)

;-----------------------------------------------
; and copying icon file for main program/directory

   (copyfiles
    (source (cat #frominstdir ".info"))
    (dest (tackon @default-dest '/'))
    (newname 'webPlug.info' )
    (infos)
    (help @copyfiles-help)
   )
)
;-----------------------------------------------
; else just set @default-dest

    (set @default-dest #directory)
)
(complete 50)

;=============================================================================
; copy the BrowserLinks directory

(copyfiles
   (source "/bin/BrowserLinks")
   (dest (tackon @default-dest "BrowserLinks"))
   (prompt #prompt-copybrowserlinks)
   (all)
   (help @copyfiles-help)
)
(complete 60)

;=============================================================================
; copy the "toolicons" directory

(copyfiles
   (source "/bin/toolicons")
   (dest (tackon @default-dest "toolicons"))
   (prompt #prompt-copytoolicons)
   (all)
   (help @copyfiles-help)
)
(complete 65)

;=============================================================================
; copy the (HTML) documentation
(set #docs-dest (tackon @default-dest "Docs"))

(if (= 1 #adddocs)
   (copyfiles
      (source "/docs")
      (dest #docs-dest)
      (prompt #prompt-adddocs)
      (help @copyfiles-help)
      (all) 
   )
)
(complete 70)
;=============================================================================
; copy the CustomTags and CustomStrins directories
(set #docs-dest (tackon @default-dest "Docs"))

(if (= 1 #adddocs)
  (
   (copyfiles
      (source "/bin/CustomStrings")
      (dest (tackon @default-dest "CustomStrings"))
      (prompt #prompt-customstrings)
      (all)
      (infos)
      (help @copyfiles-help)
   )
   (copyfiles
      (source "/bin/CustomTags")
      (dest (tackon @default-dest "CustomTags"))
      (prompt #prompt-customstags)
      (all)
      (infos)
      (help @copyfiles-help)
   )
  )
)
(complete 75)
;=============================================================================
; install the PopColor.mcc progdir:mui/

(copylib
    (source "/bin/mui/popcolor.mcc")
    (dest (tackon @default-dest "mui"))
    (prompt #prompt-popcolor)
)

;=============================================================================
; install the Texteditor.mcc MUI:Libs/mui/

(copylib
    (source "/bin/mui/texteditor.mcc")
    (dest "mui:libs/mui")
    (prompt #prompt-texteditor)
)

;=============================================================================
; install the BetterString.mcc MUI:Libs/mui/

(copylib
    (source "/bin/mui/betterstring.mcc")
    (dest "mui:libs/mui")
    (prompt #prompt-betterstring)
)

(complete 85)

;=============================================================================
; install executable files for webPlug

(copyfiles
   (source "/bin/webPlug")
   (dest @default-dest)
   (prompt #prompt-executable)
   (help @copyfiles-help)
   (infos)
)
(complete 90)

;=============================================================================
; install sample plugins for webPlug

(copyfiles
   (source "/bin/webplugins")
   (dest (tackon @default-dest "webplugins"))
   (prompt #prompt-plugins)
   (help @copyfiles-help)
   (infos)
   (all)
)
(complete 95)

;=============================================================================
; procedure to copy the language catalogs

(P_InstLocale)

;=============================================================================
;Close the mlutiview window

(rexx "quit_multiview.rexx")

(complete 100)

;=============================================================================
; That's it!

(if (= 1 #adddocs)
   (set #exit-text (cat #mess-congra (#mess-docsfound #docs-dest) #mess-shareware))
   (set #exit-text (cat #mess-congra #mess-shareware) )
)

(exit (#exit-text) )