; ***************************************
; *                                     *
; *  ITA1004Config-Installationsskript  *
; *                                     *
; *  $VER: 1.0 (17.02.99) by J.Reinert  *
; *                                     *
; ***************************************



; *************************************************************************
; Definition der globalen Konstanten
; *************************************************************************

(set #liesmichtext  "Lies_mich.TXT")        ; Schlusswort
(set #libssource    "libs/wizard.library")  ; Library
(set #progssource   "ITA1004Config/")       ; Programm

; *************************************************************************
; Version der Workbench bestimmen
; *************************************************************************

(set #os_version (/ (getversion "libs:version.library") 65536))

; *************************************************************************
; Definition der deutschen Texte
; *************************************************************************

(set #msg2
  (cat "\nDas Programm \"ITA1004Config\" ermöglicht Amiga-Anwendern "
       "eine relativ einfache Konfiguration der ISDN-Anlage \"I-TA 1004 II\" von "
       "Conrad-Electronic. Die Eingabe langer Zahlenkolonnen über die "
       "Tastatur des Telefones hat damit ein Ende\n\n"
       "Um das Programm nutzen zu können, sollte Ihr Amiga über 2MB RAM, "
       "komplett installiertem Amiga-OS 3.x und einer freien seriellen "
       "Schnittstelle verfügen."
  )
)

(set #bad-kick
  (cat ""@app-name" benötigt Amiga-OS 3.0 oder höher!\n"
       "Dies wäre jetzt der richtige Zeitpunkt, Ihren "
       "Amiga aufzuwerten. "
  )
)

(set #askdirmsg
  (cat "Wo möchten Sie "@app-name" installieren?. Eine Schublade "
       "mit Namen \"ITA1004Config\" wird erzeugt"
  )
)

(set #wizardhelp
  (cat "Die 'wizard.library' wird zum erzeugen und verwalten der "
       "grafischen Benutzerschnittstelle benötigt."
  )
)

(set #prgprompt "Kopieren des Programmes und Zubehör")

(set #prghelp
  (cat "Bei Erstinstallation sollten Sie alle Dateien auswählen. "
       "Erfahrene Anwender können durch auswählen bestimmter Dateien "
       "auch Updates installieren"
  )
)

; *************************************************************************
; Beginn der Installation
; *************************************************************************

(complete 0)
(if (< #os_version 39)
  (
    (abort #bad-kick)
  )
)
(message #msg2)
(welcome)
(complete 1)

; *************************************************************************
; Zielverzeichnis auswählen lassen
; *************************************************************************

(set name
  (askdir
    (prompt  #askdirmsg)
    (help    #askdirhelp)
    (default @default-dest)
  )
)
(set #destname (tackon name "ITA1004Config"))
(complete 5)

; *************************************************************************
; Datenschubladen erzeugen
; *************************************************************************

(makedir #destname (infos))

(complete 10)

; *************************************************************************
; Kopieren der Librarys
; *************************************************************************

(copylib 
  (prompt "Kopieren der 'wizard.library'") 
  (help #wizardhelp) 
  (source #libssource) 
  (dest "Libs:") 
  (confirm "EXPERT")
)
(complete 20)

; *************************************************************************
; Kopieren des Programms
; *************************************************************************

(copyfiles 
  (prompt #prgprompt) 
  (help #prghelp) 
  (source #progssource) 
  (dest #destname) 
  (all) 
  (confirm "EXPERT")
)
(complete 80)

; *************************************************************************
; Aktuelles Verzeichnis setzen
; *************************************************************************

(set @default-dest #destname)

(complete 100)

; *************************************************************************
; Falls vorhanden, einen LiesMich-Text anzeigen
; *************************************************************************

(if (exists #liesmichtext)
  (run (cat "run sys:utilities/more " #liesmichtext))
)

; *************************************************************************
; Ende der Installation
; *************************************************************************