(complete 0)

(set default_lang 4)
(set #introduction
(cat "\n\nInstallation of EnvMan.\n"
))

(set #bravi
(cat "Installation is not possible."
))

(set #quel-disque
(cat "Where do you want to install EnvMan\n(A directory will be created) ?"
))

(set #quel-disque-aide
(cat "Select the drawer or volume where the installation should be made."
))
(set #oui-prompt
(cat "Installation of OBJECT USER INTERFACE catalog files."
))

(set #startup-prompt
(cat "Adding path in user-startup."
))

(if (= @language "français")
(
(set default_lang 16)
(set #introduction
(cat "\n\nInstallation de EnvMan.\n"
))

(set #bravi
(cat "L'installation a échoué."
))

(set #quel-disque
(cat "Où voulez-vous installer EnvMan\n(Un répertoire sera créé) ?"
))

(set #quel-disque-aide
(cat "Sélectionnez le disque ou répertoire où l'installation doit être effectuée."
))

(set #oui-prompt
(cat "Installation des catalogues pour l'interface OUI."
))

(set #startup-prompt
(cat "Ajout du chemin dans le fichier user-startup."
))



))

;---------------------------------------------------------------------
(set installLoc (pathonly (pathonly @icon))
     installCats (tackon installLoc "Catalogs")
     installOuiCat (tackon (tackon (tackon installLoc "OUI_Catalogs") @language) "oui.catalog")
     targetOuiCat (tackon "LOCALE:Catalogs" @language)
)

(delopts "oknodelete" "force" "askuser")
(user 2)
(message #introduction)
(user 0)
(welcome)
(set old_level @user-level)
    (user 2)
    (set target (tackon (askdir (prompt #quel-disque)
                        (help #quel-disque-aide)
                        (default "SYS:")
                        (disk)
                ) "EnvMan")
    )
    (makedir target
             (infos))

    (user old_level)
(set @default-dest target)
(complete 10)

(set targetCats (tackon target "Catalogs"))

(makedir targetCats
         (infos))

(copyfiles (source installLoc)
           (dest target)
           (pattern "EnvMan#?")
)
(complete 70)
(copyfiles (source installLoc)
           (dest target)
           (pattern "locale#?")
)
(complete 80)
(copyfiles (source installCats)
           (dest targetCats)
           (all)
)
(copylib (prompt #oui-prompt)
         (source installOuiCat)
         (dest targetOuiCat)
         (confirm)
         (optional nofail askuser)
         (help @copylib-help)
)

(startup "EnvMan" (prompt #startup-prompt)
         (help @startup-help)
         (command (cat "Path " target " ADD"))
)
(complete 100)