/*
    $VER: Userfilter.zprx 1.1 (31.7.94) Copyright (c) Jürgen Kohrmeyer

    Dies ist ein ARexx-Skript für Zodiac's  Point,  mit  dem  man  auf
    bequeme Weise  den Absender der  aktuellen  Mail in den Userfilter
    übernehmen  kann. Im  Usernamen  vorkommende  Jokerzeichen  werden
    durch  Voranstellen eines  Hochkommas ausgeschaltet.  Nach erfolg-
    reicher Übernahme in den Filter öffnet sich  das Fenster  und  der
    gerade übernommene Username ist selektiert.

    Sie dürfen dieses Skript beliebig kopieren,  solange  es  zusammen
    mit  Zodiac's  Point  eingesetzt wird, aber verändern Sie es bitte
    nicht ohne Erlaubnis des Autors.

    Sie erreichen den Autor wie folgt:

       Jürgen Kohrmeyer       Tel. : +49 5402 5195
       Oststraße 2            EMail: j_kohrmeyer@wilam.north.de
       49143 Bissendorf

    Hinweise zur Installation:

    Kopieren sie dieses Skript in  das  Rexx-Verzeichnis  von  ZP  und
    fügen  sie  danach  der  Datei  'fkeys.zp'  auf Wunsch den Eintrag
    "F1:SYS:Rexxc/RX ZP:Rexx/Userfilter.zprx %s" hinzu.
*/


/* Ergebnisse anfordern */

OPTIONS RESULTS



/* Name des Screens auslesen */

PARSE ARG screenname
ADDRESS VALUE screenname



/* Script beenden wenn wir uns nicht innerhelb eines Brettes befinden */

WHICHLEVEL

IF result ~= 'BOARD' THEN
   EXIT(0)



/* Absender auslesen */

MESSAGEINFO AUTHOR

IF rc ~= 0 THEN EXIT(10)

absender.pattern    = result
absender.emppattern = ''
absender.newsgroup  = ''
absender.mailtype   = ''
absender.action     = ''



/* Testen, ob MailFilter gestartet ist. Wenn nicht, dann jetzt starten */

IF ~SHOW(PORTS,'MAILFILTER') THEN DO
   ADDRESS COMMAND
   'run >NIL: <NIL: MAILFILTER:MailFilter'

   DO 3 WHILE ~SHOW(PORTS,'MAILFILTER')
      'WaitForPort MAILFILTER'
   END

   IF rc = 5 THEN DO
      SAY 'Kann MailFilter nicht starten!'
      EXIT(10)
   END
END



/* Aktuellen ZPoint-Screen einstellen */

ADDRESS MAILFILTER

GETATTR screen

IF result ~= screenname THEN DO
   DEACTIVATE
   SETATTR screen screenname
END



/* Adresse in den Userfilter übernehmen und das */
/* Fenster auf dem aktuellen MicroDot-Screen öffnen */

ADDITEM TO user STEM absender CONVERT POPUP



/* Prefs speichern */

IF rc = 0 THEN
   SAVE



/* Beenden */

EXIT(0)