; $VER: BlitzDms Install Script V1.2 (09.10.96) by Anthony Brice.
;
; Update for 1.12 archive - 10th March, 1997.
;
(set MSG_DESTINATION "Where would you like %s to be installed?\n(%s will be directly copied there)")
(set MSG_COPYING "Going to copy %s to %s.")
(set MSG_DOCS "Copying %s AmigaGuide document to %s")
(set DOCUMENTATION "Where would you like the %s Guide document?")
(set FONT "Install the supplied Fonts?\n%s can use with any size 8 or above font,\nand these are very nice examples.")
(set LIBS "Would you like to install the ReqTools Library\n which %s needs to run? Newer versions will NOT\nbe overwritten!!")
(set @abort-button "Forget it!")
(set MSG_THANKS "Thank you for evaluating %s!\nPlease remember that it is shareware and registration\nSupports future Amiga development\n")

(set #bad-kick
(cat "BlitzDms 1.01 will only run under KickStart 2.04 or above!"
))

(if (< (/ (getversion) 65536) 37) (abort #bad-kick))

(complete 0)

; Choose default tool for guide, depending on user's OS version

(set osversion  (/ (getversion) 65536))
(if (>= osversion 39)
   (set guide_reader "MultiView") 
   (set guide_reader "AmigaGuide")
)

(complete 10)

(set installed "")

(set dest_dir
   (askdir (prompt (MSG_DESTINATION @app-name @app-name))
           (help @askdir-help)
           (default "Ram:")
           (newpath))
)

(set @default-dest dest_dir)

(complete 20)

(copyfiles  (prompt (MSG_COPYING @app-name @default-dest))
            (help @copyfiles-help)
            (source "/")
            (Pattern "BlitzDms#?")
            (dest dest_dir)
)

(complete 40)

(set dest_dir
   (askdir (prompt (DOCUMENTATION @app-name))
           (help @askdir-help)
           (default "Ram:")
           (newpath))
)

(set @default-dest dest_dir)

(complete 50)

(copyfiles  (prompt (MSG_DOCS @app-name @default-dest))
            (help @copyfiles-help)
            (source "/docs/")
            (Pattern "#?guide#?")
            (dest dest_dir)
)

(complete 60)

(copyfiles  (prompt (FONT @app-name))
            (help @copyfiles-help)
            (source "/fonts/")
            (pattern "#?")
            (dest "Fonts:")
            (fonts)
            (confirm)
)

(complete 70)

(copylib    (prompt (LIBS @app-name))
            (help @copyfiles-help)
            (source "/libs/reqtools.library")
            (dest "Libs:")
            (confirm)
)

(complete 90)

(if (exists (tackon @default-dest "BlitzDms.guide.info") (noreq))
   (
      (tooltype   (dest (tackon @default-dest "BlitzDms.guide"))
                  (noposition) (setdefaulttool guide_reader))
      (set installed "YES")         
  )
)

(complete 100)

(if (= installed "YES") 
   (exit (MSG_THANKS @app-name))
   (exit)
)   

; End of BlitzDms-Installer script !