; ******************************************
; *                                        *
; *   DragonTools-Installationsskript      *
; *                                        *
; *  $VER: 1.0 (08.10.98) by J.Reinert     *
; *                                        *
; ******************************************



; *************************************************************************
; Definition der globalen Konstanten
; *************************************************************************

(set #liesmichtext  "Lies_mich.TXT")        ; Schlusswort
(set #libssource    "libs/wizard.library")  ; Library
(set #progssource   "DragonTools/")         ; Programm

; *************************************************************************
; Version der Workbench bestimmen
; *************************************************************************

(set #os_version (/ (getversion "libs:version.library") 65536))

; *************************************************************************
; Definition der deutschen Texte
; *************************************************************************

(set #msg2
  (cat "\nMit \"DragonTools\" haben auch Amiga-Anwender die "
       "Möglichkeit, die ISDN-Anlage und DataBox \"SpeedDragon\" von Hagenuk "
       "zu konfigurieren und Anruf-Umleitungen bequem zu programmieren "
  )
)

(set #bad-kick
  (cat ""@app-name" benötigt Amiga-OS 3.0 oder höher!\n"
       "Dies wäre jetzt der richtige Zeitpunkt, Ihren "
       "Amiga aufzuwerten. "
  )
)

(set #askdirmsg
  (cat "Bitte wählen Sie ein Ziel für "@app-name". Eine Schublade "
       "mit Namen \"DragonTools\" wird erzeugt"
  )
)

(set #askdirhelp
  (cat "Kopieren Sie die vorliegende Version bitte NICHT über eine "
       "alte DragonTools-Installation!"
  )
)

(set #wizardhelp
  (cat "Die 'wizard.library' wird zum erzeugen und verwalten der "
       "grafischen Benutzerschnittstelle benötigt!"
  )
)

(set #prgprompt "Kopieren des Programmes und Zubehör")

(set #prghelp
  (cat "*Die Dateien \"DragonTools\", \"DragonTools.info\" und \"DragonTools.wizard\" "
       "müssen Sie unbedingt auswählen.\n\n"
       "*Die \"Catalogs\" benötigen Sie für eine deutsche Benutzerführung\n\n"
       "*Ob Sie die \"Docs\" (Anleitungen) umkopieren, überlasse ich Ihnen :)"
  )
)

(set #hinweis
  (cat "\nBeachten Sie bitte, das einige Funktionen von DragonTools nur "
       "dann genutzt werden können, wenn die dafür notwendige Firmware "
       "in der DataBox installiert ist. Wie Sie neue Versionen mit "
       "Ihrem Amiga in die DataBox bekommen, können Sie in der Anleitung "
       "nachlesen\n\n"
       "Wenn Sie DragonTools bereits in einer älteren Version "
       "genutzt hatten, müssen Sie die Programmeinstellungen neu definieren"
  )
)


; *************************************************************************
; Beginn der Installation
; *************************************************************************

(complete 0)
(if (< #os_version 39)
  (
    (abort #bad-kick)
  )
)
(welcome)
(message #msg2)
(complete 1)

; *************************************************************************
; Zielverzeichnis auswählen lassen
; *************************************************************************

(set name
  (askdir
    (prompt  #askdirmsg)
    (help    #askdirhelp)
    (default @default-dest)
  )
)
(set #destname (tackon name "DragonTools"))
(complete 5)

; *************************************************************************
; Datenschubladen erzeugen
; *************************************************************************

(makedir #destname (infos))

(complete 10)

; *************************************************************************
; Kopieren der Librarys
; *************************************************************************

(copylib (prompt "Kopieren der 'wizard.library'") (help #wizardhelp) (source #libssource) (dest "Libs:") (confirm "EXPERT"))
(complete 20)

; *************************************************************************
; Kopieren des Programms
; *************************************************************************

(copyfiles (prompt #prgprompt) (help #prghelp) (source #progssource) (dest #destname) (all) (confirm "EXPERT"))
(complete 80)

; *************************************************************************
; Aktuelles Verzeichnis setzen
; *************************************************************************

(set @default-dest #destname)

(message #hinweis)
(complete 100)

; *************************************************************************
; Falls vorhanden, einen LiesMich-Text anzeigen
; *************************************************************************

(if (exists #liesmichtext)
  (run (cat "run sys:utilities/more " #liesmichtext))
)

; *************************************************************************
; Ende der Installation
; *************************************************************************