;
; $VER: InstallSrpskiWBUpd11 v1.0 (27.4.98)
;
; Installation script for SrpskiWBUpd11 by Andrija Antonijevic
;
;
;                    Andrija Antonijevic <TheAntony@bigfoot.com>
; Copyright ©1997-98                     &
;                        Ljubomir Jankovic <lurch@beotel.yu>
;
;   All rights reserved
;

(set Read
	(cat "Pre nego ãto izvrãite instalaciju SrpskogWB-a, "
		 "preporuàljivo je da proàitate dokumentaciju koja dolazi "
		 "uz njega."
	)
)
(set What		"Ãta biste hteli da instalirate?")
(set WhereDoc	"Gde biste hteli da prekopirate dokumentaciju?")
(set WhereDocDir "Not set")
(set WhichDocs	"U kom formatu biste hteli da bude dokumentacija?")
(set WhereFake	"Gde biste hteli da instalirate FakeTopaz?")
(set CPCError "Doãlo je do greãke prilikom konverzije dokumentacije. Pokuãavam da prekopiram orginalnu dokumentaciju u formatu Srpski.")
(set WhichKeymaps   "Koje rasporede tastera biste hteli da instalirate?\nAko odaberete i stari i novi USA raspored, samo áe novi biti instaliran.")

(set WhatHelp
	(cat "Dokumentacija:\n\nDokumentaciju za SrpskiWBUpd11 "
		 "bi trebalo da proàitate i, ako äelite, instalirate.\n\n"
		 "Direktorijum LOCALE:\n\nOvde su srpski.accent koji je "
		 "neophodan za translator.library v43, svi sistemski katalozi, "
		 "country fajl za Jugoslaviju, pomoáni fajl za AmigaGuide i "
		 "language fajl za srpski.\n\n"
		 "Rasporedi tastera:\n\nRasporedi tastera koji "
		 "se najàeãáe koriste kod nas. Tu su Srpski, CP852, CP1250 i "
		 "ISO8859-2 (Latin-2) u tri formata.\n\n"
		 "Fontovi:\n\nFontovi sa naãim slovima. Tu su fontovi koji áe "
		 "posluäiti kao zamena sistemskih fontova: TopazSrpski, Topaz852, "
		 "TopazBoth (Srpski i CP852 u jednom fontu), Topaz1250, "
		 "Topaz8859-2, Helvetica, NewCleanIBM852, IBMBoth (CP852 i Srpski), "
		 "XEN i Cirilica. Tu su i fontovi koji su korisni za upotrebu na "
		 "Internetu: CourierINet, HelveticaINet i TimesINet koji imaju "
		 "naãa slova po standardima CP1250 i ISO8859-2.\n\n"
		 "Code Page Converter:\n\nProgram koji konvertuje tekstove i "
		 "kataloge iz/u razne kodne strane: Srpski, CP852, CP1250, ISO8859-2, "
		 "YUSCII i ASCII.\n\n"
		 "Fake Topaz:\n\nCommodity koji krpi OpenFont() i svaki poziv "
		 "fonta topaz zamenjuje pozivom fonta TopazSrpski ili "
		 "onoga koga vi podesite."

	)
)


(set NoLocale
	(cat "Na Vaãem sistemu ne postoji assign LOCALE: Proàitajte "
		 "dokumentaciju koja dolazi uz ovaj paket da biste saznali "
		 "moguáe razloge za ovo."
	)
)

(set NoHelp
	(cat "Na Vaãem sistemu ne postoji assign HELP: Proàitajte "
		 "dokumentaciju koja dolazi uz ovaj paket da biste saznali "
		 "moguáe razloge za ovo."
	)
)

(set Final
	(cat "Iako je instalacija bila uspeãna, nije joã sve zavrãeno. "
		 "Pogledajte dokumentaciju da biste videli ãta treba da "
		 "podesite da bi srpski bio u potpunosti instaliran.\n\n"
		 "Poãto ste instalirali srpski na Vaã sistem, verovatno biste "
		 "hteli da naâete srpske kataloge za programe koje koristite. "
		 "Ako imate pristup Internetu, moäete ih naái na\n"
		 "http://ato.vapor.com/ato-serbian\n"
		 "ili na\n"
         "http://www.bitsmart.com/antony/ato-ser.html"
	)
)

(set CurrDir (pathonly @icon))

(message Read)

(if (not (exists "LOCALE:" (noreq))) (abort NoLocale))
(if (not (exists "HELP:" (noreq))) (abort NoHelp))

(set Choose
	(askoptions
    	(prompt What)
		(help WhatHelp)
		(choices "Dokumentaciju" "Direktorijum LOCALE:" "Rasporede tastera" "Fontove" "Code Page Converter" "Fake Topaz")
	)
)

(if (bitand 2 Choose)
	(
		(copyfiles
			(source (tackon CurrDir "Locale/Accents"))
			(dest "LOCALE:Accents")
			(all)
		)
		(copyfiles
			(source (tackon CurrDir "Locale/Catalogs"))
			(dest "LOCALE:Catalogs")
			(all)
		)
		(copyfiles
			(source (tackon CurrDir "Locale/Countries"))
			(dest "LOCALE:Countries")
			(all)
		)
		(copyfiles
			(source (tackon CurrDir "Locale/Languages"))
			(dest "LOCALE:Languages")
			(all)
		)
	)
)

(if (bitand 1 Choose)
	(
		(if (= WhereDocDir "Not set")
			(set WhereDocDir
				(askdir
					(prompt WhereDoc)
					(help @askdir-help)
					(default "HELP:srpski")
				)
			)
		)

		(set ChooseDocs
			(askchoice
    			(prompt WhichDocs)
				(help @askchoice-help)
				(choices "SRPSKI" "CP852" "ASCII" "YUSCII" "CP1250" "ISO8859-2")
			)
		)

		(if (= ChooseDocs 0)
			;then
			(
				(copyfiles
					(source (tackon CurrDir "Docs/SrpskiWBUpd11.guide"))
					(infos)
					(dest WhereDocDir)
				)
			)
			;else
			(
				(if (= ChooseDocs 1) (set ToCP "CP852"))
				(if (= ChooseDocs 2) (set ToCP "ASCII"))
				(if (= ChooseDocs 3) (set ToCP "YUSCII"))
				(if (= ChooseDocs 4) (set ToCP "CP1250"))
				(if (= ChooseDocs 5) (set ToCP "ISO8859-2"))
				(set Result (run (cat "\"" (tackon CurrDir "CPC/CPC") "\"") "INFILE" (cat "\"" (tackon CurrDir "Docs/SrpskiWBUpd11.guide") "\"") "OUTFILE" (cat "\"" (tackon WhereDocDir "SrpskiWBUpd11.guide") "\"") "FROM SRPSKI" "TO" ToCP "OVERWRITE"))
				(if (<> Result 0)
					(
						(message CPCError)
						(copyfiles
							(source (tackon CurrDir "Docs/SrpskiWBUpd11.guide"))
							(dest WhereDocDir)
							(infos)
						)
					)
					(
						(copyfiles
							(source (tackon CurrDir "Docs/SrpskiWBUpd11.guide.info"))
							(dest WhereDocDir)
							(infos)
						)
					)
				)
			)
		)
	)
)

(if (bitand 4 Choose)
	(
		(if (exists "SYS:Storage/Keymaps" (noreq))
			(copyfiles
				(source (tackon CurrDir "Devs/Keymaps"))
				(dest "SYS:Storage/Keymaps")
				(all)
			)
		)

		(set Keymaps
        	(askoptions
            	(prompt WhichKeymaps)
				(help @askoptions-help)
				(default 14)
    		    (choices "USA (stari raspored)" "USA (novi raspored)" "D (nemaàki)" "GB (britanski)")
	        )
        )

		(if (bitand 1 Keymaps)
			(copyfiles
				(source (tackon CurrDir "Devs/Keymaps/USA/Old"))
				(dest "Devs:Keymaps")
				(all)
			)
		)

		(if (bitand 2 Keymaps)
			(copyfiles
				(source (tackon CurrDir "Devs/Keymaps/USA/New"))
				(dest "Devs:Keymaps")
				(all)
			)
		)

		(if (bitand 4 Keymaps)
			(copyfiles
				(source (tackon CurrDir "Devs/Keymaps/D"))
				(dest "Devs:Keymaps")
				(all)
			)
		)

		(if (bitand 8 Keymaps)
			(copyfiles
				(source (tackon CurrDir "Devs/Keymaps/GB"))
				(dest "Devs:Keymaps")
				(all)
			)
		)
	)
)

(if (bitand 8 Choose)
	(
		(copyfiles
			(source (tackon CurrDir "Fonts"))
			(dest "Fonts:")
			(all)
		)
	)
)

(if (bitand 16 Choose)
	(
		(set WhereCPC	"Gde biste hteli da instalirate Code Page Converter?")
		(set WhatCPC	"Ãta biste hteli da instalirate?")
		(set WhatHelpCPC
			(cat "CPC je glavni program i trebalo bi da ga instalirate.\n\n"
				 "CPC.guide je dokumentacija na srpskom (opciono).\n\n"
			)
		)
		(set DefWhatCPC 3)

		(set ChooseCPC
			(askoptions
		    	(prompt WhatCPC)
				(help WhatHelpCPC)
				(choices "CPC" "CPC.guide")
		    	(default DefWhatCPC)
			)
		)

		(if (bitand 1 ChooseCPC)
			(
				(set CPCDir
					(askdir
						(prompt WhereCPC)
						(help @askdir-help)
						(default "C:")
					)
				)

				(copyfiles
					(source (tackon CurrDir "CPC/CPC"))
					(dest CPCDir)
					(infos)
				)
			)
		)

		(if (bitand 2 ChooseCPC)
			(
				(if (= WhereDocDir "Not set")
					(set WhereDocDir
						(askdir
							(prompt WhereDoc)
							(help @askdir-help)
							(default "HELP:srpski")
						)
					)
				)

				(copyfiles
					(source (tackon CurrDir "CPC/CPC.guide"))
					(infos)
					(dest WhereDocDir)
					(infos)
				)
			)
		)
	)
)

(if (bitand 32 Choose)
	(
		(set WhereFakeDir
			(askdir
				(prompt WhereFake)
				(help @askdir-help)
				(default "SYS:WBStartup")
			)
		)

		(copyfiles
			(source "FakeTopaz")
			(infos)
			(dest WhereFakeDir)
		)

		(if (= WhereDocDir "Not set")
			(set WhereDocDir
				(askdir
					(prompt WhereDoc)
					(help @askdir-help)
					(default "HELP:srpski")
				)
			)
		)

		(copyfiles
			(source "FakeTopaz.guide")
			(infos)
			(dest WhereDocDir)
		)
	)
)

(message Final)

(set @default-dest "LOCALE:")
(exit)