;*
;* Install Script For The Boss V2.10
;*  
;* Done By -> AlphaSOUND <-
;*

(set #Langage
  (askchoice
    (prompt "Select your langage for the installer procedure")
    (Help "")
    (choices
      "English"
      "Francais"
    )
  )
)


;*** English ***

(if (= #Langage 0)
  (
  (set #FBDirPrompt "Where do you want to install TheBoss ? A Drawer called TheBoss will be created.")
  (set #FBDirHelp "")
  (set #FBLangSel "Select the languages to install with TheBoss.")
  (set #FBIcon "Select your icons")
  (set #FBExamples "What Examples would you like to install ?")
  )
)


;*** Francais ***

(if (= #Langage 1)
  (
  (set #FBDirPrompt "Où voulez-vous installer TheBoss ? Un Tiroir sera automatiquement créé.")
  (set #FBDirHelp "")
  (set #FBLangSel "Choisissez quels langages vous voulez avoir pour TheBoss")
  (set #FBIcon "Veuillez choisir une sorte d'icone")
  (set #FBExamples "Quels fichiers d'Examples voulez-vous installer ?")
  )
)


;*** Directory Select ***

(complete 0)

(set DestDir
  (askdir
    (prompt #FBDirPrompt)
    (help #FBDirHelp)
    (default "SYS:")
  )
)

(complete 20)

(set DestDir (expandpath DestDir))
(set @default-dest (tackon DestDir "TheBoss"))

(set TheBoss_dir @default-dest)

(makedir @default-dest (infos))

;*** Select Langages ***

(set #Catalogs
  (askoptions
    (prompt #FBLangSel)
    (help "")
    (choices
      "English"
      "Francais"
    )
  )
)

(complete 30)

;*** Select Icon ***

(set #Icons
  (askchoice
    (prompt #FBIcon)
    (Help "")
    (choices
      "MagicWB"
      "Huge MagicWB"
      "NewIcons"
    )
  )
)

(complete 40)

;*** Select Examples ***

;(set #Examples
;  (askoptions
;    (prompt #FBExamples)
;    (help "")
;    (choices
;      "English"
;      "Francais"
;      "None"
;    )
;  )
;)

(complete 50)

;*** Copy Files ***

(if (in #Catalogs 0)
  (
  (copyfiles
    (source "")
    (dest @default-dest)
    (pattern "(TheGuide_English)")
  )

  (set Catalog_dir (tackon TheBoss_dir "Catalogs/English"))

  (makedir Catalog_dir)

  (copyfiles
    (source "Catalogs/English")
    (dest Catalog_dir)
    (pattern "TheBoss.catalog")
  )
  )
)


(if (in #Catalogs 1)
  (
  (copyfiles
    (source "")
    (dest @default-dest)
    (pattern "(TheGuide_Francais)")
  )

  (set Catalog_dir (tackon TheBoss_dir "Catalogs/Français"))

  (makedir Catalog_dir)

  (copyfiles
    (source "Catalogs/Français")
    (dest Catalog_dir)
    (pattern "TheBoss.catalog")
  )
  )
)

(complete 60)

;*** Main Files ***

(copyfiles
  (source "")
  (dest @default-dest)
  (pattern "(TheBoss|ThePrefs|TheBoss.key|TheBoss_Server|TheBoss_Convert)")
  (infos)
)

(set Libs_dir (tackon TheBoss_dir "Libs"))
(makedir Libs_dir)

(copyfiles
  (source "Libs")
  (dest Libs_dir)
  (pattern "WBStart.library")
)

(copyfiles
  (source "")
  (dest @default-dest)
  (pattern "RegForm_English|Register_Français")
  (infos)
)

(complete 80)

;*** Icons Files ***

(if (= #Icons 0)
  (
  (set Icon_Dir "")
  )
)

(if (= #Icons 1)
  (
  (set Icon_Dir "MagicWB_Huge")
  )
)

(if (= #Icons 2)
  (
  (set Icon_Dir "NewIcons")
  )
)

(copyfiles
  (source Icon_Dir)
  (dest @default-dest)
  (pattern "(TheBoss.info|ThePrefs.info)")
)

(complete 90)

(if (in #Catalogs 0)
  (copyfiles
    (source Icon_Dir)
    (dest @default-dest)
    (pattern "TheGuide_English.info")
  )
)

(if (in #Catalogs 1)
  (copyfiles
    (source Icon_Dir)
    (dest @default-dest)
    (pattern "TheGuide_Francais.info")
  )
)

;
; ***** Copy of the Examples files *****
;

(complete 100)