(welcome "Willkommen zum Installation-Programm für den AssignMaster.")

(if (= (askbool (prompt "A C H T U N G !\n\n"
                        "Sollte eine ältere AM-Version bereits installiert sein, so ist "
                        "diese vorher komplett (inklusive Sicherungsdateien) "
                        "zu entfernen!\n\n"
                        "Soll AssignMaster V1.2 jetzt installiert werden?")
                (help @askbool-help)
                (default 1)
        ) 0)
  (
    (exit (cat "\n\nDie Installation wurde vom Benutzer abgebrochen.")
          (quiet)
    )
  )
)

(set #destination_prg (askdir (prompt "Bitte wähle das Zielverzeichnis"
                                      " für das AssignMaster-Programm."
                                      " Ein Unterverzeichnis dafür wird dort nicht"
                                      " erzeugt.")
                              (help @askdir-help)
                              (default "SYS:Tools")
                      )
)


(set #catalog_dest (askdir (prompt "Wohin sollen die Sprachdateien "
                                   "kopiert werden? Das Unterverzeichnis "
                                   "entsprechend der gewählten Sprache "
                                   "wird automatisch gewählt.")
                           (help @askdir-help)
                           (default "LOCALE:Catalogs")
                   )
)

(set #destination_doc (askdir (prompt "Wohin soll die Dokumentation "
                                      "kopiert werden?")
                              (help @askdir-help)
                              (default "HELP:")
                      )
)


(copyfiles (prompt "Kopiere Programmdatei...")
           (help @copyfiles-help)
           (source "/AssignMaster")
           (dest #destination_prg)
           (files)
           (confirm)
           (infos)
)


(set #catalog_dir (tackon #catalog_dest "deutsch"))
(copyfiles (prompt "Kopiere deutsche Katalogdatei...")
           (help @copyfiles-help)
           (source "/catalogs/deutsch/assignmaster.catalog")
           (dest #catalog_dir)
           (files)
           (confirm)
)

(copyfiles (prompt "Kopiere deutsche Dokumentation...")
           (help @copyfiles-help)
           (source "/docs/AM_Ger.Guide")
           (dest #destination_doc)
           (newname "AssignMaster.Guide")
           (files)
           (confirm)
           (infos)
)

(copyfiles (prompt "Kopiere History...")
           (help @copyfiles-help)
           (source "/docs/AM_History.txt")
           (dest #destination_doc)
           (newname "AssignMaster.History")
           (files)
           (confirm)
)

(if (= 1 (askbool (prompt "Die folgende Funktion ist nur für die spätere "
                          "Installation in der 'startup-sequence' hilfreich."
                          "\n\nSoll die aktuelle Zuweisungsliste "
                          "jetzt gesichert werden?\n\n"
                          "Stelle sicher, daß im Moment wirklich nur "
                          "Zuweisungen im System vorhanden sind, die "
                          "auch beim Systemstart erzeugt werden! Diese "
                          "gesicherte Liste kann dann als Parameter "
                          "für den AssignMaster in der StartUp-Sequence dienen."
                          "\n\nSolltest du dir hier nicht sicher sein, "
                          "so antworte mit \"Nein\".")
                  (help @askbool-help)
                  (default 0)
                  (choices "Ja" "Nein")
         )
    )
  (
    (set #savefile (askfile (prompt "Wohin und unter welchem Namen soll "
                                    "soll die Zuweisungliste gesichert werden?")
                            (help @askfile-help)
                            (default #destination_prg)
                   )
    )
    (set #amcommand (cat (tackon #destination_prg "AssignMaster")
                         " BACKUP=\""
                         #savefile
                         "\"")
    )
    (run #amcommand (prompt (cat "Speichere nun die aktuelle Zuweisungliste in die "
                                 "Datei:\n"
                                 "#savefile")
                    )
                    (help @run-help)
                    (confirm)
    )
  )
)

(exit (cat "Installation abgeschlossen.\n\nUm das Programm 'AssignMaster' beim "
           "Systemstart benutzen zu können, muß die "
           "in der 'startup-sequence' manuell geändert werden."
           "Eine automatische Installation ist dafür nicht vorgesehen.\n"
           "ACHTUNG!!! Da sich die CLI-Parameter in AM1.2 geändert haben, "
           "sollte die Installation in der 'startup-sequence' komplett "
           "neu vorgenommen werden und eine neue Assign-Liste erzeugt werden.\n\n"
           "Viel Spaß mit AssignMaster.")
      (quiet)
)