/*
** html_anchor.ced
**
** $VER: html_anchor.ced 2.1 (02.03.1999)
**
** Arexx script for HTML v3.2 anchor mark
**
** This script works with CygnusEd Professional v4.2
**
** Copyright © Eric BELLE
*/

/*
**------------------------------------------------------------------------------
**	Initialisation
**------------------------------------------------------------------------------
*/

OPTIONS RESULTS							/* Tell CygnusEd to return results. */
NL = '0A'X									/* Alias for new line. */
KRETURN = RAWKEY 68					/* Shortcut to the return key. */
KTAB = RAWKEY 66						/* Shortcut to the tab key. */
STATUS TABSARESPACES				/* Return TAB mode ("tab" or "space"). */
IF RESULT = 1								/* Test the TAB mode. */
THEN "TABS = SPACES"				/* Switch TAB mode from "space" to "tab". */
ELSE NOP										/* No operation. */
TAB SIZE 1									/* Set TAB size proportional to 2 spaces. */

/*
**------------------------------------------------------------------------------
**	Anchor identification name
**------------------------------------------------------------------------------
*/

GETSTRING '"Anchor"' '"Indentification name for the anchor?"'
AnchorName= RESULT

IF (AnchorName=" " | AnchorName="RESULT")
THEN EXIT 0
ELSE NOP

/*
**------------------------------------------------------------------------------
**	Anchor mode
**------------------------------------------------------------------------------
*/

AnchorMode = "q"
DO WHILE ~(AnchorMode="t" | AnchorMode="i",
					| AnchorMode=" " | AnchorMode="RESULT")
	GETSTRING "t" '"Anchor mode: (t)ext, (i)mage?"'
	AnchorMode = RESULT
END

SELECT
	WHEN (AnchorMode="RESULT") THEN EXIT 0
	WHEN (AnchorMode=" ") THEN EXIT 0
	WHEN (AnchorMode="i") THEN DO

		/*
		**------------------------------------------------------------------------------
		**	Image anchor name
		**------------------------------------------------------------------------------
		*/

		ImageLocation = "q"
		DO WHILE ~(ImageLocation="l" | ImageLocation="a" | ImageLocation="u",
							| ImageLocation=" " | ImageLocation="RESULT")
			GETSTRING "l" '"Image location: (l)ocal, (a)bsolute, (u)niversal?"'
			ImageLocation = RESULT
		END

		IF (ImageLocation="RESULT" | ImageLocation=" ")
		THEN EXIT 0
		ELSE NOP

		SELECT
			WHEN (ImageLocation="l") THEN DO
				GETSTRING "Image" '"Image name with its relative path?"'
				ImageName = RESULT

				IF (ImageName=" " | ImageName="RESULT")
				THEN EXIT 0
				ELSE NOP

				OpenImage = '<IMG SRC="' || ImageName	||	'"'
			END
			WHEN (ImageLocation="a") THEN DO
				STATUS DIRNAME
				HtmlFileDir = RESULT || "/"

				GETFILENAME HtmlFileDir '"Select Image"'
				ImageName = RESULT

				IF (ImageName=" " | ImageName="RESULT")
				THEN EXIT 0
				ELSE NOP

				OpenImage = '<IMG SRC="file://localhost/' || ImageName	||	'"'
			END
			WHEN (ImageLocation="u") THEN DO
				GETSTRING "Image" '"Image name with its universal path?"'
				ImageName = RESULT

				IF (ImageName="RESULT" | ImageName=" ")
				THEN EXIT 0
				ELSE NOP

				OpenImage = '<IMG SRC="http://' || ImageName	||	'"'
			END
			OTHERWISE NOP
		END

		/*
		**------------------------------------------------------------------------------
		**	Text for image anchor substitution
		**------------------------------------------------------------------------------
		*/

		GETSTRING '"text"' '"Text for image substitution?"'
		ImageText = RESULT

		IF (ImageText="RESULT")
		THEN EXIT 0
		ELSE NOP

		/*
		**------------------------------------------------------------------------------
		**	Image anchor size options
		**------------------------------------------------------------------------------
		*/

		ImageSize = "q"
		DO WHILE ~(ImageSize="y" | ImageSize="n" | ImageSize="d",
							| ImageSize=" " | ImageSize="RESULT")
			GETSTRING "d" '"Image size options: (y)es, (n)o, (d)efault?"'
			ImageSize = RESULT
		END

		IF (ImageSize="RESULT" | ImageSize=" ")
		THEN EXIT 0
		ELSE NOP

		SELECT
			WHEN (ImageSize="d") THEN DO
				ImageWidth = "100"
				ImageHeight = "100"
				ImageBorder = "0"
			END
			WHEN (ImageSize="y") THEN DO
				GETNUMBER "100" '"Width (pixels)?"'
				ImageWidth = RESULT

				IF (ImageWidth="RESULT" | ImageWidth=" ")
				THEN EXIT 0
				ELSE NOP

				GETNUMBER "100" '"Height (pixels)?"'
				ImageHeight = RESULT

				IF (ImageHeight="RESULT" | ImageHeight=" ")
				THEN EXIT 0
				ELSE NOP

				GETNUMBER 0 '"Border (pixels)?"' 0 32768
				ImageBorder = RESULT

				IF (ImageBorder=" ")
				THEN EXIT 0
				ELSE NOP
			END
			OTHERWISE NOP
		END

		/*
		**------------------------------------------------------------------------------
		**	Image anchor position options
		**------------------------------------------------------------------------------
		*/

		ImagePosition = "q"
		DO WHILE ~(ImagePosition="y" | ImagePosition="n" | ImagePosition="d",
							| ImagePosition=" " | ImagePosition="RESULT")
			GETSTRING "d" '"Image position options: (y)es, (n)o, (d)efault?"'
			ImagePosition = RESULT
		END

		IF (ImagePosition="RESULT" | ImagePosition=" ")
		THEN EXIT 0
		ELSE NOP

		SELECT
			WHEN (ImagePosition="d") THEN DO
				ImagePositionMode = "c"
				HorizontalTextDistance = "10"
				VerticalTextDistance = "10"
			END
			WHEN (ImagePosition="y") THEN DO
				ImagePositionMode = "q"
				DO WHILE ~(ImagePositionMode="l" | ImagePositionMode="c" | ImagePositionMode="r",
									| ImagePositionMode=" " | ImagePositionMode="RESULT")
					GETSTRING "c" '"Image position: (l)eft, (c)enter, (r)ight ?"'
					ImagePositionMode = RESULT
				END

				IF (ImagePositionMode="RESULT" | ImagePositionMode=" ")
				THEN EXIT 0
				ELSE NOP

				OKAY2 "You know have to specify the distance " 			||	NL	||,
							"between the image en the surrounding text"		||	NL	||,
							"(Lateral and vertical)."

				IF (RESULT=" " | RESULT="RESULT")
				THEN EXIT 0
				ELSE

				GETNUMBER 10 '"Lateral (pixels)?"' 0 32768
				HorizontalTextDistance = RESULT

				IF (HorizontalTextDistance=" ")
				THEN EXIT 0
				ELSE NOP

				GETNUMBER 10 '"Vertical (pixels)?"' 0 32768
				VerticalTextDistance = RESULT

				IF (VerticalTextDistance=" ")
				THEN EXIT 0
				ELSE NOP
			END
			OTHERWISE NOP
		END

		/*
		**------------------------------------------------------------------------------
		**	Html image anchor marks
		**------------------------------------------------------------------------------
		*/

		IF (ImageSize="n")
		THEN ImageSizeString = ""
		ELSE DO
			ImageSizeString =											" BORDER="	||	ImageBorder
			ImageSizeString = ImageSizeString ||	" WIDTH="		||	ImageWidth
			ImageSizeString = ImageSizeString	||	" HEIGHT="	||	ImageHeight
		END

		SELECT
			WHEN (ImagePositionMode="c") THEN ImagePosition = ""
			WHEN (ImagePositionMode="r") THEN ImagePosition = " ALIGN=RIGHT"
			WHEN (ImagePositionMode="l") THEN ImagePosition = " ALIGN=LEFT"
			OTHERWISE NOP
		END

		IF (ImagePosition="n")
		THEN ImagePositionString = ""
		ELSE DO
			ImagePositionString =	ImagePosition
			ImagePositionString = ImagePositionString ||	" HSPACE=" || HorizontalTextDistance
			ImagePositionString = ImagePositionString	||	" VSPACE=" || VerticalTextDistance
		END

		ImageString =									OpenImage
		ImageString = ImageString || 	' ALT="'    		||	ImageText						|| '"'
		ImageString = ImageString ||	ImageSizeString	||	ImagePositionString || ">"

	END
	OTHERWISE NOP
END

/*
**------------------------------------------------------------------------------
**	HTML anchor structure
**------------------------------------------------------------------------------
*/

OpenAnchor = '<A NAME="' || AnchorName || '">'
CloseAnchor = "</A>"

/*
**------------------------------------------------------------------------------
**	Anchor structure
**------------------------------------------------------------------------------
*/

TEXT OpenAnchor ; "AUTO-INDENT" ; KTAB
IF (AnchorMode="t")
THEN TEXT "Should be modified - Anchor text"
ELSE DO
	IF (ImagepositionMode="c")
	THEN DO
		TEXT "<CENTER>" ; "AUTO-INDENT" ; KTAB
		TEXT ImageString ; "AUTO-INDENT" ; BACKTAB
		TEXT "</CENTER>"
		"DELETE TO EOL"
	END
	ELSE TEXT ImageString
END
"AUTO-INDENT" ; BACKTAB
TEXT CloseAnchor
"DELETE TO EOL"

/*
**------------------------------------------------------------------------------
**	End of html_anchor.ced Arexx script
**------------------------------------------------------------------------------
*/

EXIT 0