/* $VER: TestWindow 1.0b (23.9.96)
  Test Window  v1.0a
  9/23/96  J. Tierney

  Usage:  TestWindow [pubscreen]
*/

MODULE 'exec/types',
       'exec/ports',
       'intuition/intuition',
       'intuition/screens',
       'dos/dos',
       'graphics/displayinfo',
       'utility/tagitem'

CONST NOTZERO = $FFFFFFFF

ENUM OKQUIT, NOWINDOW

RAISE NOWINDOW IF OpenWindowTagList() = NIL

DEF scrntitle[80]:STRING, winw, winh

PROC main() HANDLE
  DEF class, code,
      testwin=NIL:PTR TO window,
      scrnw, scrnh, tmp

  testwin:=OpenWindowTagList(NIL,
                            [WA_LEFT, 20,          WA_TOP, 10,
                            WA_WIDTH, 200,         WA_HEIGHT, 75,
                            WA_MINWIDTH, 65,       WA_MINHEIGHT, 15,
                            WA_MAXWIDTH, NOTZERO,  WA_MAXHEIGHT, NOTZERO,
                            WA_DRAGBAR,            TRUE,
                            WA_DEPTHGADGET,        TRUE,
                            WA_SIZEGADGET,         TRUE,
                            WA_CLOSEGADGET,        TRUE,
                            WA_SIMPLEREFRESH,      TRUE,
                            WA_NOCAREREFRESH,      TRUE,
                            WA_ACTIVATE,           TRUE,
                            WA_IDCMP,              IDCMP_CLOSEWINDOW OR IDCMP_CHANGEWINDOW OR IDCMP_VANILLAKEY,
                            WA_TITLE,              'TestWindow',
                            WA_PUBSCREENNAME,      arg,
                            WA_PUBSCREENFALLBACK,  TRUE])

  setscrntitle(testwin)

  scrnw:=testwin.wscreen.width AND $FFFF
  scrnh:=testwin.wscreen.height AND $FFFF

  LOOP
    class:=WaitIMessage(testwin)
    code:=MsgCode() AND $FFFFFFDF
    SELECT class
      CASE IDCMP_CLOSEWINDOW
        Raise(OKQUIT)
      CASE IDCMP_CHANGEWINDOW
        setscrntitle(testwin)
      CASE IDCMP_VANILLAKEY
        SELECT code
          CASE "H"
            tmp:=(scrnw / 2) - (winw / 2)
            ChangeWindowBox(testwin, tmp, testwin.topedge, winw, winh)
          CASE "V"
            tmp:=(scrnh / 2) - (winh / 2)
            ChangeWindowBox(testwin, testwin.leftedge, tmp, winw, winh)
        ENDSELECT
    ENDSELECT
  ENDLOOP

EXCEPT
  IF testwin THEN CloseWindow(testwin)
ENDPROC IF exception THEN 10 ELSE 0

PROC setscrntitle(win:PTR TO window)
  winw:=win.width AND $FFFF
  winh:=win.height AND $FFFF

  StringF(scrntitle, 'Test Window - x: \d  y: \d  w: \d  h: \d', win.leftedge, win.topedge, winw, winh)
  SetWindowTitles(win, -1, scrntitle)
ENDPROC

CHAR '$VER: TestWindow 1.0b (23.9.96) by J. Tierney', 0