; AGAiff
; Include > window.s

ShowWindow	tst.l	window-j(a5)
		bne.w	.already
		move.l	intbase-j(a5),a6
		tst.b	actpubscreen		;PubScreen angegeben ?
		beq.s	.nopub
		lea	actpubscreen,a0
		bra.s	.yespub
.nopub		sub.l	a0,a0
.yespub		LIBCALL	LockPubScreen
		move.l	d0,wbscreen-j(a5)
		beq.s	.nopub		;nicht da --> Workbench ? ich weiß, ist riskant..
		move.l	d0,a0
		lea	sc_ViewPort(a0),a0
		move.l	gfxbase(pc),a6
		LIBCALL	GetVPModeID
		move.l	d0,wbmodeid-j(a5)

		tst.w	PREFS_font-j(a5)
		bne.s	.usetopaz
		clr.w	whichfont
		bsr	InitWindow
		bne.s	.2
.usetopaz	st	whichfont
		bsr	InitWindow
		beq	swnowin
.2		bsr	UpdateFormatGadgets

.already	tst.w	activate_window-j(a5)
		beq.s	.noact
		bsr	WindowNachVorne
.noact		moveq	#-1,d0
		rts

whichfont	dc.w	0	;0 = Screen, <>0 = topaz

wbmodeid	dc.l	0
wbscreen	dc.l	0
visualinfo	dc.l	0
glistpointer	dc.l	0	;für CreateGadget/gadtools
gad		dc.l	0
actsaveformat1	dc.w	0
actsaveformat2	dc.w	0
actcolsformat1	dc.w	0
actcolsformat2	dc.w	0

HideWindow	tst.l	window-j(a5)
		beq	hwalready
	
		bsr	ClosePrefsWindow
		bsr	ClosePresetsWindow
		bsr	ClosePic
		bsr	DeallocPictureSpace
		bsr	FreeWindow
swnowin		clr.w	NOSHOWflag-j(a5)
hwalready	moveq	#0,d0
		rts

InitWindow	move.l	gadbase-j(a5),a6
		move.l	wbscreen(pc),a0
		sub.l	a1,a1
		LIBCALL	GetVisualInfoA
		move.l	d0,visualinfo-j(a5)
		lea	glistpointer-j(a5),a0
		LIBCALL	CreateContext
		move.l	d0,gad-j(a5)
		beq	iwnocontext

		bsr	calccoordinates

Gadget		macro		; Gadget KIND,struct,tags
		moveq	#\1,d0
		lea	\2(pc),a1
		lea	\3(pc),a2
		bsr	mgsub1
		beq	iwnogadgets
		endm

again		Gadget	LISTVIEW_KIND,gad0,gad0t
		move.l	d0,listgadget-j(a5)
		Gadget	TEXT_KIND,gad1,gad1t
		move.l	d0,modegadget-j(a5)
		Gadget	TEXT_KIND,gad2,gad1t
		move.l	d0,depthgadget-j(a5)
		Gadget	CYCLE_KIND,gad4,gad4t
		move.l	d0,sfor1gadget-j(a5)
		Gadget	CYCLE_KIND,gad5,gad5t
		move.l	d0,sfor2gadget-j(a5)
		Gadget	CYCLE_KIND,gad6,gad6t
		move.l	d0,cfor1gadget-j(a5)
		Gadget	CYCLE_KIND,gad7,gad7t
		move.l	d0,cfor2gadget-j(a5)
		Gadget	TEXT_KIND,gad8,gad8t
		move.l	d0,textgadget-j(a5)
		Gadget	BUTTON_KIND,gad9,notagz
		Gadget	BUTTON_KIND,gad10,notagz
		move.l	d0,savegadget-j(a5)
		Gadget	BUTTON_KIND,gad14,gad14t
		Gadget	BUTTON_KIND,gad15,notagz
		Gadget	NUMBER_KIND,gad11,numgadt
		move.l	d0,picxgadget-j(a5)
		Gadget	NUMBER_KIND,gad12,numgadt
		move.l	d0,picygadget-j(a5)
		Gadget	TEXT_KIND,gad13,gad13t
		move.l	d0,modeidtgadget-j(a5)
		Gadget	INTEGER_KIND,gad16,intgadt
		move.l	d0,rangeX1gadget-j(a5)
		Gadget	INTEGER_KIND,gad17,intgadt
		move.l	d0,rangeY1gadget-j(a5)
		Gadget	INTEGER_KIND,gad18,intgadt
		move.l	d0,rangeX2gadget-j(a5)
		Gadget	INTEGER_KIND,gad19,intgadt
		move.l	d0,rangeY2gadget-j(a5)
		Gadget	BUTTON_KIND,gad4.1,notagz
		Gadget	BUTTON_KIND,gad22,notagz
		Gadget	BUTTON_KIND,gad23,notagz
		Gadget	BUTTON_KIND,gad24,notagz

		Gadget	TEXT_KIND,gad25,gad1t
		move.l	d0,anim1gadget-j(a5)
		Gadget	BUTTON_KIND,gad31,diztagz
		move.l	d0,anim7gadget-j(a5)

		move.w	newwindowtags+6(pc),d0	* Fenstergröße mit
		add.w	wborderl(pc),d0		* Maximalgröße vergleichen!!!
		move.l	wbscreen(pc),a0
		moveq	#0,d2
		move.b	sc_WBorRight(a0),d2
		add.w	d2,d0	;X-Größe
		move.w	newwindowtags+14(pc),d1
		add.w	wbordert(pc),d1
		move.b	sc_WBorBottom(a0),d2
		add.w	d2,d1	;Y-Größe

		cmp.w	12(a0),d0
		bhi	iwnowindow
		cmp.w	14(a0),d1
		bhi	iwnowindow

		move.l	intbase(pc),a6
		lea	newwindow(pc),a0
		lea	newwindowtags(pc),a1
		move.l	glistpointer(pc),nw_FirstGadget(a0)
		move.l	wbscreen(pc),nw_Screen(a0)
		LIBCALL	OpenWindowTagList
		move.l	d0,window-j(a5)
		beq	iwnowindow

		move.l	window(pc),a0
		move.l	wd_RPort(a0),rastport-j(a5)
		move.l	wd_UserPort(a0),a0
		move.l	a0,windowport-j(a5)
		move.b	MP_SIGBIT(a0),Signal.window
	
		move.l	gfxbase(pc),a6
		lea	textattr(pc),a0
		LIBCALL	OpenFont
		move.l	d0,a0
		move.l	d0,d3
		move.l	rastport(pc),a1
		LIBCALL	SetFont
		move.l	d3,a1
		LIBCALL	CloseFont
	
		move.l	gadbase(pc),a6
		move.l	window(pc),a0
		sub.l	a1,a1
		LIBCALL	GT_RefreshWindow
		bsr	dowindowgfx
		move.l	DispModeList+LH_HEAD(pc),a0
		move.l	LN_SIZE+32(a0),load.modeid-j(a5)
		bsr	UpdateModeID
		bsr	DisableSaveGadgets
		moveq	#-1,d0
		rts

mgsub1		move.l	gad-j(a5),a0
		move.l	#textattr,12(a1)
		move.l	visualinfo-j(a5),22(a1)
		move.l	gadbase(pc),a6
		LIBCALL	CreateGadgetA
		move.l	d0,gad-j(a5)
		rts

WindowNachVorne	move.l	intbase(pc),a6
		move.l	wbscreen(pc),a0
		LIBCALL	ScreenToFront
		move.l	window(pc),a0
		LIBCALL	WindowToFront
		move.l	window(pc),a0
		LIBCALL	ActivateWindow
		rts

EnableSaveGadgets
		moveq	#0,d4
		bra.s	DisableSaveGadgetENTRY
DisableSaveGadgets
		moveq	#1,d4
DisableSaveGadgetENTRY
		move.w	d4,save_disabled-j(a5)
		lea	ChangeGadMode(pc),a2
		move.w	d4,d0
		move.l	savegadget(pc),a0
		jsr	(a2)
		move.w	d4,d0
		move.l	rangeX1gadget(pc),a0
		jsr	(a2)
		move.w	d4,d0
		move.l	rangeY1gadget(pc),a0
		jsr	(a2)
		move.w	d4,d0
		move.l	rangeX2gadget(pc),a0
		jsr	(a2)
		move.w	d4,d0
		move.l	rangeY2gadget(pc),a0
		jmp	(a2)

textattr	dc.l	0
fy		dc.w	0,0
fx		dc.w	0
basel		dc.w	0

newwindow	dc.w	0,0,0,0,1
		dc.l	GADGETSIDCMP!$200!$8!IDCMP_VANILLAKEY!IDCMP_RAWKEY
newwindowflags	dc.l	$1000e
		dc.l	0,0,windowname,0,0
		dc.w	0,0,-1,-1,15
newwindowtags	dc.l	WA_InnerWidth,580
		dc.l	WA_InnerHeight,100
		dc.l	WA_AutoAdjust,1
		dc.l	TAG_DONE
windowname	dc.b	"AGAiff V",VERSION,".",REVISION
		dc.b	" by Michael Krause"
windownamemod	dc.b	"  Hotkey: "
Hotkey.text	dc.b	"ctrl alt i",0
		ds.b	50
		even

modeidtgadget	dc.l	0	;Textview für 'Mode-ID:...'
textgadget	dc.l	0	;Textview für Meldungen
picxgadget	dc.l	0
picygadget	dc.l	0
listgadget	dc.l	0
depthgadget	dc.l	0
modegadget	dc.l	0
rangeX1gadget	dc.l	0
rangeY1gadget	dc.l	0
rangeX2gadget	dc.l	0
rangeY2gadget	dc.l	0
savegadget	dc.l	0
sfor1gadget	dc.l	0
sfor2gadget	dc.l	0
cfor1gadget	dc.l	0
cfor2gadget	dc.l	0
anim1gadget	dc.l	0
anim7gadget	dc.l	0

windowport	dc.l	0
rastport	dc.l	0
window		dc.l	0

dowindowgfx	move.l	gfxbase(pc),a6
		move.l	rastport(pc),a4
		move.l	a4,a1
		moveq	#1,d0
		LIBCALL	SetAPen
		move.w	cccolumn1start(pc),d0
		move.w	gad13+2(pc),d1
		add.w	basel(pc),d1
		move.l	a4,a1
		LIBCALL	Move
		lea	modeIDtext(pc),a0
		moveq	#8,d0
		move.l	a4,a1
		LIBCALL	Text
		rts

modeIDtext	dc.b	"Mode-ID:"
modeIDtext2	dc.b	"$"
modeIDtextmod	dc.b	"00000000",0
modeIDtextl	equ	*-modeIDtext
		even

TextL		; a0 *string, d0 stringlength
		movem.l	d1/a1,-(sp)
		tst.w	topazflag
		bne.s	.1
		lsl.w	#3,d0
		bra.s	.2
.1		move.l	gfxbase(pc),a6
		move.l	wbscreen(pc),a1
		lea	sc_RastPort(a1),a1
		LIBCALL	TextLength
.2		movem.l	(sp)+,d1/a1
		rts


FreeWindow	move.l	intbase(pc),a6
		move.l	window(pc),a0
		LIBCALL	CloseWindow
		clr.l	window-j(a5)
		move.w	#-1,Signal.window
iwnogadgets
iwnowindow	move.l	gadbase-j(a5),a6
		move.l	glistpointer(pc),a0
		LIBCALL	FreeGadgets
iwnocontext	move.l	gadbase-j(a5),a6
		move.l	visualinfo-j(a5),a0
		LIBCALL	FreeVisualInfo
		move.l	intbase-j(a5),a6
		sub.l	a0,a0
		move.l	wbscreen-j(a5),a1
		LIBCALL	UnlockPubScreen
		moveq	#0,d0
		rts

calccoordinates	move.l	intbase(pc),a6	;Kernstück für die
		move.l	wbscreen(pc),a0	;Fontsensitivität -
		LIBCALL	GetScreenDrawInfo	;berechnet abhängig
		move.l	d0,drawinfo	;vom eingestellten Font
		move.l	d0,a0	;die Koordinaten
		move.l	dri_Font(a0),a0	;der Gadgets
		tst.w	whichfont
		bne.s	.1
		move.l	LN_NAME(a0),textattr
		move.w	tf_YSize(a0),fy
		move.w	tf_XSize(a0),fx
		move.w	tf_Baseline(a0),basel
		bra.s	.2
.1		move.l	#topazname,textattr
		move.w	#8,fy
		move.w	#8,fx
		move.w	#6,basel
.2		move.l	wbscreen(pc),a0
		move.l	drawinfo(pc),a1
		LIBCALL	FreeScreenDrawInfo
		move.l	wbscreen(pc),a0
		move.w	sc_RastPort+rp_TxHeight(a0),d0
		add.b	sc_WBorTop(a0),d0
		addq.b	#1,d0
		move.b	d0,wbordert+1-j(a5)
		move.b	sc_WBorLeft(a0),wborderl+1-j(a5)

; zur Übersichtlichkeit:
;
; in d6 wird jeweils die letzte Y-Koordinate gespeichert !! (manchmal...)
; in d7 Höhe eines Standard-Gadgets !!

		st	topazflag	;wird topaz-8 verwendet ?
		cmp.w	#8,textattr+4
		bne.s	.notopaz
		move.l	utilbase(pc),a6
		move.l	textattr(pc),a0
		lea	topazname(pc),a1
		LIBCALL	Stricmp
		tst.l	d0
		bne.s	.notopaz
		clr.w	topazflag
.notopaz
		lea	gad0(pc),a0	* listview-gadget
		move.w	fx(pc),d0
		lsl.w	#5,d0
		move.w	d0,4(a0)	;Breite
		move.w	d0,cccolumnwidth
		move.w	fy(pc),d0
		mulu.w	#4,d0
		add.w	#4,d0
		move.w	d0,6(a0)	;Höhe
		move.w	fx(pc),d0
		add.w	d0,d0
		move.w	d0,gad0t+6-j(a5) 	;Scrollbalken
		move.w	wborderl(pc),d0
		addq.w	#4,d0
		move.w	d0,d6
		move.w	d0,cccolumn1start-j(a5)
		move.w	d0,(a0)	;X
		move.w	wbordert(pc),d0
		addq.w	#2,d0
		move.w	d0,cccolumnystart-j(a5)
		move.w	d0,2(a0)	;Y
		move.w	d0,d6
	
		move.w	fy(pc),d2
		addq.w	#4,d2
		move.w	d2,d7
		move.w	d7,cccycleheight-j(a5)
	
		lea	gad1(pc),a3	* type/depth-gadget
		lea	gad2(pc),a4
		move.w	cccolumnwidth(pc),d1
		lea	gad1text,a0
		moveq	#4,d0
		bsr	TextL
		sub.w	d0,d1
		move.w	d0,d4
		lea	gad2text,a0
		moveq	#5,d0
		bsr	TextL
		sub.w	d0,d1
		sub.w	#24,d1
		move.w	d1,d2
		lsr.w	#1,d1
		move.w	d1,4(a3)	;Breite Type
		sub.w	d1,d2
		move.w	d2,4(a4)	;Breite Depth
		addq.w	#8,d4
		add.w	cccolumn1start(pc),d4
		move.w	d4,(a3)		;X Type
		add.w	d1,d4
		add.w	d0,d4
		add.w	#16,d4
		move.w	d4,(a4)		;X Depth
		move.w	d7,6(a3)
		move.w	d7,6(a4)
		move.w	gad0+2(pc),d1
		add.w	gad0+6(pc),d1
		addq.w	#2,d1
		move.w	d1,2(a3)
		move.w	d1,2(a4)
		move.w	d1,d6
	
		move.w	cccolumnwidth(pc),d2	*Reshow/Restore
		subq.w	#8,d2
		lsr.w	#1,d2
		move.w	d7,d3
		move.w	d6,d1
		add.w	d7,d1
		addq.w	#2,d1
		move.w	d1,d6
		move.w	cccolumn1start(pc),d0
		movem.w	d0-d3,gad22-j(a5)
		add.w	d2,d0
		addq.w	#8,d0
		movem.w	d0-d3,gad23-j(a5)
	
		lea	gad8(pc),a3	* textview-gadget
		move.w	d6,d0
		addq.w	#2,d0
		add.w	gad2+6(pc),d0
		addq.w	#2,d0
		add.w	fy(pc),d0
		move.w	d0,2(a3)
		move.w	d0,d6
		move.w	cccolumn1start(pc),d0
		move.w	d0,(a3)
		add.w	cccolumnwidth(pc),d0
		add.w	cccolumnwidth(pc),d0
		add.w	#8,d0
		move.w	d0,4(a3)
		move.w	d7,6(a3)
	
		lea	gad4.1(pc),a3	* save-presets
		move.w	cccolumnwidth(pc),d1
		move.w	d1,4(a3)	;Breite
		move.w	d7,6(a3)	;Höhe
		move.w	cccolumn1start(pc),d1
		add.w	cccolumnwidth(pc),d1
		add.w	#16,d1
		move.w	d1,cccolumn2start-j(a5)
		move.w	d1,(a3)
		move.w	cccolumnystart(pc),d0
		move.w	d0,2(a3)	;Y
		move.w	d0,d6

		lea	gad4(pc),a3	* saveformat
		lea	gad4text,a0
		moveq	#4,d0
		bsr	TextL
		move.w	cccolumnwidth(pc),d1
		sub.w	d0,d1
		subq.w	#8,d1
		move.w	d1,4(a3)
		move.w	d7,6(a3)
		add.w	cccolumn2start(pc),d0
		addq.w	#8,d0
		move.w	d0,(a3)
		move.w	d6,d0
		add.w	d7,d0
		addq.w	#6,d0
		move.w	d0,2(a3)
		move.w	d0,d6
	
		lea	gad5(pc),a3	* saveformat II
		movem.w	gad4(pc),d0-d3
		add.w	d7,d1
		addq.w	#2,d1
		movem.w	d0-d3,(a3)
		move.w	d1,d6

		lea	gad6(pc),a3	* colors
		lea	gad6text,a0
		moveq	#6,d0
		bsr	TextL
		move.w	cccolumnwidth(pc),d1
		sub.w	d0,d1
		subq.w	#8,d1
		move.w	d1,4(a3)
		move.w	d7,6(a3)
		add.w	cccolumn2start(pc),d0
		addq.w	#8,d0
		move.w	d0,(a3)
		move.w	d6,d0
		add.w	d7,d0
		addq.w	#2,d0
		move.w	d0,2(a3)
		move.w	d0,d6
	
		lea	gad7(pc),a3	* colors II
		movem.w	gad6(pc),d0-d3
		add.w	d7,d1
		addq.w	#2,d1
		movem.w	d0-d3,(a3)
		move.w	d1,d6

		lea	gad9(pc),a3	* load/save/arexx
		move.w	gad8+2(pc),d0
		add.w	gad8+6(pc),d0
		addq.w	#2,d0
		move.w	d0,2(a3)
		move.w	d0,d6
		move.w	d7,6(a3)
		move.w	cccolumn2start(pc),d2
		move.w	d2,(a3)
		moveq	#0,d1
		move.w	cccolumnwidth(pc),d1
		sub.w	#16,d1
		divu.w	#3,d1
		move.w	d1,4(a3)
		lea	gad10(pc),a2
		move.w	d1,4(a2)
		move.w	d7,6(a2)
		add.w	d1,d2
		addq.w	#8,d2
		move.w	d2,(a2)
		move.w	d6,2(a2)
		lea	gad14(pc),a2
		move.w	d1,4(a2)
		move.w	d7,6(a2)
		add.w	d1,d2
		addq.w	#8,d2
		move.w	d2,(a2)
		move.w	d6,2(a2)
	
		sub.w	d1,gad8+4-j(a5)
		subq.w	#8,gad8+4-j(a5)
		movem.w	gad14(pc),d0-d3
		sub.w	d7,d1
		subq.w	#2,d1
		movem.w	d0-d3,gad24-j(a5)
	
		lea	gad11(pc),a2	* picsize
		lea	gad12(pc),a3
		move.w	d6,2(a2)
		move.w	d6,2(a3)
		move.w	d7,6(a2)
		move.w	d7,6(a3)
		move.w	cccolumn1start(pc),d2
		move.w	cccolumnwidth(pc),d3
		lea	gad11text,a0
		moveq	#15,d0
		bsr	TextL
		add.w	d0,d2
		addq.w	#8,d2
		move.w	d2,(a2)
		sub.w	d0,d3
		lea	gad12text,a0
		moveq	#1,d0
		bsr	TextL
		sub.w	d0,d3
		sub.w	#3*8,d3
		lsr.w	#1,d3
		move.w	d3,4(a2)
		move.w	d3,4(a3)
		add.w	d3,d2
		add.w	d0,d2
		add.w	#16,d2
		move.w	d2,(a3)
	
		lea	gad13(pc),a2	* modeID !!
		move.w	gad22+2(pc),d0
		add.w	gad22+6(pc),d0
		addq.w	#2,d0
		move.w	d0,2(a2)
		move.w	cccolumn1start(pc),d3
		move.w	d3,d2
		lea	modeIDtext,a0
		moveq	#8,d0
		bsr	TextL
		add.w	d0,d3
		addq.w	#8,d3
		move.w	d3,(a2)
		move.w	fy(pc),6(a2)
		move.w	cccolumnwidth(pc),d2
		sub.w	d0,d2
		sub.w	(a2),d2
		move.w	d2,4(a2)
	
		lea	gad15(pc),a2	* quit
		movem.w	gad14(pc),d0-d3
		movem.w	d0-d3,(a2)
		add.w	d7,2(a2)
		addq.w	#2,2(a2)
	
		move.w	cccolumnwidth(pc),d3	* range-gadgets
		add.w	d3,d3
		add.w	#8,d3
		sub.w	gad15+4(pc),d3
		lea	gad16text2,a0
		moveq	#11,d0
		bsr	TextL
		move.w	d0,-(sp)
		sub.w	d0,d3
		lea	gad17text,a0
		moveq	#1,d0
		bsr	TextL
		move.w	d0,-(sp)
		sub.w	d0,d3
		sub.w	d0,d3
		lea	gad18text,a0
		moveq	#1,d0
		bsr	TextL
		move.w	d0,-(sp)
		sub.w	d0,d3
		sub.w	#4*16-8,d3
		lsr.w	#2,d3
		move.w	d3,d2
		move.w	4(sp),d0
		add.w	#16,d0
		move.w	d7,d3
		move.w	gad15+2(pc),d1
		movem.w	d0-d3,gad16-j(a5)
		add.w	2(sp),d0
		add.w	d2,d0
		add.w	#16,d0
		movem.w	d0-d3,gad17-j(a5)
		add.w	(sp),d0
		add.w	d2,d0
		add.w	#16,d0
		movem.w	d0-d3,gad18-j(a5)
		add.w	2(sp),d0
		add.w	d2,d0
		add.w	#16,d0
		movem.w	d0-d3,gad19-j(a5)
		addq.w	#6,sp

		move.w	gad8(pc),d2		* frame
		lea	gad25text,a0
		moveq	#gad25textl,d0
		bsr	TextL
		add.w	d0,d2
		addq.w	#8,d2
		move.w	d2,gad25-j(a5)
		move.w	cccolumnwidth(pc),d0
		add.w	d0,d0
		add.w	#16,d0
		sub.w	d2,d0
		sub.w	gad15+4(pc),d0
		move.w	d0,gad25+4-j(a5)
		move.w	gad16+2(pc),d0
		add.w	d7,d0
		addq.w	#2,d0
		move.w	d0,gad25+2-j(a5)
		move.w	d7,gad25+6-j(a5)

		movem.w	gad15(pc),d0-d3		* new
		move.w	gad25+2(pc),d1
		move.w	gad25+6(pc),d3
		movem.w	d0-d3,gad31-j(a5)
	
		move.w	cccolumnwidth(pc),d0	* window-größe
		add.w	d0,d0
		add.w	#24,d0
		move.w	d0,newwindowtags+6-j(a5)
		move.w	gad0+6(pc),d0 ;liste
		add.w	gad1+6(pc),d0 ;mode
		add.w	gad2+6(pc),d0 ;depth
		add.w	fy(pc),d0     ;modeID-text
		add.w	gad8+6(pc),d0 ;textview
		add.w	gad9+6(pc),d0 ;load/save
		add.w	gad15+6(pc),d0 ;range/quit
		add.w	gad15+6(pc),d0 ;anim
		add.w	#8+2+2+2+2+2,d0
		move.w	d0,newwindowtags+14-j(a5)
		move.l	wbscreen(pc),a0
		moveq	#0,d0
		move.b	sc_BarHeight(a0),d0
		addq.w	#1,d0
		move.w	d0,newwindow+2-j(a5)
		rts

topazflag	dc.w	0
wborderl	dc.w	0
wbordert	dc.w	0
drawinfo	dc.l	0
topazname	dc.b	"topaz.font",0
		even

cccolumn1start	dc.w	0
cccolumn2start	dc.w	0
cccolumnystart	dc.w	0
cccolumnwidth	dc.w	0
cccycleheight	dc.w	0

gad0		dc.w	0,0,0,0
		dc.l	0,0
		dc.w	0	;-> ID !! <-
		dc.l	0,0,0
gad0t		dc.l	GTLV_ScrollWidth,0
		dc.l	GTLV_Top,0
		dc.l	GTLV_Labels,DispModeList
		dc.l	GTLV_ShowSelected,0
		dc.l	GTLV_Selected,0
		dc.l	TAG_DONE
gad1		dc.w	0,0,0,0
		dc.l	gad1text,0
		dc.w	-1
		dc.l	0,0,0
gad1t		dc.l	GTTX_Text,0
		dc.l	GTTX_Border,1
		dc.l	TAG_DONE

gad2		dc.w	0,0,0,0
		dc.l	gad2text,0
		dc.w	-1
		dc.l	0,0,0

gad4		dc.w	0,0,0,0
		dc.l	gad4text,0
		dc.w	1
		dc.l	0,0,0
gad4t		dc.l	GTCY_Active,0
		dc.l	GTCY_Labels,gad4labels
		dc.l	GT_Underscore,"____"
		dc.l	TAG_DONE
gad4labels	dc.l	.1,.2,.3,.4,.5,.6,.7,.8,.9,.10,0
.1		dc.b	"IFF-ILBM",0
.2		dc.b	"RAW Standard",0
.3		dc.b	"RAW Interleaved",0
.4		dc.b	"[no picture data]",0
.5		dc.b	"Copperlist",0
.6		dc.b	"Sprite",0
.7		dc.b	"Mask",0
.8		dc.b	"Mask (1 plane)",0
.9		dc.b	"Unpacked Chunky",0
.10		dc.b	"Chunky Colors",0
		even
gad5		dc.w	0,0,0,0
		dc.l	0,0
		dc.w	2
		dc.l	0,0,0
gad5t		dc.l	GTCY_Active,0
		dc.l	GTCY_Labels,gad5labels
		dc.l	TAG_DONE
gad5labels	dc.l	.1,.2,.3,0
.1		dc.b	"File",0
.2		dc.b	"dc.X",0
.3		dc.b	"db (PC)",0
		even
gad6		dc.w	0,0,0,0
		dc.l	gad6text,0
		dc.w	3
		dc.l	0,0,0
gad6t		dc.l	GTCY_Active,0
		dc.l	GTCY_Labels,gad6labels
		dc.l	GT_Underscore,"____"
		dc.l	TAG_DONE
gad6labels	dc.l	.1,.2,.3,0
.1		dc.b	"[no colors]",0
.2		dc.b	"Top",0
.3		dc.b	"Bottom",0
		even
gad7		dc.w	0,0,0,0
		dc.l	0,0
		dc.w	4
		dc.l	0,0,0
gad7t		dc.l	GTCY_Active,0
		dc.l	GTCY_Labels,gad7labels
		dc.l	TAG_DONE
gad7labels	dc.l	.1,.2,.3,.4,.5,.6,.7,.8,.9,0
.1		dc.b	"12 Bit",0
.2		dc.b	"24 Bit 0RGB",0
.3		dc.b	"24 Bit RGB0",0
.4		dc.b	"24 Bit RGB",0
.5		dc.b	"24 Bit HL",0
.6		dc.b	"24 Bit HLi",0
.7		dc.b	"24 Bit LH",0
.8		dc.b	"24 Bit LHi",0
.9		dc.b	"96 Bit",0
		even
gad8		dc.w	0,0,0,0
		dc.l	0,0
		dc.w	-1
		dc.l	0,0,0
gad8t		dc.l	GTTX_Text,welcometext
		dc.l	GTTX_Border,1
		dc.l	TAG_DONE
gad9		dc.w	0,0,0,0
		dc.l	gad9text,0
		dc.w	5
		dc.l	0,0,0
gad10		dc.w	0,0,0,0
		dc.l	gad10text,0
		dc.w	6
		dc.l	0,0,0
intgadt		dc.l	GTIN_Number,0
		dc.l	GTIN_MaxChars,4
		dc.l	GT_Underscore,"____"
		dc.l	GA_Disabled,1
		dc.l	TAG_DONE
numgadt		dc.l	GTNM_Number,0
		dc.l	GTNM_Border,1
		dc.l	TAG_DONE
gad11		dc.w	0,0,0,0
		dc.l	gad11text,0
		dc.w	-1
		dc.l	0,0,0
gad12		dc.w	0,0,0,0
		dc.l	gad12text,0
		dc.w	-1
		dc.l	0,0,0
gad13		dc.w	0,0,0,0
		dc.l	0,0
		dc.w	-1
		dc.l	0,0,0
gad13t		dc.l	GTTX_Border,0
		dc.l	TAG_DONE

gad14		dc.w	0,0,0,0	;in der gleiche Zeile
		dc.l	gad14text,0	;wie Load/Save/Picsize
		dc.w	13
		dc.l	0,0,0
gad14t		dc.l	GA_Disabled,1
		dc.l	GT_Underscore,"____"
		dc.l	TAG_DONE

gad15		dc.w	0,0,0,0
		dc.l	gad15text,0
		dc.w	7
		dc.l	0,0,0
gad16		dc.w	0,0,0,0
		dc.l	gad16text,0
		dc.w	8
		dc.l	0,0,0
gad17		dc.w	0,0,0,0
		dc.l	gad17text,0
		dc.w	9
		dc.l	0,0,0
gad18		dc.w	0,0,0,0
		dc.l	gad18text,0
		dc.w	10
		dc.l	0,0,0
gad19		dc.w	0,0,0,0
		dc.l	gad17text,0
		dc.w	11
		dc.l	0,0,0
gad4.1		dc.w	0,0,0,0
		dc.l	gad4.1text,0
		dc.w	12
		dc.l	0,0,0
gad22		dc.w	0,0,0,0
		dc.l	gad22text,0
		dc.w	14
		dc.l	0,0,0
gad23		dc.w	0,0,0,0
		dc.l	gad23text,0
		dc.w	15
		dc.l	0,0,0
gad24		dc.w	0,0,0,0
		dc.l	gad24text,0
		dc.w	16
		dc.l	0,0,0

; -- Animation gADGETS

gad25		dc.w	0,0,0,0
		dc.l	gad25text,0
		dc.w	-1
		dc.l	0,0,0
gad31		dc.w	0,0,0,0
		dc.l	gad31text,0
		dc.w	17
		dc.l	0,0,0


gad1text	dc.b	"Type",0
gad2text	dc.b	"Depth",0
gad4text	dc.b	"D_ata",0
gad6text	dc.b	"C_olors",0
welcometext	dc.b	"Welcome to AGAiff V",VERSION,".",REVISION,"!",0
gad9text	dc.b	"_Load",0
gad10text	dc.b	"_Save",0
gad11text	dc.b	"Picture Size: X",0
gad12text	dc.b	"Y",0
gad14text	dc.b	"ARe_xx",0
gad15text	dc.b	"Exit",0
gad16text	dc.b	"Save _Range:",0
gad16text2	dc.b	"Save Range:",0
gad17text	dc.b	"/",0
gad18text	dc.b	":",0
gad4.1text	dc.b	"Save Format Settings",0
gad22text	dc.b	"Reshow",0
gad23text	dc.b	"Restore",0
gad24text	dc.b	"_Prefs",0
gad25text	dc.b	"Animation Control:  Frame",0
gad25textl	equ	*-gad25text-1
gad31text	dc.b	"Next",0
		even

notagz		dc.l	GT_Underscore,"____"
		dc.l	TAG_DONE
diztagz		dc.l	GT_Underscore,"____"
		dc.l	GA_Disabled,1
		dc.l	TAG_DONE