/*
    $VER: SeekAndDestroy.zprx 1.0 (10.3.94) by Ralph Seichter
    ARexx script for Zodiac's Point 3.7.

    This script examines the current message's id, jumps to the board
    where the message is supposed to be held, and deletes it there.
    I suggest you to bind this script to an F-Key, e.g. by adding

        F14:SYS:Rexxc/RX ZP:Rexx/SeekAndDestroy.zprx %s

    to your "fkeys.zp" file.
*/

PARSE ARG zpPort
ADDRESS VALUE zpPort
OPTIONS RESULTS

whichlevel
IF (RESULT ~= 'BOARD') THEN DO
    requestnotify 'You must be inside a board!'
    exit
END

messageinfo id
mid = RESULT
messageinfo receiver
rcv = RESULT
IF (mid == '' OR rcv == '') THEN DO
    requestnotify 'Missing ID or receiver!'
    exit
END

boardmenu
jumptoboard 1
jumptoboard name rcv
IF (~RC) THEN DO
    requestnotify "Can't find board" || '0A'X || rcv
    exit
END

enterboard
jumptomessage 1
jumptomessage id mid
IF (~RC) THEN DO
    requestnotify "Can't find message" || '0A'X || mid
    exit
END
delete one
requestnotify 'Message 'mid' deleted.'

/* EOF */