/*  This is a T-Warp-Colonizer routine.                                  */

/*  This script will automatically colonize your planet if you have a    */
/*  capable ship.    This script works best with a Corp Flag or an ISS.  */
/*  The Havoc has a very limited range so it won't be able to bring      */
/*  enough people back to make it's use worthwhile.   It will T-warp to  */
/*  to Terra if you have a commision.  If you don't you will need a Jump */
/*  point near Terra.  It will also give you the option to use a Planet  */
/*  transporter for the inbound trip to Terra if it has the range needed */
/*  To make it to the Jump Point or Terra whichever your using.          */
/*   If your using Terra due to a Fed Commision then when you are asked  */
/*  for the closest jump point to Terra use 1 as the sector number.      */


init:
test$ = "off"
areas$ = "foe"
planet = 0
land$ = "l"
planettwo = 0
landtwo$ = "l"
counttimes = 0
transporter$ = ""
gosub invalidmode
onmouse goto finish
gosub parseinfo
setplanetsector:
planetsector$ = str$(cursect)
getstring "What sector is your planet in?" , planetsector$
planetsector = val(planetsector$)
if planetsector != cursect
      beep
      tpen = 3
      print local
      print local "You must start out over your planet"
      tpen = 1
      goto finish
    endif
setjumppoint:
jumppoint$ = ""
getstring "What is the jump point closest to Terra?" , jumppoint$
jumppoint = val(jumppoint$)
if jumppoint < 1
      gosub validsector
      goto setjumppoint
    endif
if jumppoint > 5000
      gosub validsector
      goto setjumppoint
    endif
selectarea:
areaone$ = "e"
getstring "What area do you want to colonize? (f,o,e)" , areaone$
areaone$ = lower$(left$(areaone$ , 1))
areaone = instr(areas$ , areaone$)
if areaone < 1
      beep
      print local "This must be one of these letters: f,o,e."
      goto selectarea
    endif
send "c"
wait "Computer"
wait "Help"
command$ = "f" + str$(planetsector) + "^m" + str$(jumppoint) + "^M"
gosub findlength
plnttojump = sectorcount
if jumppoint > 1
      command$ = "f" + str$(jumppoint) + "^m1^M"
      gosub findlength
      jumptoterra = sectorcount
    else
      jumptoterra = 0
    endif
command$ = "f1^m" + str$(planetsector) + "^M"
gosub findlength
terratoplnt = sectorcount
send "q"
wait "Command"
transporter$ = "No"
getstring "Use the transporter?" , transporter$
if lower$(left$(transporter$ , 1)) != "y"
      transporter$ = "n"
      numtimes = (turns - 40) / (((2 + jumptoterra) * turnstowarp) + 2)
      maxtimes = (turns) / (((2 + jumptoterra) * turnstowarp) + 2)
      getfuel = (plnttojump + terratoplnt) * 3
    else
      transporter$ = "y"
      numtimes = (turns - 40) / (((1 + jumptoterra) * turnstowarp) + 3)
      maxtimes = (turns) / (((1 + jumptoterra) * turnstowarp) + 3)
      getfuel = terratoplnt * 3
    endif
if numtimes < 1
      numtimes = 0
    endif
getint "How many times do you want to run this loop?" , numtimes , 0 , maxtimes
if numtimes < 1
      goto finish
    endif
goto partone

partone:
send land$
if planet == 0
      when 1 "on which" goto multiple
      wait "Landing"
      land$ = "l "
      planet = 999
    endif
landing:
if land$ == "l"
      when 1 "[D]" goto notransport
      wait "ort pow"
      when 1
      wait "[D]"
    else
      wait "[D]"
    endif
command$ = "s^ml" + str$(areaone) + "^m"
send command$
when 1 "aren't" goto fullarea
wait "Planet"
command$ = "t^mt1" + str$(getfuel) + "^m"
send command$
when 1 "aren't" goto emptyplanet
wait "Planet"
if transporter$ == "y"
      send "cb"
      wait "sector?"
      command$ = left$(str$(jumppoint) + "   " , 4) + "^m"
      send command$
    else
      send "q"
      wait "(?"
      wait ") :"
      command$ = left$(str$(jumppoint) + "   " , 4) + "y"
      send command$
    endif
goto parttwo

parttwo:
when 1 "WARNING" goto noblindjump
wait "Locked"
when 1
send "y"
wait "Command"
if jumppoint > 1
      send "1^m n e"
      wait "Command"
    endif
send landtwo$
if planettwo == 0
      when 1 "on which" goto multipletwo
      wait "to land"
      landtwo$ = "l "
      planettwo = 999
    endif
landingtwo:
wait "(Q to"
command$ = "t^m"
send command$
command$ = left$(str$(planetsector) + "   " , 4) + "y"
send command$
when 1 "WARNING" goto noblindjump
wait "Locked"
when 1
send "y "
wait "Command"
goto goagain

goagain:
counttimes = counttimes + 1
if counttimes < numtimes
      goto partone
    endif
goagain$ = "yes"
getstring "do you wish to continue?" , goagain$
if goagain$ == "yes"
      goto partone
    endif
goto finish

finish:
end

fullarea:
beep
tpen = 3
print local
print local "That area seems to be  Full."
tpen = 1
goto finish

emptyplanet:
beep
tpen = 3
print local
print local "The planet seems to be out of Fuel Ore."
tpen = 1
goto finish

noblindjump:
send "n"
wait "Command"
beep
tpen = 3
print local
print local "This script will not blind jump."
tpen = 1
goto finish

multiple:
getint "Which planet?" , planet , 2 , 150
land$ = "l " + str$(planet) + "^m "
planet$ = str$(planet) + "^m"
send planet$
goto landing

multipletwo:
landtwo$ = "l 1^m "
planettwo$ = "1^m "
planettwo = 1
send planettwo$
goto landingtwo

invalidmode:
cmdlne$ = left$(getline$(row + 1) , 7)
if cmdlne$ != "Command"
      beep
      tpen = 3
      print local
      print local "You need to be at the main command prompt to run this script!"
      tpen = 1
      goto finish
    endif
return

validsector:
beep
print local
print local "This must be a number from 11 to 5000!"
return

parseinfo:
send "i"
wait "Alignm"
experience$ = trim$(getline$(row + 1))
experience$ = right$(experience$ , len(experience$) - 16)
experience = val(experience$)
wait "Current"
turnstowarp$ = trim$(getline$(row))
turnstowarp$ = right$(turnstowarp$ , len(turnstowarp$) - 16)
turnstowarp = val(turnstowarp$)
wait " left "
cursect$ = trim$(getline$(row))
cursect$ = right$(cursect$ , len(cursect$) - 16)
cursect = val(cursect$)
wait "Total Ho"
turns$ = trim$(getline$(row))
turns$ = right$(turns$ , len(turns$) - 16)
turns = val(turns$)
wait "Fight"
totholds$ = trim$(getline$(row))
totholds$ = right$(totholds$ , len(totholds$) - 16)
totholds = val(totholds$)
wait "?"
wait ") :"
if test$ == "on"
      print local
      print local "experience = " ; experience
      print local "current sector = " ; cursect
      print local "turns = " ; turns
      print local "totholds = " ; totholds
    endif
return

findlength:
send command$
wait "Computer"
thepath$ = trim$(getline$(row - 1))
sectorcount = 0
counting:
slash = instr(thepath$, ">")
if slash != 0
      sectorcount = sectorcount + 1
      thepath$ = right$(thepath$, len(thepath$) - slash)
      goto counting
    endif
return

notransport:
beep
tpen = 3
print local
print local "*** This planet has no Tele-Porter! ***"
print local
tpen = 1
end