; M2I 5.77 Installer Script (Update)
; $VER: 5.77 (22-May-97)
; Written by Thomas PIMMEL

(set #welcome-message
(cat	"\nM2I 5.77 (c) Thomas PIMMEL 1991-1998\n"
	"Update 5.76 -> 5.77"))

(set @default-dest "SYS:")


(if (= @language "français")
 (
	(set #wrongversion
	(cat	"Vous utilisez une vieille version du programme 'Installer'"
		"\n\n Ce script a besoin de l'Installer 42.9 (minimum),\n\n"
		"disponible sur Aminet (ftp.wustl.edu)"))

	(set #selectdir "\nChoisissez l'endroit où se trouve l'ancienne version de l'exécutable")

	(set #notfound "\nM2I5 non trouvé")

 )

 (
	(set #wrongversion
	(cat	"Your 'Installer' version on your amiga is too old!\n\nYou need "
		"at least 'Installer' V42.9, available on Aminet (ftp.wustl.edu)"))

	(set #selectdir "\nChoose the directory of the executable old version")

	(set #notfound "\nM2I5 not found")

 )
)


; ------------------------------------
; Check Installer & Kickstart Version
; ------------------------------------

(if (< @installer-version 2752521)
  (
    (message #wrongversion (all))
    (exit (quiet))
  )
)

; ------------------------------
; Where?
; ------------------------------
(set destdir
	(askdir
	(prompt #selectdir)
	(help @askdir-help)
	(disk)
	(default @default-dest)
	)
)

(set @default-dest destdir)

; ------------------------------
; Verify
; ------------------------------

(if (not (exists (tackon destdir "M2I5") (NOREQ)))
  (
    (message #notfound (all))
    (exit (quiet))
  )
)

; ------------------------------
; Programms
; ------------------------------

(if	(OR (= (database "cpu") "68000")
	(= (database "cpu") "68010"))

;======== Copy 68000 Version
	(
		(copyfiles
			(source "bin/M2I5_000")
			(dest destdir)
			(newname "M2I5")
			(optional "force")

		)
	)
;======== Copy 68020 Version
	(
		(copyfiles
			(source "bin/M2I5_020")
			(dest destdir)
			(newname "M2I5")
			(optional "force")
		)
	)
)